reserve

  k,n,m,i,j for Element of NAT,
  K for Field;
reserve L for non empty addLoopStr;
reserve G for non empty multLoopStr;

theorem Th53:
  for A being Matrix of n,K st A<> 0.(K,n) holds ex B,C being
Matrix of n,K st B is invertible & C is invertible & (B*A*C)*(1,1) =1.K & (for
i st 1<i & i<=n holds (B*A*C)*(i,1)= 0.K)& for j st 1<j & j<=n holds (B*A*C)*(1
  ,j)= 0.K
proof
  let A be Matrix of n,K;
  assume A<> 0.(K,n);
  then consider i0,j0 being Element of NAT such that
A1: 1<=i0 & i0<=n and
A2: 1<=j0 & j0<=n and
A3: A*(i0,j0)<>0.K by Th52;
  set A3=((SwapDiagonal(K,n,i0))*A)*(SwapDiagonal(K,n,j0));
  set A2= ((SwapDiagonal(K,n,i0))*A);
  1<=n by A1,XXREAL_0:2;
  then
  (((SwapDiagonal(K,n,i0))*A)*(SwapDiagonal(K,n,j0)))*(1,1) =A2*(1,j0) by A2
,Th51
    .=A*(i0,j0) by A1,A2,Th48;
  then consider P,Q being Matrix of n,K such that
A4: P is invertible and
A5: Q is invertible and
A6: ( (P*A3*Q)*(1,1)=1.K & for i st 1<i & i<=n holds (P*A3*Q)*(i,1)= 0.K
  )& for j st 1<j & j<=n holds (P*A3*Q)*(1,j)= 0.K by A1,A3,Th41;
  set B0=P*(SwapDiagonal(K,n,i0)),C0=(SwapDiagonal(K,n,j0))*Q;
  SwapDiagonal(K,n,i0) is invertible by A1,Th49;
  then
A7: B0 is invertible by A4,MATRIX_6:36;
  SwapDiagonal(K,n,j0) is invertible by A2,Th49;
  then
A8: C0 is invertible by A5,MATRIX_6:36;
  (B0*A*C0)=(P*((SwapDiagonal(K,n,i0))*A)*((SwapDiagonal(K,n,j0))*Q)) by Th17
    .=(P*((SwapDiagonal(K,n,i0))*A)*(SwapDiagonal(K,n,j0))*Q) by Th17
    .=(P*A3*Q) by Th17;
  hence thesis by A6,A7,A8;
end;
