reserve

  k,n,m,i,j for Element of NAT,
  K for Field;
reserve L for non empty addLoopStr;
reserve G for non empty multLoopStr;

theorem Th52:
  for A being Matrix of n,K holds A=0.(K,n) iff for i,j st 1<=i &
  i<=n & 1<=j & j<=n holds A*(i,j)= 0.K
proof
  let A be Matrix of n,K;
A1: width A=n by MATRIX_0:24;
  thus A=0.(K,n) implies for i,j st 1<=i & i<=n & 1<=j & j<=n holds A*(i,j)=
  0.K
  proof
    assume A=0.(K,n);
    then
A2: A=0.(K,n,n) by MATRIX_3:def 1;
    thus for i,j st 1<=i & i<=n & 1<=j & j<=n holds A*(i,j)= 0.K
    proof
      let i,j;
      assume 1<=i & i<=n & 1<=j & j<=n;
      then [i,j] in Indices A by MATRIX_0:31;
      hence thesis by A2,MATRIX_3:1;
    end;
  end;
  assume
A3: for i,j st 1<=i & i<=n & 1<=j & j<=n holds A*(i,j)=0.K;
A4: Indices A=[: Seg n,Seg n :] by MATRIX_0:24;
A5: for i,j being Nat st [i,j] in Indices A holds A*(i,j)=(A+A)*(i,j)
  proof
    let i,j be Nat;
    reconsider i0=i,j0=j as Element of NAT by ORDINAL1:def 12;
    assume
A6: [i,j] in Indices A;
    then j in Seg n by A1,ZFMISC_1:87;
    then
A7: 1<=j & j<=n by FINSEQ_1:1;
    i in Seg n by A4,A6,ZFMISC_1:87;
    then 1<=i & i<=n by FINSEQ_1:1;
    then A*(i0,j0)= 0.K by A3,A7;
    then (A+A)*(i,j) = 0.K+(A*(i,j)) by A6,MATRIX_3:def 3
      .= A*(i,j) by RLVECT_1:4;
    hence thesis;
  end;
  len A=n by MATRIX_0:24;
  then A = 0.(K,n,n) by A1,A5,MATRIX_0:27,MATRIX_4:6;
  hence thesis by MATRIX_3:def 1;
end;
