reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;
reserve f, f1, f2, f3 for PartFunc of REAL, REAL;

theorem
  A c= Z & (for x st x in Z holds (1+sin.x)<>0 & (1-sin.x)<>0 & f.x =
  sin.x/(1+sin.x)) & Z c= dom (id Z-tan+sec) & Z = dom f & f|A is continuous
  implies integral(f,A) =
   (id Z-tan+sec).(upper_bound A)-(id Z-tan+sec).(lower_bound A)
proof
  assume that
A1: A c= Z and
A2: for x st x in Z holds (1+sin.x)<>0 & (1-sin.x)<>0 & f.x = sin.x/(1+
  sin.x) and
A3: Z c= dom (id Z-tan+sec) and
A4: Z = dom f and
A5: f|A is continuous;
A6: f is_integrable_on A by A1,A4,A5,INTEGRA5:11;
A7: for x st x in Z holds (1+sin.x)<>0 & (1-sin.x)<>0 by A2;
  then
A8: (id Z-tan+sec) is_differentiable_on Z by A3,Th53;
A9: for x being Element of REAL
st x in dom ((id Z-tan+sec)`|Z) holds ((id Z-tan+sec)`|Z).x = f.x
  proof
    let x be Element of REAL;
    assume x in dom ((id Z-tan+sec)`|Z);
    then
A10: x in Z by A8,FDIFF_1:def 7;
    then ((id Z-tan+sec)`|Z).x = sin.x/(1+sin.x) by A3,A7,Th53
      .= f.x by A2,A10;
    hence thesis;
  end;
  dom ((id Z-tan+sec)`|Z) = dom f by A4,A8,FDIFF_1:def 7;
  then ((id Z-tan+sec)`|Z) = f by A9,PARTFUN1:5;
  hence thesis by A1,A4,A5,A6,A8,INTEGRA5:10,13;
end;
