reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th54:
  for a,b,c,d being Real st a<b & c <d
  ex f being Function of I[01],(TOP-REAL 2)|(Lower_Arc rectangle(a,b,c,d))
  st f is being_homeomorphism
  & f.0=E-max rectangle(a,b,c,d) & f.1=W-min rectangle(a,b,c,d) &
  rng f=Lower_Arc rectangle(a,b,c,d) &
  (for r being Real st r in [.0,1/2.] holds f.r=(1-2*r)*|[b,d]|+(2*r)*|[b,c]|)&
  (for r being Real st r in [.1/2,1.] holds
  f.r=(1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]|)&
  (for p being Point of TOP-REAL 2 st p in LSeg(|[b,d]|,|[b,c]|)
  holds 0<=((p`2)-d)/(c-d)/2 & ((p`2)-d)/(c-d)/2<=1
  & f.(((p`2)-d)/(c-d)/2)=p)&
  for p being Point of TOP-REAL 2 st p in LSeg(|[b,c]|,|[a,c]|)
  holds 0<=((p`1)-b)/(a-b)/2+1/2 & ((p`1)-b)/(a-b)/2+1/2<=1
  & f.(((p`1)-b)/(a-b)/2+1/2)=p
proof
  let a,b,c,d be Real;
  set K = rectangle(a,b,c,d);
  assume that
A1: a<b and
A2: c <d;
  defpred P[object,object] means for r being Real st $1=r holds
  (r in [.0,1/2.] implies $2=(1-2*r)*|[b,d]|+(2*r)*|[b,c]|) &
  (r in [.1/2,1.] implies $2=(1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]|);
A3: [.0,1.]=[.0,1/2.] \/ [.1/2,1.] by XXREAL_1:165;
A4: for x being object st x in [.0,1.] ex y being object st P[x,y]
  proof
    let x be object;
    assume
A5: x in [.0,1.];
    now per cases by A3,A5,XBOOLE_0:def 3;
      case
A6:     x in [.0,1/2.];
        then reconsider r=x as Real;
A7:     r<=1/2 by A6,XXREAL_1:1;
        set y0= (1-2*r)*|[b,d]|+(2*r)*|[b,c]|;
        r in [.1/2,1.] implies y0=(1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]|
        proof
          assume r in [.1/2,1.];
          then 1/2 <=r by XXREAL_1:1;
          then
A8:       r=1/2 by A7,XXREAL_0:1;
          then
A9:       y0= (0)*|[b,d]|+|[b,c]| by RLVECT_1:def 8
            .= (0.TOP-REAL 2) + |[b,c]| by RLVECT_1:10
            .= |[b,c]| by RLVECT_1:4;
          (1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]|
          = (1)*|[b,c]|+0.TOP-REAL 2 by A8,RLVECT_1:10
            .= |[b,c]|+0.TOP-REAL 2 by RLVECT_1:def 8
            .= |[b,c]| by RLVECT_1:4;
          hence thesis by A9;
        end;
        then for r2 being Real st x=r2 holds
        (r2 in [.0,1/2.] implies y0=(1-2*r2)*|[b,d]|+(2*r2)*|[b,c]|) &
        (r2 in [.1/2,1.] implies y0=(1-(2*r2-1))*|[b,c]|+(2*r2-1)*|[a,c]|);
        hence thesis;
      end;
      case
A10:    x in [.1/2,1.];
        then reconsider r=x as Real;
A11:    1/2<=r by A10,XXREAL_1:1;
        set y0= (1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]|;
        r in [.0,1/2.] implies y0=(1-2*r)*|[b,d]|+(2*r)*|[b,c]|
        proof
          assume r in [.0,1/2.];
          then r<=1/2 by XXREAL_1:1;
          then
A12:      r=1/2 by A11,XXREAL_0:1;
          then
A13:      y0= |[b,c]|+(0)*|[a,c]| by RLVECT_1:def 8
            .= |[b,c]|+(0.TOP-REAL 2) by RLVECT_1:10
            .= |[b,c]| by RLVECT_1:4;
          (1-2*r)*|[b,d]|+(2*r)*|[b,c]|
          = 0.TOP-REAL 2+(1)*|[b,c]| by A12,RLVECT_1:10
            .= 0.TOP-REAL 2+|[b,c]| by RLVECT_1:def 8
            .= |[b,c]| by RLVECT_1:4;
          hence thesis by A13;
        end;
        then for r2 being Real st x=r2 holds
        (r2 in [.0,1/2.] implies y0=(1-2*r2)*|[b,d]|+(2*r2)*|[b,c]|) &
        (r2 in [.1/2,1.] implies y0=(1-(2*r2-1))*|[b,c]|+(2*r2-1)*|[a,c]|);
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  ex f2 being Function st dom f2 = [.0,1.] &
  for x being object st x in [.0,1.] holds P[x,f2.x] from CLASSES1:sch 1(A4);
  then consider f2 being Function such that
A14: dom f2 = [.0,1.] and
A15: for x being object st x in [.0,1.] holds P[x,f2.x];
  rng f2 c= the carrier of (TOP-REAL 2)|(Lower_Arc(K))
  proof
    let y be object;
    assume y in rng f2;
    then consider x being object such that
A16: x in dom f2 and
A17: y=f2.x by FUNCT_1:def 3;
    now per cases by A3,A14,A16,XBOOLE_0:def 3;
      case
A18:    x in [.0,1/2.];
        then reconsider r=x as Real;
A19:    0<=r by A18,XXREAL_1:1;
        r<=1/2 by A18,XXREAL_1:1;
        then
A20:    r*2<=1/2*2 by XREAL_1:64;
        f2.x= (1-2*r)*|[b,d]|+(2*r)*|[b,c]| by A14,A15,A16,A18;
        then
A21:    y in LSeg(|[b,d]|,|[b,c]|) by A17,A19,A20;
        Lower_Arc(K)= LSeg(|[a,c]|,|[b,c]|) \/ LSeg(|[b,c]|,|[b,d]|)
        by A1,A2,Th52;
        then y in Lower_Arc(K) by A21,XBOOLE_0:def 3;
        hence thesis by PRE_TOPC:8;
      end;
      case
A22:    x in [.1/2,1.];
        then reconsider r=x as Real;
A23:    1/2<=r by A22,XXREAL_1:1;
A24:    r<=1 by A22,XXREAL_1:1;
        r*2>=1/2*2 by A23,XREAL_1:64;
        then
A25:    2*r-1>=0 by XREAL_1:48;
        2*1>=2*r by A24,XREAL_1:64;
        then
A26:    1+1-1>=2*r-1 by XREAL_1:9;
        f2.x= (1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]| by A14,A15,A16,A22;
        then
A27:    y in LSeg(|[b,c]|,|[a,c]|) by A17,A25,A26;
        Lower_Arc(K)= LSeg(|[a,c]|,|[b,c]|) \/ LSeg(|[b,c]|,|[b,d]|)
        by A1,A2,Th52;
        then y in Lower_Arc(K) by A27,XBOOLE_0:def 3;
        hence thesis by PRE_TOPC:8;
      end;
    end;
    hence thesis;
  end;
  then reconsider f3=f2 as Function of I[01],(TOP-REAL 2)|(Lower_Arc(K))
  by A14,BORSUK_1:40,FUNCT_2:2;
A28: 0 in [.0,1.] by XXREAL_1:1;
  0 in [.0,1/2.] by XXREAL_1:1;
  then
A29: f3.0= (1-2*0)*|[b,d]|+(2*0)*|[b,c]| by A15,A28
    .= (1)*|[b,d]|+0.TOP-REAL 2 by RLVECT_1:10
    .= |[b,d]|+0.TOP-REAL 2 by RLVECT_1:def 8
    .= |[b,d]| by RLVECT_1:4
    .= E-max(K) by A1,A2,Th46;
A30: 1 in [.0,1.] by XXREAL_1:1;
  1 in [.1/2,1.] by XXREAL_1:1;
  then
A31: f3.1= (1-(2*1-1))*|[b,c]|+(2*1-1)*|[a,c]| by A15,A30
    .= (0)*|[b,c]|+|[a,c]| by RLVECT_1:def 8
    .= (0.TOP-REAL 2) + |[a,c]| by RLVECT_1:10
    .= |[a,c]| by RLVECT_1:4
    .= W-min(K) by A1,A2,Th46;
A32: for r being Real st r in [.0,1/2.] holds
  f3.r=(1-2*r)*|[b,d]|+(2*r)*|[b,c]|
  proof
    let r be Real;
    assume
A33: r in [.0,1/2.];
    then
A34: 0<=r by XXREAL_1:1;
    r<=1/2 by A33,XXREAL_1:1;
    then r<=1 by XXREAL_0:2;
    then r in [.0,1.] by A34,XXREAL_1:1;
    hence thesis by A15,A33;
  end;
A35: for r being Real st r in [.1/2,1.] holds
  f3.r=(1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]|
  proof
    let r be Real;
    assume
A36: r in [.1/2,1.];
    then
A37: 1/2<=r by XXREAL_1:1;
    r<=1 by A36,XXREAL_1:1;
    then r in [.0,1.] by A37,XXREAL_1:1;
    hence thesis by A15,A36;
  end;
A38: for p being Point of TOP-REAL 2 st p in LSeg(|[b,d]|,|[b,c]|)
  holds 0<=((p`2)-d)/(c-d)/2 & ((p`2)-d)/(c-d)/2<=1
  & f3.(((p`2)-d)/(c-d)/2)=p
  proof
    let p be Point of TOP-REAL 2;
    assume
A39: p in LSeg(|[b,d]|,|[b,c]|);
A40: (|[b,d]|)`2= d by EUCLID:52;
A41: (|[b,c]|)`2= c by EUCLID:52;
    then
A42: c <=p`2 by A2,A39,A40,TOPREAL1:4;
A43: p`2<=d by A2,A39,A40,A41,TOPREAL1:4;
    d-c>0 by A2,XREAL_1:50;
    then
A44: -(d-c)< -0 by XREAL_1:24;
    d-(p`2) >=0 by A43,XREAL_1:48;
    then
A45: -(d-(p`2)) <= -0;
    (p`2) -d >=c-d by A42,XREAL_1:9;
    then ((p`2) -d)/(c-d) <=(c-d)/(c-d) by A44,XREAL_1:73;
    then ((p`2) -d)/(c-d) <=1 by A44,XCMPLX_1:60;
    then
A46: ((p`2) -d)/(c-d)/2 <=1/2 by XREAL_1:72;
    set r=((p`2)-d)/(c-d)/2;
    r in [.0,1/2.] by A44,A45,A46,XXREAL_1:1;
    then f3.(((p`2)-d)/(c-d)/2)=(1-2*r)*|[b,d]|+(2*r)*|[b,c]| by A32
      .=|[(1-2*r)*b,(1-2*r)*d]|+(2*r)*|[b,c]| by EUCLID:58
      .=|[(1-2*r)*b,(1-2*r)*d]|+|[(2*r)*b,(2*r)*c]| by EUCLID:58
      .=|[1*b-(2*r)*b+(2*r)*b,(1-2*r)*d+(2*r)*c]| by EUCLID:56
      .=|[b,1*d+(((p`2)-d)/(c-d))*(c-d)]|
      .=|[b,1*d+((p`2)-d)]| by A44,XCMPLX_1:87
      .=|[p`1,p`2]| by A39,TOPREAL3:11
      .= p by EUCLID:53;
    hence thesis by A44,A45,A46,XXREAL_0:2;
  end;
A47: for p being Point of TOP-REAL 2 st p in LSeg(|[b,c]|,|[a,c]|)
  holds 0<=((p`1)-b)/(a-b)/2+1/2 & ((p`1)-b)/(a-b)/2+1/2<=1
  & f3.(((p`1)-b)/(a-b)/2+1/2)=p
  proof
    let p be Point of TOP-REAL 2;
    assume
A48: p in LSeg(|[b,c]|,|[a,c]|);
A49: (|[b,c]|)`1= b by EUCLID:52;
A50: (|[a,c]|)`1= a by EUCLID:52;
    then
A51: a <=p`1 by A1,A48,A49,TOPREAL1:3;
A52: p`1<=b by A1,A48,A49,A50,TOPREAL1:3;
    b-a>0 by A1,XREAL_1:50;
    then
A53: -(b-a)< -0 by XREAL_1:24;
    b-(p`1) >=0 by A52,XREAL_1:48;
    then
A54: -(b-(p`1)) <= -0;
    then
A55: ((p`1) -b)/(a-b)/2+1/2 >=0+1/2 by A53,XREAL_1:7;
    (p`1) -b >=a-b by A51,XREAL_1:9;
    then ((p`1) -b)/(a-b) <=(a-b)/(a-b) by A53,XREAL_1:73;
    then ((p`1) -b)/(a-b) <=1 by A53,XCMPLX_1:60;
    then ((p`1) -b)/(a-b)/2 <=1/2 by XREAL_1:72;
    then
A56: ((p`1) -b)/(a-b)/2+1/2 <=1/2+1/2 by XREAL_1:7;
    set r=((p`1)-b)/(a-b)/2+1/2;
    r in [.1/2,1.] by A55,A56,XXREAL_1:1;
    then f3.(((p`1)-b)/(a-b)/2+1/2)=(1-(2*r-1))*|[b,c]|+(2*r-1)*|[a,c]| by A35
      .=|[(1-(2*r-1))*b,(1-(2*r-1))*c]|+((2*r-1))*|[a,c]| by EUCLID:58
      .=|[(1-(2*r-1))*b,(1-(2*r-1))*c]|+|[((2*r-1))*a,((2*r-1))*c]|
    by EUCLID:58
      .=|[(1-(2*r-1))*b+((2*r-1))*a,1*c-(2*r-1)*c+((2*r-1))*c]| by EUCLID:56
      .=|[1*b+(((p`1)-b)/(a-b))*(a-b),c]|
      .=|[1*b+((p`1)-b),c]| by A53,XCMPLX_1:87
      .=|[p`1,p`2]| by A48,TOPREAL3:12
      .= p by EUCLID:53;
    hence thesis by A53,A54,A56;
  end;
  reconsider B00=[.0,1.] as Subset of R^1 by TOPMETR:17;
  reconsider B01=B00 as non empty Subset of R^1 by XXREAL_1:1;
  I[01]=(R^1)|B01 by TOPMETR:19,20;
  then consider h1 being Function of I[01],R^1 such that
A57: for p being Point of I[01] holds h1.p=p and
A58: h1 is continuous by Th6;
  consider h2 being Function of I[01],R^1 such that
A59: for p being Point of I[01],r1 being Real st h1.p=r1 holds h2.p
  =2*r1 and
A60: h2 is continuous by A58,JGRAPH_2:23;
  consider h5 being Function of I[01],R^1 such that
A61: for p being Point of I[01],r1 being Real st h2.p=r1 holds h5.p
  =1-r1 and
A62: h5 is continuous by A60,Th8;
  consider h3 being Function of I[01],R^1 such that
A63: for p being Point of I[01],r1 being Real st h2.p=r1 holds h3.p
  =r1-1 and
A64: h3 is continuous by A60,Th7;
  consider h4 being Function of I[01],R^1 such that
A65: for p being Point of I[01],r1 being Real st h3.p=r1 holds h4.p
  =1-r1 and
A66: h4 is continuous by A64,Th8;
  consider g1 being Function of I[01],TOP-REAL 2 such that
A67: for r being Point of I[01] holds g1.r=(h5.r)*|[b,d]|+(h2.r)*|[b,c]| and
A68: g1 is continuous by A60,A62,Th13;
A69: for r being Point of I[01],s being Real st r=s holds
  g1.r=(1-2*s)*|[b,d]|+(2*s)*|[b,c]|
  proof
    let r be Point of I[01],s be Real;
    assume
A70: r=s;
    g1.r=(h5.r)*|[b,d]|+(h2.r)*|[b,c]| by A67
      .=(1-2*(h1.r))*|[b,d]|+(h2.r)*|[b,c]| by A59,A61
      .=(1-2*(h1.r))*|[b,d]|+(2*(h1.r))*|[b,c]| by A59
      .=(1-2*s)*|[b,d]|+(2*(h1.r))*|[b,c]| by A57,A70
      .=(1-2*s)*|[b,d]|+(2*s)*|[b,c]| by A57,A70;
    hence thesis;
  end;
  consider g2 being Function of I[01],TOP-REAL 2 such that
A71: for r being Point of I[01] holds g2.r=(h4.r)*|[b,c]|+(h3.r)*|[a,c]| and
A72: g2 is continuous by A64,A66,Th13;
A73: for r being Point of I[01],s being Real st r=s holds
  g2.r=(1-(2*s-1))*|[b,c]|+(2*s-1)*|[a,c]|
  proof
    let r be Point of I[01],s be Real;
    assume
A74: r=s;
    g2.r=(h4.r)*|[b,c]|+(h3.r)*|[a,c]| by A71
      .=(1-((h2.r)-1))*|[b,c]|+(h3.r)*|[a,c]| by A63,A65
      .=(1-((h2.r)-1))*|[b,c]|+((h2.r)-1)*|[a,c]| by A63
      .=(1-(2*(h1.r)-1))*|[b,c]|+((h2.r)-1)*|[a,c]| by A59
      .=(1-(2*(h1.r)-1))*|[b,c]|+(2*(h1.r)-1)*|[a,c]| by A59
      .=(1-(2*s-1))*|[b,c]|+(2*(h1.r)-1)*|[a,c]| by A57,A74
      .=(1-(2*s-1))*|[b,c]|+(2*s-1)*|[a,c]| by A57,A74;
    hence thesis;
  end;
  reconsider B11=[.0,1/2.] as non empty Subset of I[01]
  by A3,BORSUK_1:40,XBOOLE_1:7,XXREAL_1:1;
A75: dom (g1|B11)=dom g1 /\ B11 by RELAT_1:61
    .= (the carrier of I[01]) /\ B11 by FUNCT_2:def 1
    .=B11 by XBOOLE_1:28
    .=the carrier of (I[01]|B11) by PRE_TOPC:8;
  rng (g1|B11) c= the carrier of TOP-REAL 2;
  then reconsider g11=g1|B11 as Function
  of I[01]|B11,TOP-REAL 2 by A75,FUNCT_2:2;
A76: TOP-REAL 2 is SubSpace of TOP-REAL 2 by TSEP_1:2;
  then
A77: g11 is continuous by A68,BORSUK_4:44;
  reconsider B22=[.1/2,1.] as non empty Subset of I[01]
  by A3,BORSUK_1:40,XBOOLE_1:7,XXREAL_1:1;
A78: dom (g2|B22)=dom g2 /\ B22 by RELAT_1:61
    .= (the carrier of I[01]) /\ B22 by FUNCT_2:def 1
    .=B22 by XBOOLE_1:28
    .=the carrier of (I[01]|B22) by PRE_TOPC:8;
  rng (g2|B22) c= the carrier of TOP-REAL 2;
  then reconsider g22=g2|B22 as Function
  of I[01]|B22,TOP-REAL 2 by A78,FUNCT_2:2;
A79: g22 is continuous by A72,A76,BORSUK_4:44;
A80: B11=[#](I[01]|B11) by PRE_TOPC:def 5;
A81: B22=[#](I[01]|B22) by PRE_TOPC:def 5;
A82: B11 is closed by Th4;
A83: B22 is closed by Th4;
A84: [#](I[01]|B11) \/ [#](I[01]|B22)=[#]I[01]
  by A80,A81,BORSUK_1:40,XXREAL_1:165;
  for p being object st p in ([#](I[01]|B11)) /\ ([#](I[01]|B22))
  holds g11.p = g22.p
  proof
    let p be object;
    assume
A85: p in ([#](I[01]|B11)) /\ ([#](I[01]|B22));
    then
A86: p in [#](I[01]|B11) by XBOOLE_0:def 4;
A87: p in [#](I[01]|B22) by A85;
A88: p in B11 by A86,PRE_TOPC:def 5;
A89: p in B22 by A87,PRE_TOPC:def 5;
    reconsider rp=p as Real by A88;
A90: rp<=1/2 by A88,XXREAL_1:1;
    rp>=1/2 by A89,XXREAL_1:1;
    then rp=1/2 by A90,XXREAL_0:1;
    then
A91: 2*rp=1;
    thus g11.p=g1.p by A88,FUNCT_1:49
      .= (1-1)*|[b,d]|+(1)*|[b,c]| by A69,A88,A91
      .=0.TOP-REAL 2 +1*|[b,c]| by RLVECT_1:10
      .=(1-0)*|[b,c]| +(1-1)*|[a,c]| by RLVECT_1:10
      .=g2.p by A73,A88,A91
      .=g22.p by A89,FUNCT_1:49;
  end;
  then consider h being Function of I[01],TOP-REAL 2 such that
A92: h=g11+*g22 and
A93: h is continuous by A77,A79,A80,A81,A82,A83,A84,JGRAPH_2:1;
A94: dom f3=dom h by Th5;
A95: dom f3=the carrier of I[01] by Th5;
  for x being object st x in dom f2 holds f3.x=h.x
  proof
    let x be object;
    assume
A96: x in dom f2;
    then reconsider rx=x as Real by A95;
A97: 0<=rx by A94,A96,BORSUK_1:40,XXREAL_1:1;
A98: rx<=1 by A94,A96,BORSUK_1:40,XXREAL_1:1;
    per cases;
    suppose
A99:  rx<1/2;
      then
A100: rx in [.0,1/2.] by A97,XXREAL_1:1;
      not rx in dom g22 by A81,A99,XXREAL_1:1;
      then h.rx=g11.rx by A92,FUNCT_4:11
        .=g1.rx by A100,FUNCT_1:49
        .=(1-(2*rx))*|[b,d]|+(2*rx)*|[b,c]| by A69,A94,A96
        .=f3.rx by A32,A100;
      hence thesis;
    end;
    suppose rx >=1/2;
      then
A101: rx in [.1/2,1.] by A98,XXREAL_1:1;
      then rx in [#](I[01]|B22) by PRE_TOPC:def 5;
      then h.rx=g22.rx by A78,A92,FUNCT_4:13
        .=g2.rx by A101,FUNCT_1:49
        .=(1-(2*rx-1))*|[b,c]|+(2*rx-1)*|[a,c]| by A73,A94,A96
        .=f3.rx by A35,A101;
      hence thesis;
    end;
  end;
  then
A102: f2=h by A94,FUNCT_1:2;
  for x1,x2 being object st x1 in dom f3 & x2 in dom f3 & f3.x1=f3.x2
holds x1=x2
  proof
    let x1,x2 be object;
    assume that
A103: x1 in dom f3 and
A104: x2 in dom f3 and
A105: f3.x1=f3.x2;
    reconsider r1=x1 as Real by A103;
    reconsider r2=x2 as Real by A104;
A106: LSeg(|[b,d]|,|[b,c]|) /\ LSeg(|[b,c]|,|[a,c]|) = {|[b,c]|} by A1,A2,Th32;
    now per cases by A3,A14,A103,A104,XBOOLE_0:def 3;
      case
A107:   x1 in [.0,1/2.] & x2 in [.0,1/2.];
        then f3.r1=(1-2*r1)*|[b,d]|+(2*r1)*|[b,c]| by A32;
        then (1-2*r2)*|[b,d]|+(2*r2)*|[b,c]|= (1-2*r1)*|[b,d]|+(2*r1)*|[b,c]|
        by A32,A105,A107;
        then (1-2*r2)*|[b,d]|+(2*r2)*|[b,c]| -(2*r1)*|[b,c]|
        = (1-2*r1)*|[b,d]| by RLVECT_4:1;
        then (1-2*r2)*|[b,d]|+((2*r2)*|[b,c]| -(2*r1)*|[b,c]|)
        = (1-2*r1)*|[b,d]| by RLVECT_1:def 3;
        then (1-2*r2)*|[b,d]|+(2*r2-2*r1)*(|[b,c]|)
        = (1-2*r1)*|[b,d]| by RLVECT_1:35;
        then (2*r2-2*r1)*(|[b,c]|)+((1-2*r2)*|[b,d]|-(1-2*r1)*|[b,d]|)
        = (1-2*r1)*|[b,d]|-(1-2*r1)*|[b,d]| by RLVECT_1:def 3;
        then (2*r2-2*r1)*(|[b,c]|)+((1-2*r2)*|[b,d]|-(1-2*r1)*|[b,d]|)
        = 0.TOP-REAL 2 by RLVECT_1:5;
        then (2*r2-2*r1)*(|[b,c]|)+((1-2*r2)-(1-2*r1))*|[b,d]|
        = 0.TOP-REAL 2 by RLVECT_1:35;
        then (2*r2-2*r1)*(|[b,c]|)+(-(2*r2-2*r1))*|[b,d]| = 0.TOP-REAL 2;
        then (2*r2-2*r1)*(|[b,c]|)+-((2*r2-2*r1)*|[b,d]|)
        = 0.TOP-REAL 2 by RLVECT_1:79;
        then (2*r2-2*r1)*(|[b,c]|)-((2*r2-2*r1)*|[b,d]|)
        = 0.TOP-REAL 2;
        then (2*r2-2*r1)*((|[b,c]|)-(|[b,d]|)) = 0.TOP-REAL 2 by RLVECT_1:34;
        then (2*r2-2*r1)=0 or (|[b,c]|)-(|[b,d]|)=0.TOP-REAL 2 by RLVECT_1:11;
        then (2*r2-2*r1)=0 or |[b,c]|=|[b,d]| by RLVECT_1:21;
        then (2*r2-2*r1)=0 or d =|[b,c]|`2 by EUCLID:52;
        hence thesis by A2,EUCLID:52;
      end;
      case
A108:   x1 in [.0,1/2.] & x2 in [.1/2,1.];
        then
A109:   f3.r1=(1-2*r1)*|[b,d]|+(2*r1)*|[b,c]| by A32;
A110:   0<=r1 by A108,XXREAL_1:1;
        r1<=1/2 by A108,XXREAL_1:1;
        then r1*2<=1/2*2 by XREAL_1:64;
        then
A111:   f3.r1 in LSeg(|[b,d]|,|[b,c]|) by A109,A110;
A112:   f3.r2=(1-(2*r2-1))*|[b,c]|+(2*r2-1)*|[a,c]| by A35,A108;
A113:   1/2<=r2 by A108,XXREAL_1:1;
A114:   r2<=1 by A108,XXREAL_1:1;
        r2*2>=1/2*2 by A113,XREAL_1:64;
        then
A115:   2*r2-1>=0 by XREAL_1:48;
        2*1>=2*r2 by A114,XREAL_1:64;
        then 1+1-1>=2*r2-1 by XREAL_1:9;
then f3.r2 in { (1-lambda)*|[b,c]| + lambda*|[a,c]|
          where lambda is Real:
        0 <= lambda & lambda <= 1 } by A112,A115;
        then f3.r1 in LSeg(|[b,d]|,|[b,c]|) /\ LSeg(|[b,c]|,|[a,c]|)
        by A105,A111,XBOOLE_0:def 4;
        then
A116:   f3.r1= |[b,c]| by A106,TARSKI:def 1;
        then (1-2*r1)*|[b,d]|+(2*r1)*|[b,c]|+-(|[b,c]|)=0.TOP-REAL 2
        by A109,RLVECT_1:5;
        then (1-2*r1)*|[b,d]|+(2*r1)*|[b,c]|+(-1)*|[b,c]|=0.TOP-REAL 2
        by RLVECT_1:16;
        then (1-2*r1)*|[b,d]|+((2*r1)*|[b,c]|+(-1)*|[b,c]|)=0.TOP-REAL 2
        by RLVECT_1:def 3;
        then (1-2*r1)*|[b,d]|+((2*r1)+(-1))*|[b,c]|=0.TOP-REAL 2 by
RLVECT_1:def 6;
        then (1-2*r1)*|[b,d]|+(-(1-(2*r1)))*|[b,c]|=0.TOP-REAL 2;
        then (1-2*r1)*|[b,d]|+-((1-(2*r1))*|[b,c]|)=0.TOP-REAL 2 by RLVECT_1:79
;
        then (1-2*r1)*|[b,d]|-((1-(2*r1))*|[b,c]|)=0.TOP-REAL 2;
        then (1-2*r1)*(|[b,d]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:34;
        then 1-2*r1=0 or (|[b,d]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:11;
        then 1-2*r1=0 or |[b,d]|=|[b,c]| by RLVECT_1:21;
        then
A117:   1-2*r1=0 or d =|[b,c]|`2 by EUCLID:52;
        (1-(2*r2-1))*|[b,c]|+(2*r2-1)*|[a,c]|+-(|[b,c]|)=0.TOP-REAL 2
        by A105,A112,A116,RLVECT_1:5;
        then
        (1-(2*r2-1))*|[b,c]|+((2*r2-1))*|[a,c]|+(-1)*|[b,c]|=0.TOP-REAL 2
        by RLVECT_1:16;
        then (2*r2-1) *|[a,c]|+((1-(2*r2-1))*|[b,c]|+(-1)*|[b,c]|)
        =0.TOP-REAL 2
        by RLVECT_1:def 3;
        then (2*r2-1) *|[a,c]|+((1-(2*r2-1))+(-1))*|[b,c]|=0.TOP-REAL 2
        by RLVECT_1:def 6;
        then (2*r2-1) *|[a,c]|+(-(2*r2-1))*|[b,c]|=0.TOP-REAL 2;
        then (2*r2-1) *|[a,c]|+-((2*r2-1)*|[b,c]|)=0.TOP-REAL 2 by RLVECT_1:79;
        then (2*r2-1) *|[a,c]|-((2*r2-1)*|[b,c]|)=0.TOP-REAL 2;
        then (2*r2-1) *(|[a,c]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:34;
        then (2*r2-1)=0 or (|[a,c]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:11;
        then (2*r2-1)=0 or |[a,c]|=|[b,c]| by RLVECT_1:21;
        then (2*r2-1)=0 or a =|[b,c]|`1 by EUCLID:52;
        hence thesis by A1,A2,A117,EUCLID:52;
      end;
      case
A118:   x1 in [.1/2,1.] & x2 in [.0,1/2.];
        then
A119:   f3.r2=(1-2*r2)*|[b,d]|+(2*r2)*|[b,c]| by A32;
A120:   0<=r2 by A118,XXREAL_1:1;
        r2<=1/2 by A118,XXREAL_1:1;
        then r2*2<=1/2*2 by XREAL_1:64;
        then
A121:   f3.r2 in LSeg(|[b,d]|,|[b,c]|) by A119,A120;
A122:   f3.r1=(1-(2*r1-1))*|[b,c]|+(2*r1-1)*|[a,c]| by A35,A118;
A123:   1/2<=r1 by A118,XXREAL_1:1;
A124:   r1<=1 by A118,XXREAL_1:1;
        r1*2>=1/2*2 by A123,XREAL_1:64;
        then
A125:   2*r1-1>=0 by XREAL_1:48;
        2*1>=2*r1 by A124,XREAL_1:64;
        then 1+1-1>=2*r1-1 by XREAL_1:9;
then f3.r1 in { (1-lambda)*|[b,c]| + lambda*|[a,c]|
             where lambda is Real:
        0 <= lambda & lambda <= 1 } by A122,A125;
        then f3.r2 in LSeg(|[b,d]|,|[b,c]|) /\ LSeg(|[b,c]|,|[a,c]|)
        by A105,A121,XBOOLE_0:def 4;
        then
A126:   f3.r2= |[b,c]| by A106,TARSKI:def 1;
        then (1-2*r2)*|[b,d]|+(2*r2)*|[b,c]|+-(|[b,c]|)=0.TOP-REAL 2
        by A119,RLVECT_1:5;
        then (1-2*r2)*|[b,d]|+(2*r2)*|[b,c]|+(-1)*|[b,c]|=0.TOP-REAL 2
        by RLVECT_1:16;
        then (1-2*r2)*|[b,d]|+((2*r2)*|[b,c]|+(-1)*|[b,c]|)=0.TOP-REAL 2
        by RLVECT_1:def 3;
        then (1-2*r2)*|[b,d]|+((2*r2)+(-1))*|[b,c]|=0.TOP-REAL 2 by
RLVECT_1:def 6;
        then (1-2*r2)*|[b,d]|+(-(1-(2*r2)))*|[b,c]|=0.TOP-REAL 2;
        then (1-2*r2)*|[b,d]|+-((1-(2*r2))*|[b,c]|)=0.TOP-REAL 2 by RLVECT_1:79
;
        then (1-2*r2)*|[b,d]|-((1-(2*r2))*|[b,c]|)=0.TOP-REAL 2;
        then (1-2*r2)*(|[b,d]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:34;
        then 1-2*r2=0 or (|[b,d]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:11;
        then 1-2*r2=0 or |[b,d]|=|[b,c]| by RLVECT_1:21;
        then
A127:   1-2*r2=0 or d =|[b,c]|`2 by EUCLID:52;
        (1-(2*r1-1))*|[b,c]|+(2*r1-1)*|[a,c]|+-(|[b,c]|)=0.TOP-REAL 2
        by A105,A122,A126,RLVECT_1:5;
        then
        (1-(2*r1-1))*|[b,c]|+((2*r1-1))*|[a,c]|+(-1)*|[b,c]|=0.TOP-REAL 2
        by RLVECT_1:16;
        then (2*r1-1) *|[a,c]|+((1-(2*r1-1))*|[b,c]|+(-1)*|[b,c]|)
        =0.TOP-REAL 2
        by RLVECT_1:def 3;
        then (2*r1-1) *|[a,c]|+((1-(2*r1-1))+(-1))*|[b,c]|=0.TOP-REAL 2
        by RLVECT_1:def 6;
        then (2*r1-1) *|[a,c]|+(-(2*r1-1))*|[b,c]|=0.TOP-REAL 2;
        then (2*r1-1) *|[a,c]|+-((2*r1-1)*|[b,c]|)=0.TOP-REAL 2 by RLVECT_1:79;
        then (2*r1-1) *|[a,c]|-((2*r1-1)*|[b,c]|)=0.TOP-REAL 2;
        then (2*r1-1) *(|[a,c]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:34;
        then (2*r1-1)=0 or (|[a,c]|-(|[b,c]|))=0.TOP-REAL 2 by RLVECT_1:11;
        then (2*r1-1)=0 or |[a,c]|=|[b,c]| by RLVECT_1:21;
        then (2*r1-1)=0 or a =|[b,c]|`1 by EUCLID:52;
        hence thesis by A1,A2,A127,EUCLID:52;
      end;
      case
A128:   x1 in [.1/2,1.] & x2 in [.1/2,1.];
        then f3.r1=(1-(2*r1-1))*|[b,c]|+((2*r1-1))*|[a,c]| by A35;
        then (1-(2*r2-1))*|[b,c]|+((2*r2-1))*|[a,c]|
        = (1-(2*r1-1))*|[b,c]|+((2*r1-1))*|[a,c]| by A35,A105,A128;
        then (1-(2*r2-1))*|[b,c]|+((2*r2-1))*|[a,c]| -((2*r1-1))*|[a,c]|
        = (1-(2*r1-1))*|[b,c]| by RLVECT_4:1;
        then (1-(2*r2-1))*|[b,c]|+(((2*r2-1))*|[a,c]| -((2*r1-1))*|[a,c]|)
        = (1-(2*r1-1))*|[b,c]| by RLVECT_1:def 3;
        then (1-(2*r2-1))*|[b,c]|+((2*r2-1)-(2*r1-1))*(|[a,c]|)
        = (1-(2*r1-1))*|[b,c]| by RLVECT_1:35;
        then ((2*r2-1)-(2*r1-1))*(|[a,c]|)
        +((1-(2*r2-1))*|[b,c]|-(1-(2*r1-1))*|[b,c]|)
        = (1-(2*r1-1))*|[b,c]|-(1-(2*r1-1))*|[b,c]| by RLVECT_1:def 3;
        then ((2*r2-1)-(2*r1-1))*(|[a,c]|)
        +((1-(2*r2-1))*|[b,c]|-(1-(2*r1-1))*|[b,c]|) = 0.TOP-REAL 2
        by RLVECT_1:5;
        then
        ((2*r2-1)-(2*r1-1))*(|[a,c]|)+((1-(2*r2-1))-(1-(2*r1-1)))*|[b,c]|
        = 0.TOP-REAL 2 by RLVECT_1:35;
        then ((2*r2-1)-(2*r1-1))*(|[a,c]|)+(-((2*r2-1)-(2*r1-1)))*|[b,c]|
        = 0.TOP-REAL 2;
        then ((2*r2-1)-(2*r1-1))*(|[a,c]|)+-(((2*r2-1)-(2*r1-1))*|[b,c]|)
        = 0.TOP-REAL 2 by RLVECT_1:79;
        then ((2*r2-1)-(2*r1-1))*(|[a,c]|)-(((2*r2-1)-(2*r1-1))*|[b,c]|)
        = 0.TOP-REAL 2;
        then ((2*r2-1)-(2*r1-1))*((|[a,c]|)-(|[b,c]|))
        = 0.TOP-REAL 2 by RLVECT_1:34;
        then ((2*r2-1)-(2*r1-1))=0 or (|[a,c]|)-(|[b,c]|)=0.TOP-REAL 2
        by RLVECT_1:11;
        then ((2*r2-1)-(2*r1-1))=0 or |[a,c]|=|[b,c]| by RLVECT_1:21;
        then ((2*r2-1)-(2*r1-1))=0 or a =|[b,c]|`1 by EUCLID:52;
        hence thesis by A1,EUCLID:52;
      end;
    end;
    hence thesis;
  end;
  then
A129: f3 is one-to-one by FUNCT_1:def 4;
  [#]((TOP-REAL 2)|(Lower_Arc(K))) c= rng f3
  proof
    let y be object;
    assume y in [#]((TOP-REAL 2)|(Lower_Arc(K)));
    then
A130: y in Lower_Arc(K) by PRE_TOPC:def 5;
    then reconsider q=y as Point of TOP-REAL 2;
A131: Lower_Arc(K)=LSeg(|[b,d]|,|[b,c]|) \/ LSeg(|[b,c]|,|[a,c]|) by A1,A2,Th52
    ;
    now per cases by A130,A131,XBOOLE_0:def 3;
      case
A132:   q in LSeg(|[b,d]|,|[b,c]|);
        then
A133:   0<=((q`2)-d)/(c-d)/2 by A38;
A134:   ((q`2)-d)/(c-d)/2<=1 by A38,A132;
A135:   f3.(((q`2)-d)/(c-d)/2)=q by A38,A132;
        ((q`2)-d)/(c-d)/2 in [.0,1.] by A133,A134,XXREAL_1:1;
        hence thesis by A14,A135,FUNCT_1:def 3;
      end;
      case
A136:   q in LSeg(|[b,c]|,|[a,c]|);
        then
A137:   0<=((q`1)-b)/(a-b)/2+1/2 by A47;
A138:   ((q`1)-b)/(a-b)/2+1/2<=1 by A47,A136;
A139:   f3.(((q`1)-b)/(a-b)/2+1/2)=q by A47,A136;
        ((q`1)-b)/(a-b)/2+1/2 in [.0,1.] by A137,A138,XXREAL_1:1;
        hence thesis by A14,A139,FUNCT_1:def 3;
      end;
    end;
    hence thesis;
  end;
  then
A140: rng f3=[#]((TOP-REAL 2)|(Lower_Arc K));
  I[01] is compact by HEINE:4,TOPMETR:20;
  then
A141: f3 is being_homeomorphism
  by A93,A102,A129,A140,COMPTS_1:17,JGRAPH_1:45;
  rng f3=Lower_Arc(K) by A140,PRE_TOPC:def 5;
  hence thesis by A29,A31,A32,A35,A38,A47,A141;
end;
