reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th53:
  for V being vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct, M
  being Subset of V, z1,z2 being Complex holds z1*(z2*M) = (z1*z2)*M
proof
  let V be vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct;
  let M be Subset of V;
  let z1,z2 be Complex;
  for x being VECTOR of V st x in z1*(z2*M) holds x in (z1*z2)*M
  proof
    let x be VECTOR of V;
    assume x in z1*(z2*M);
    then consider w1 be VECTOR of V such that
A1: x = z1*w1 and
A2: w1 in z2*M;
    consider w2 be VECTOR of V such that
A3: w1 = z2*w2 and
A4: w2 in M by A2;
    x = (z1*z2)*w2 by A1,A3,CLVECT_1:def 4;
    hence thesis by A4;
  end;
  then
A5: z1*(z2*M) c= (z1*z2)*M;
  for x being VECTOR of V st x in (z1*z2)*M holds x in z1*(z2*M)
  proof
    let x be VECTOR of V;
    assume x in (z1*z2)*M;
    then consider w1 be VECTOR of V such that
A6: x = (z1*z2)*w1 & w1 in M;
    x = z1*(z2*w1) & z2*w1 in z2*M by A6,CLVECT_1:def 4;
    hence thesis;
  end;
  then (z1*z2)*M c= z1*(z2*M);
  hence thesis by A5,XBOOLE_0:def 10;
end;
