reserve x,y,z,X,Y for set;
reserve X,Y for non empty set,
  f for Function of X,Y;
reserve X, Y for non empty set,
  F for (BinOp of Y),
  B for (Element of Fin X),
  f for Function of X,Y;
reserve A for set,
  x,y,z for Element of Fin A;
reserve X,Y for non empty set,
  A for set,
  f for (Function of X, Fin A),
  i,j,k for (Element of X);

theorem Th50:
  for Z being non empty set, Y being set for G being BinOp of Z st
G is commutative & G is associative & G is idempotent & G is having_a_unity for
  f being Function of X, Fin Y for g being Function of Fin Y,Z st g.{}.Y =
the_unity_wrt G & for x,y being Element of Fin Y holds g.(x \/ y) = G.(g.x,g.y)
  for B being Element of Fin X holds g.(FinUnion(B,f)) = G$$(B,g*f)
proof
  let Z be non empty set, Y be set;
  let G be BinOp of Z such that
A1: G is commutative & G is associative and
A2: G is idempotent and
A3: G is having_a_unity;
  let f be Function of X, Fin Y;
  let g be Function of Fin Y,Z such that
A4: g.{}.Y = the_unity_wrt G and
A5: for x,y being Element of Fin Y holds g.(x \/ y) = G.(g.x,g.y);
  let B be Element of Fin X;
A6: {} = {}.X;
A7: {} = {}.Fin Y;
  per cases;
  suppose
A8: B = {};
    then
A9: f.:B = {};
    thus g.(FinUnion(B,f)) = g.{}.Y by A6,A8,Th44
      .= G$$(f.:B,g) by A1,A3,A4,A7,A9,Th28
      .= G$$(B,g*f) by A1,A2,A3,Th32;
  end;
  suppose
    B <> {};
    hence thesis by A1,A2,A5,Th49;
  end;
end;
