reserve X for set,
        D for a_partition of X,
        TG for non empty TopologicalGroup;
reserve A for Subset of X;
reserve US for UniformSpace;
reserve R for Relation of X;

theorem
  for X being non empty set, R being Equivalence_Relation of X holds
  TopSpace_induced_by( @(uniformity_induced_by(R)) ) =
    partition_topology(Class R)
  proof
    let X be non empty set,
        R be Equivalence_Relation of X;
    set T1 = TopSpace_induced_by( @(uniformity_induced_by(R)) ),
        T2 = partition_topology(Class R);
    now
      thus the carrier of T1 = the carrier of T2 by FINTOPO7:def 16;
A1:   the topology of T1 =
        Family_open_set(FMT_induced_by( @(uniformity_induced_by(R))))
        by FINTOPO7:def 16
                        .= the set of all O where O is open Subset of
        FMT_induced_by( @(uniformity_induced_by(R)));
A2:   the topology of T2 = the set of all union P where P is
        Subset of Class R by Th14;
A3:   the topology of T1 c= the topology of T2
      proof
        let t be object;
        assume t in the topology of T1;
        then consider O be open Subset of
          FMT_induced_by( @(uniformity_induced_by(R))) such that
A4:     t = O by A1;
        per cases;
        suppose
A5:       O is empty;
          {} c= Class R;
          then reconsider P = {} as Subset of Class R;
          t = union P by A4,A5,ZFMISC_1:2;
          hence thesis by A2;
        end;
        suppose
A6:       O is non empty;
          set P = the set of all Class(R,u) where u is Element of O;
          P c= Class R
          proof
            let u be object;
            assume u in P;
            then consider u0 be Element of O such that
A7:         u = Class(R,u0);
A8:         u0 in O by A6;
            thus thesis by A7,A8,EQREL_1:def 3;
          end;
          then reconsider P as Subset of Class R;
          reconsider t1 = t as Subset of X by A4;
          t1 = union P
          proof
            thus t1 c= union P
            proof
              let a be object;
              assume
A10:          a in t1;
              then reconsider b = a as Element of O by A4;
              b in Class(R,b) & Class(R,b) in P by A10,EQREL_1:20;
              hence thesis by TARSKI:def 4;
            end;
            let a be object;
            assume a in union P;
            then consider Q be set such that
A11:        a in Q and
A12:        Q in P by TARSKI:def 4;
            consider v be Element of O such that
A13:        Q = Class(R,v) by A12;
            v in O by A6;
            then reconsider w = v as Element of @(uniformity_induced_by(R));
            O in Neighborhood w by Th8,A6;
            then consider V be Element of the entourages of
              @(uniformity_induced_by(R)) such that
A14:        O = Neighborhood(V,w);
            V in rho(R);
            then consider W be Relation of the carrier of
              @(uniformity_induced_by(R)) such that
A15:        V = W and
A16:        R c= W;
A17:        Neighborhood(V,w) = V.:{w} & Neighborhood(V,w) = rng(V|{w}) &
            Neighborhood(V,w) = Im(V,w) &
            Neighborhood(V,w) = Class(V,w) &
            Neighborhood(V,w) = neighbourhood(w,V) by UNIFORM2:14;
            Class(R,w) c= Class(W,w)
            proof
              let z be object;
              assume z in Class(R,w);
              then [w,z] in W by A16,EQREL_1:18;
              hence thesis by EQREL_1:18;
            end;
            hence thesis by A11,A13,A4,A17,A15,A14;
          end;
          hence thesis by A2;
        end;
      end;
      the topology of T2 c= the topology of T1
      proof
        let t be object;
        assume
A18:    t in the topology of T2;
        then consider P be Subset of Class R such that
A19:    t = union P by A2;
        reconsider Q = union P as Subset of
          FMT_induced_by( @(uniformity_induced_by(R))) by A18,A19;
        for x being Element of
          @(uniformity_induced_by(R)) st x in Q holds
        Q in Neighborhood x
        proof
          let x be Element of @(uniformity_induced_by(R));
          assume
A20:      x in Q;
          then consider T be set such that
A21:      x in T and
A22:      T in P by TARSKI:def 4;
          T in Class R by A22;
          then consider b be object such that
A23:      b in X and
A24:      T = Class(R,b) by EQREL_1:def 3;
          set S1 = the set of all [x,y] where y is Element of Q;
          set S = R \/ S1;
          S1 c= [:X,X:]
          proof
            let s be object;
            assume s in S1;
            then consider y be Element of Q such that
A25:        s = [x,y];
            Q c= X;
            then y in X by A20;
            hence thesis by A25,ZFMISC_1:def 2;
          end;
          then reconsider S as Subset of [:X,X:] by XBOOLE_1:8;
          R c= S by XBOOLE_1:7;
          then S in rho(R);
          then reconsider V = S as Element of the entourages of
            @(uniformity_induced_by(R));
          Q = Neighborhood(V,x)
          proof
            thus Q c= Neighborhood(V,x)
            proof
              let a be object;
              assume a in Q;
              then reconsider b = a as Element of Q;
A27:          [x,b] in S1;
A28:          S1 c= R \/ S1 by XBOOLE_1:7;
              b in Q by A20;
              then reconsider c = b as Element of @(uniformity_induced_by(R));
              [x,c] in V by A28,A27;
              hence thesis;
            end;
            let a be object;
            assume a in Neighborhood(V,x);
            then consider y be Element of
              @(uniformity_induced_by(R)) such that
A29:        a = y and
A30:        [x,y] in V;
            per cases by A29,A30,XBOOLE_0:def 3;
            suppose [x,a] in S1;
              then consider y be Element of Q such that
A31:          [x,a] = [x,y];
              a = y by A31,XTUPLE_0:1;
              hence thesis by A20;
            end;
            suppose [x,a] in R; then
A32:          a in Class(R,x) by EQREL_1:18;
              Class(R,b) = Class(R,x) by A21,A23,A24,EQREL_1:23;
              hence thesis by A22,A24,A32,TARSKI:def 4;
            end;
          end;
          hence thesis;
        end;
        then reconsider O = union P as open Subset of
          FMT_induced_by( @(uniformity_induced_by(R))) by Th8;
        t = O by A19;
        hence thesis by A1;
      end;
      hence the topology of T1 = the topology of T2 by A3;
    end;
    hence thesis;
  end;
