reserve a,b,c,d for positive Real,
  m,u,w,x,y,z for Real,
  n,k for Nat,
  s,s1 for Real_Sequence;

theorem
  (for n being Nat holds s.n>0 & s1.n=1/s.n) implies
  for n holds Partial_Sums(s).n*Partial_Sums(s1).n>=(n+1)^2
proof
  defpred X[Nat] means Partial_Sums(s).$1*Partial_Sums(s1).$1>=($1+
  1)^2;
  assume
A1: for n being Nat holds s.n>0 & s1.n=1/s.n;
  then
A2: s.0>0;
A3: for n st X[n] holds X[n+1]
  proof
    let n;
    set x=Partial_Sums(s).n;
    set y=Partial_Sums(s1).n;
    assume
A4: Partial_Sums(s).n*Partial_Sums(s1).n>=(n+1)^2;
    then
A5: x*y+(x/s.(n+1)+y*s.(n+1)+1)>=(n+1)^2+(x/s.(n+1)+y*s.(n+1)+1) by XREAL_1:7;
    sqrt(x*y)>=sqrt((n+1)^2) by A4,SQUARE_1:26;
    then sqrt(x*y)>=n+1 by SQUARE_1:22;
    then
A6: 2*sqrt(x*y)>=2*(n+1) by XREAL_1:64;
A7: s.(n+1)>0 by A1;
A8: x>0 by A1,SERIES_3:33;
    y>0 by A1,Th52;
    then x/s.(n+1)+y*s.(n+1)>=2*sqrt((y*s.(n+1))*(x/s.(n+1))) by A7,A8,
SIN_COS2:1;
    then x/s.(n+1)+y*s.(n+1)>=2*sqrt(x/((1*s.(n+1))/(y*s.(n+1)))) by
XCMPLX_1:81;
    then x/s.(n+1)+y*s.(n+1)>=2*sqrt(x/(1/y)) by A7,XCMPLX_1:91;
    then x/s.(n+1)+y*s.(n+1)>=2*sqrt(y*(x/1)) by XCMPLX_1:81;
    then x/s.(n+1)+y*s.(n+1)>=2*n+2 by A6,XXREAL_0:2;
    then
A9: (x/s.(n+1)+y*s.(n+1))+(n^2+2*n+2)>=(2*n+2)+(n^2+2*n+2) by XREAL_1:7;
    Partial_Sums(s).(n+1)*Partial_Sums(s1).(n+1) =(x+s.(n+1))*Partial_Sums
    (s1).(n+1) by SERIES_1:def 1
      .=(x+s.(n+1))*(y+s1.(n+1)) by SERIES_1:def 1
      .=x*y+x*(s1.(n+1))+(s.(n+1))*y+(s.(n+1))*(s1.(n+1))
      .=x*y+x*(1/s.(n+1))+(s.(n+1))*y+(s.(n+1))*(s1.(n+1)) by A1
      .=x*y+x*(1/s.(n+1))+(s.(n+1))*y+(s.(n+1))*(1/s.(n+1)) by A1
      .=x*y+x*(1/s.(n+1))+(s.(n+1))*y+((s.(n+1))*1)/s.(n+1) by XCMPLX_1:74
      .=x*y+x*(1/s.(n+1))+(s.(n+1))*y+1 by A7,XCMPLX_1:60
      .=x*y+x/(s.(n+1)/1)+(s.(n+1))*y+1 by XCMPLX_1:79
      .=x*y+x/s.(n+1)+(s.(n+1))*y+1;
    hence thesis by A9,A5,XXREAL_0:2;
  end;
  Partial_Sums(s).0*Partial_Sums(s1).0 =s.0*Partial_Sums(s1).0 by
SERIES_1:def 1
    .=s.0*s1.0 by SERIES_1:def 1
    .=s.0*(1/s.0) by A1
    .=s.0/(s.0/1) by XCMPLX_1:79
    .=1 by A2,XCMPLX_1:60;
  then
A10: X[0];
  for n holds X[n] from NAT_1:sch 2(A10,A3);
  hence thesis;
end;
