reserve            x for object,
               X,Y,Z for set,
         i,j,k,l,m,n for Nat,
                 r,s for Real,
                  no for Element of OrderedNAT,
                   A for Subset of [:NAT,NAT:];
reserve X,Y,X1,X2 for non empty set,
          cA1,cB1 for filter_base of X1,
          cA2,cB2 for filter_base of X2,
              cF1 for Filter of X1,
              cF2 for Filter of X2,
             cBa1 for basis of cF1,
             cBa2 for basis of cF2;
reserve T for non empty TopSpace,
        s for Function of [:NAT,NAT:], the carrier of T,
        M for Subset of the carrier of T;
reserve cF3,cF4 for Filter of the carrier of T;

theorem Th45:
  for x being Point of T holds
  x in lim_filter(s,Frechet_Filter([:NAT,NAT:])) iff
  for A being a_neighborhood of x holds
  ex B being finite Subset of [:NAT,NAT:] st s"(A) = [:NAT,NAT:] \ B
  proof
    let x be Point of T;
    set F = filter_image(s,Frechet_Filter([:NAT,NAT:]));
A1: F is_filter-finer_than NeighborhoodSystem x iff
    for A be a_neighborhood of x holds
      ex B be finite Subset of [:NAT,NAT:] st s"(A) = [:NAT,NAT:] \ B
    proof
      hereby
        assume F is_filter-finer_than NeighborhoodSystem x;
        then NeighborhoodSystem x c= {M where
          M is Subset of the carrier of T: ex A being finite Subset of
          [:NAT,NAT:] st s"(M) = [:NAT,NAT:] \ A} by Th43; then
A2:       the set of all A where A is a_neighborhood of x c=
          {M where M is Subset of the carrier of T:
          ex A being finite Subset of [:NAT,NAT:] st
          s"(M) = [:NAT,NAT:] \ A} by YELLOW19:def 1;
        thus for A be a_neighborhood of x holds
          ex B be finite Subset of [:NAT,NAT:] st s"(A) = [:NAT,NAT:] \ B
        proof
          let A be a_neighborhood of x;
          A in the set of all A where A is a_neighborhood of x;
          then A in {M where M is Subset of the carrier of T:
            ex A being finite Subset of [:NAT,NAT:] st
            s"(M) = [:NAT,NAT:] \ A} by A2;
          then ex M be Subset of the carrier of T st A = M &
            ex B being finite Subset of [:NAT,NAT:] st
            s"(M) = [:NAT,NAT:] \ B;
          hence thesis;
        end;
      end;
      assume
A3:   for A be a_neighborhood of x holds ex B be finite Subset of
        [:NAT,NAT:] st s"(A) = [:NAT,NAT:] \ B;
      NeighborhoodSystem x c= F
      proof
        let y be object;
        assume y in NeighborhoodSystem x;
        then y in the set of all A where A is a_neighborhood of x
          by YELLOW19:def 1;
        then consider A be a_neighborhood of x such that
A4:     y = A;
        ex B be finite Subset of [:NAT,NAT:] st s"(A) = [:NAT,NAT:] \ B by A3;
        then A in {M where M is Subset of the carrier of T:
          ex A being finite Subset of [:NAT,NAT:] st
          s"(M) = [:NAT,NAT:] \ A};
        hence thesis by A4,Th43;
      end;
      hence F is_filter-finer_than NeighborhoodSystem x;
    end;
    F is_filter-finer_than NeighborhoodSystem x iff x in lim_filter F
    proof
      thus F is_filter-finer_than NeighborhoodSystem x implies
        x in lim_filter F;
      assume x in lim_filter F;
      then ex y be Point of T st x = y &
        F is_filter-finer_than NeighborhoodSystem y;
      hence F is_filter-finer_than NeighborhoodSystem x;
    end;
    hence thesis by A1;
  end;
