
theorem Th52:
  for a,b,c,d being Real, h being Function of TOP-REAL 2,
TOP-REAL 2,f being Function of I[01],TOP-REAL 2 st a<b & c <d & h=AffineMap(2/(
b-a),-(b+a)/(b-a),2/(d-c),-(d+c)/(d-c)) & rng f c= closed_inside_of_rectangle(a
  ,b,c,d) holds rng (h*f) c= closed_inside_of_rectangle(-1,1,-1,1)
proof
  let a,b,c,d be Real, h be Function of TOP-REAL 2,TOP-REAL 2,f be
  Function of I[01],TOP-REAL 2;
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  assume that
A1: a<b and
A2: c <d and
A3: h=AffineMap(A,B,C,D) and
A4: rng f c= closed_inside_of_rectangle(a,b,c,d);
  let x be object;
  assume x in rng (h*f);
  then consider y being object such that
A5: y in dom (h*f) and
A6: x=(h*f).y by FUNCT_1:def 3;
  reconsider t0=y as Point of I[01] by A5;
A7: ((h*f).t0)=(h.(f.t0)) by A5,FUNCT_1:12;
  dom f=the carrier of I[01] by FUNCT_2:def 1;
  then f.t0 in rng f by FUNCT_1:def 3;
  then f.t0 in closed_inside_of_rectangle(a,b,c,d) by A4;
  then f.t0 in {p where p is Point of TOP-REAL 2: a <=p`1 & p`1<= b & c <=p`2
  & p`2<= d} by JGRAPH_6:def 2;
  then
A8: ex p being Point of TOP-REAL 2 st f.t0=p & a <=p`1 & p `1<= b & c
  <=p`2 & p`2<= d;
  reconsider p0=x as Point of TOP-REAL 2 by A5,A6,FUNCT_2:5;
A9: (h.(f.t0))= |[A*((f.t0)`1)+B,C*((f.t0)`2)+D]| by A3,JGRAPH_2:def 2;
A10: b-a>0 by A1,XREAL_1:50;
  then
A11: A >0 by XREAL_1:139;
  (-1-B)/A =(-1+(b+a)/(b-a))/(2/(b-a))
    .=((-1)*(b-a)+(b+a))/(b-a)/(2/(b-a)) by A10,XCMPLX_1:113
    .= (a+a)/(b-a)/2*(b-a) by XCMPLX_1:82
    .= ((b-a)*((a+a)/(b-a)))/2
    .=(a+a)/2 by A10,XCMPLX_1:87
    .= a;
  then A*((-1-B)/A) <= A*((f.t0)`1) by A11,A8,XREAL_1:64;
  then -1-B <= A*((f.t0)`1) by A11,XCMPLX_1:87;
  then -1-B+B <= A*((f.t0)`1)+B by XREAL_1:6;
  then
A12: -1 <=p0`1 by A6,A9,A7,EUCLID:52;
A13: d-c >0 by A2,XREAL_1:50;
  then
A14: C >0 by XREAL_1:139;
  (1-B)/A =(1+(b+a)/(b-a))/(2/(b-a))
    .=((1)*(b-a)+(b+a))/(b-a)/(2/(b-a)) by A10,XCMPLX_1:113
    .= (b+b)/(b-a)/2*(b-a) by XCMPLX_1:82
    .= ((b-a)*((b+b)/(b-a)))/2
    .=(b+b)/2 by A10,XCMPLX_1:87
    .= b;
  then A*((1-B)/A) >= A*((f.t0)`1) by A11,A8,XREAL_1:64;
  then 1-B >= A*((f.t0)`1) by A11,XCMPLX_1:87;
  then 1-B+B >= A*((f.t0)`1)+B by XREAL_1:6;
  then
A15: p0`1<=1 by A6,A9,A7,EUCLID:52;
  (1-D)/C =(1+(d+c)/(d-c))/(2/(d-c))
    .=((1)*(d-c)+(d+c))/(d-c)/(2/(d-c)) by A13,XCMPLX_1:113
    .= (d+d)/(d-c)/2*(d-c) by XCMPLX_1:82
    .= ((d-c)*((d+d)/(d-c)))/2
    .=(d+d)/2 by A13,XCMPLX_1:87
    .= d;
  then C*((1-D)/C) >= C*((f.t0)`2) by A14,A8,XREAL_1:64;
  then 1-D >= C*((f.t0)`2) by A14,XCMPLX_1:87;
  then 1-D+D >= C*((f.t0)`2)+D by XREAL_1:6;
  then
A16: p0`2<=1 by A6,A9,A7,EUCLID:52;
  (-1-D)/C =(-1+(d+c)/(d-c))/(2/(d-c))
    .=((-1)*(d-c)+(d+c))/(d-c)/(2/(d-c)) by A13,XCMPLX_1:113
    .= (c+c)/(d-c)/2*(d-c) by XCMPLX_1:82
    .= ((d-c)*((c+c)/(d-c)))/2
    .=(c+c)/2 by A13,XCMPLX_1:87
    .= c;
  then C*((-1-D)/C) <= C*((f.t0)`2) by A14,A8,XREAL_1:64;
  then -1-D <= C*((f.t0)`2) by A14,XCMPLX_1:87;
  then -1-D+D <= C*((f.t0)`2)+D by XREAL_1:6;
  then -1 <=p0`2 by A6,A9,A7,EUCLID:52;
  then x in {p2 where p2 is Point of TOP-REAL 2: -1 <=p2`1 & p2`1<= 1 & -1 <=
  p2`2 & p2`2<= 1} by A16,A12,A15;
  hence thesis by JGRAPH_6:def 2;
end;
