reserve x for set,
  t,t1,t2 for DecoratedTree;
reserve C for set;
reserve X,Y for non empty constituted-DTrees set;
reserve T for DecoratedTree,
  p for FinSequence of NAT;
reserve T for finite-branching DecoratedTree,
  t for Element of dom T,
  x for FinSequence,
  n, m for Nat;
reserve x, x9 for Element of dom T,
  y9 for set;
reserve n,k1,k2,l,k,m for Nat,
  x,y for set;

theorem Th52:
  for f being sequence of NAT st (for n holds f.(n+1) qua
Nat <= f.n qua Nat) ex m st for n st m <= n holds f.n = f
  .m
proof
  let f be sequence of NAT such that
A1: for n holds f.(n+1) qua Nat <= f.n qua Nat;
A2: for m,k st m <= k holds f.k qua Nat <= f.m qua Nat
  proof
    defpred P[Nat] means for m st m <= $1 holds f.$1 qua Element of
    NAT <= f.m qua Nat;
A3: for k st P[k] holds P[k + 1]
    proof
      let k such that
A4:   P[k];
      now
        let m;
        assume
A5:     m <= k+1;
        per cases by A5,NAT_1:8;
        suppose
A6:       m <= k;
          reconsider fk = f.k, fm = f.m, fk1 = f.(k+1) as Nat;
A7:       fk1 <= fk by A1;
          fk <= fm by A4,A6;
          hence f.(k+1) qua Nat <= f.m qua Nat by A7,
XXREAL_0:2;
        end;
        suppose
          m = k+1;
          hence f.(k+1) qua Nat <= f.m qua Nat;
        end;
      end;
      hence thesis;
    end;
A8: P[0]
    by XXREAL_0:1;
A9: for k holds P[k] from NAT_1:sch 2(A8,A3);
    let m,k;
    assume m <= k;
    hence thesis by A9;
  end;
  defpred P[set] means $1 in rng f;
A10: ex k be Nat st P[k]
  proof
    consider y such that
A11: y = f.0;
    reconsider k = y as Nat by A11;
    take k;
    dom f = NAT by FUNCT_2:def 1;
    hence thesis by A11,FUNCT_1:def 3;
  end;
  ex k be Nat st P[k] & for n be Nat st P[n] holds k <= n from NAT_1:sch
  5(A10);
  then consider l be Nat such that
A12: l in rng f and
A13: for n be Nat st n in rng f holds l <= n;
  consider x being object such that
A14: x in dom f and
A15: l = f.x by A12,FUNCT_1:def 3;
  reconsider m = x as Nat by A14;
A16: dom f = NAT by FUNCT_2:def 1;
  for k st m <= k holds f.k = f.m
  proof
    let k such that
A17: m <= k;
    now
      reconsider fk = f.k, fm = f.m as Nat;
      assume
A18:  f.k <> f.m;
      fk <= fm by A2,A17;
      then
A19:  fk < fm by A18,XXREAL_0:1;
      k in NAT by ORDINAL1:def 12;
      then f.k in rng f by A16,FUNCT_1:def 3;
      hence contradiction by A13,A15,A19;
    end;
    hence thesis;
  end;
  hence thesis;
end;
