reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th40:
  for a being Real,P being Subset of TOP-REAL n st n>=2 & P=(REAL
  n)\ {q : |.q.| < a } holds P is connected
proof
  let a be Real, P be Subset of TOP-REAL n;
  assume
A1: n>=2 & P=(REAL n)\ {q : |.q.| < a };
  then reconsider Q=P as non empty Subset of TOP-REAL n by Th39,XXREAL_0:2;
  for w1,w7 being Point of TOP-REAL n st w1 in Q & w7 in Q & w1<>w7 ex f
  being Function of I[01],((TOP-REAL n) | Q) st f is continuous & w1=f.0 &
  w7=f.1
  proof
    let w1,w7 be Point of TOP-REAL n;
    assume that
A2: w1 in Q & w7 in Q and
    w1<>w7;
    per cases;
    suppose
      not (ex r being Real st w1=r*w7 or w7=r*w1);
      then
      ex w2,w3 being Point of TOP-REAL n st w2 in Q & w3 in Q & LSeg(w1,w2)
      c=Q & LSeg(w2,w3) c= Q & LSeg(w3,w7) c= Q by A1,A2,Th30;
      hence thesis by A2,Th26;
    end;
    suppose
      ex r being Real st w1=r*w7 or w7=r*w1;
      then
      ex w2,w3,w4,w5,w6 being Point of TOP-REAL n st w2 in Q & w3 in Q & w4
in Q & w5 in Q & w6 in Q & LSeg(w1,w2) c=Q & LSeg(w2,w3) c= Q & LSeg(w3,w4) c=
      Q & LSeg(w4,w5) c= Q & LSeg(w5,w6) c=Q & LSeg(w6,w7) c= Q by A1,A2,Th36;
      hence thesis by A2,Th27;
    end;
  end;
  hence thesis by JORDAN1:2;
end;
