reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th53:
  for cn being Real,K1 being non empty Subset of TOP-REAL 2, f
  being Function of (TOP-REAL 2)|K1,R^1 st -1<cn & (for p being Point of (
TOP-REAL 2) st p in the carrier of (TOP-REAL 2)|K1 holds f.p=|.p.|* ((p`1/|.p.|
  -cn)/(1+cn))) & (for q being Point of TOP-REAL 2 st q in the carrier of (
  TOP-REAL 2)|K1 holds q`2>=0 & q<>0.TOP-REAL 2) holds f is continuous
proof
  let cn be Real,K1 be non empty Subset of TOP-REAL 2,
f be Function of (
  TOP-REAL 2)|K1,R^1;
  reconsider g1=(2 NormF)|K1 as continuous Function of (TOP-REAL 2)|K1,R^1 by
Lm5;
  set a=cn, b=(1+cn);
  reconsider g2=proj1|K1 as continuous Function of (TOP-REAL 2)|K1,R^1 by Lm2;
  assume that
A1: -1<cn and
A2: for p being Point of (TOP-REAL 2) st p in the carrier of (TOP-REAL 2
  )|K1 holds f.p=|.p.|* ((p`1/|.p.|-cn)/(1+cn)) and
A3: for q being Point of TOP-REAL 2 st q in the carrier of (TOP-REAL 2)
  |K1 holds q`2>=0 & q<>0.TOP-REAL 2;
  for q being Point of TOP-REAL 2 st q in the carrier of (TOP-REAL 2)|K1
  holds q<>0.TOP-REAL 2 by A3;
  then
A4: for q being Point of (TOP-REAL 2)|K1 holds g1.q<>0 by Lm6;
  1+cn>0 by A1,XREAL_1:148;
  then consider g3 being Function of (TOP-REAL 2)|K1,R^1 such that
A5: for q being Point of (TOP-REAL 2)|K1,r1,r2 being Real st g2.q=r1 &
  g1.q =r2 holds g3.q=r2*((r1/r2-a)/b) and
A6: g3 is continuous by A4,Th5;
A7: dom g3=the carrier of (TOP-REAL 2)|K1 by FUNCT_2:def 1;
A8: for x being object st x in dom f holds f.x=g3.x
  proof
    let x be object;
    assume
A9: x in dom f;
    then reconsider s=x as Point of (TOP-REAL 2)|K1;
    x in dom g3 by A7,A9;
    then x in K1 by A7,PRE_TOPC:8;
    then reconsider r=x as Point of TOP-REAL 2;
A10: proj1.r=r`1 & (2 NormF).r=|.r.| by Def1,PSCOMP_1:def 5;
A11: g2.s=proj1.s & g1.s=(2 NormF).s by Lm2,Lm5;
    f.r=(|.r.|)* ((r`1/|.r.|-cn)/(1+cn)) by A2,A9;
    hence thesis by A5,A11,A10;
  end;
  dom f=dom g3 by A7,FUNCT_2:def 1;
  hence thesis by A6,A8,FUNCT_1:2;
end;
