reserve x,X,Y for set;
reserve C for non empty set;
reserve c for Element of C;
reserve V for RealNormSpace;
reserve f,f1,f2,f3 for PartFunc of C,V;
reserve r,r1,r2,p for Real;

theorem Th53:
  f|Y is constant implies ||.f.|||Y is constant & (-f)|Y is constant
proof
  assume f|Y is constant;
  then consider r being VECTOR of V such that
A1: for c st c in Y /\ dom f holds f/.c = r by PARTFUN2:35;
  now
    let c;
    assume
A2: c in Y /\ dom (||.f.||);
    then
A3: c in Y by XBOOLE_0:def 4;
A4: c in dom (||.f.||) by A2,XBOOLE_0:def 4;
    then c in dom f by NORMSP_0:def 3;
    then
A5: c in Y /\ dom f by A3,XBOOLE_0:def 4;
    thus (||.f.||).c = ||.f/.c.|| by A4,NORMSP_0:def 3
      .= ||.r.|| by A1,A5;
  end;
  hence ||.f.|||Y is constant by PARTFUN2:57;
  now
    take p=-r;
    let c;
    assume
A6: c in Y /\ dom (-f);
    then c in Y /\ dom f by Def5;
    then
A7: -f/.c = p by A1;
    c in dom (-f) by A6,XBOOLE_0:def 4;
    hence (-f)/.c = p by A7,Def5;
  end;
  hence thesis by PARTFUN2:35;
end;
