reserve a,b,c,h for Integer;
reserve k,m,n for Nat;
reserve i,j,z for Integer;
reserve p for Prime;

theorem Th53:
  for j being Integer st j <> 0
  for n being positive Nat st
    for i being Nat st i in dom PrimeDivisorsFS(n) holds
      j,PrimeDivisorsFS(n).i are_coprime holds
  j,n are_coprime
  proof
    let j be Integer;
    assume j <> 0;
    then reconsider j1 = |.j.| as non zero Nat;
    let n be positive Nat;
    set X = PrimeDivisors(n);
    set q = PrimeDivisorsFS(n);
    assume
A1: for i being Nat st i in dom q holds j,q.i are_coprime;
    set N = ppf n;
    set J = ppf j1;
A2: now
      assume support J meets support N;
      then consider y being object such that
A3:   y in support J and
A4:   y in support N by XBOOLE_0:3;
      set C = canFS support N;
      q = sort_a C by Th52;
      then
A5:   rng C = rng q by CLASSES1:75,RFINSEQ2:def 6;
      support N = support pfexp n by NAT_3:def 9;
      then reconsider y as Prime by A4,NAT_3:34;
      support J = support pfexp j1 by NAT_3:def 9;
      then
A6:   y divides j1 by A3,NAT_3:36;
      rng C = support N by FUNCT_2:def 3;
      then consider x being object such that
A7:   x in dom q and
A8:   q.x = y by A4,A5,FUNCT_1:def 3;
      j,q.x are_coprime by A1,A7;
      hence contradiction by A6,A8,Th10,PYTHTRIP:def 2;
    end;
    Product N = n & Product J = j1 by NAT_3:61;
    hence j,n are_coprime by A2,Th10,INT_7:12;
  end;
