reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th41:
  for a being Real,n being Nat, P being Subset of
TOP-REAL n st n>=1 & P=(REAL n)\ {q where q is Point of TOP-REAL n: |.q.| < a }
  holds not P is bounded
proof
  let a be Real,n be Nat,P be Subset of TOP-REAL n;
  assume that
A1: n>=1 and
A2: P=(REAL n)\ {q where q is Point of TOP-REAL n : |.q.| < a };
  per cases;
  suppose
A3: a>0;
    now
      set p = the Element of P;
      assume P is bounded;
      then consider r being Real such that
A4:   for q being Point of TOP-REAL n st q in P holds |.q.|<r by Th21;
A5:   P<>{} by A1,A2,Th39;
      then p in P;
      then reconsider p as Point of TOP-REAL n;
A6:   |.p.|<r by A4,A5;
A7:   now
        assume not (a+r+1)*(1.REAL n) in (REAL n) \{q where q is Point of
        TOP-REAL n: (|.q.|) < a };
        then
A8:     not ((a+r+1)*(1.REAL n) in (REAL n) & not (a+r+1)*(1.REAL n) in {
        q where q is Point of TOP-REAL n : (|.q.|) < a }) by XBOOLE_0:def 5;
        (a+r+1)*(1.REAL n) in the carrier of TOP-REAL n;
        then
A9:     ex q being Point of TOP-REAL n st q= (a+r+1)*(1.REAL n) & (|.q.|)
        < a by A8,EUCLID:22;
A10:    a+r+1<=|.a+r+1.| by ABSVALUE:4;
        a+r<a+r+1 & a<a+r by A6,XREAL_1:29;
        then
A11:    a<a+r+1 by XXREAL_0:2;
        |.a+r+1.|>=0 & sqrt 1<=sqrt n by A1,COMPLEX1:46,SQUARE_1:26;
        then
A12:    |.a+r+1.|*1<=|.a+r+1.|*sqrt n by XREAL_1:64;
        |.(a+r+1)*(1.REAL n).|=|.a+r+1.|*|.(1.REAL n).| by TOPRNS_1:7
          .=|.a+r+1.|*(sqrt n) by EUCLID:73;
        then a+r+1<= |.(a+r+1)*(1.REAL n).| by A12,A10,XXREAL_0:2;
        hence contradiction by A9,A11,XXREAL_0:2;
      end;
A13:  a+r+1<=|.a+r+1.| by ABSVALUE:4;
      |.a+r+1.|>=0 & sqrt 1<=sqrt n by A1,COMPLEX1:46,SQUARE_1:26;
      then
A14:  |.a+r+1.|*1<=|.a+r+1.|*sqrt n by XREAL_1:64;
A15:  a+r<a+r+1 by XREAL_1:29;
      |.(a+r+1)*(1.REAL n).| =|.a+r+1.|*|.(1.REAL n).| by TOPRNS_1:7
        .=|.a+r+1.|*(sqrt n) by EUCLID:73;
      then a+r+1<= |.(a+r+1)*(1.REAL n).| by A14,A13,XXREAL_0:2;
      then
A16:  a+r<|.((a+r+1)*(1.REAL n)).| by A15,XXREAL_0:2;
      r<r+a by A3,XREAL_1:29;
      hence contradiction by A2,A4,A7,A16,XXREAL_0:2;
    end;
    hence thesis;
  end;
  suppose
A17: a<=0;
    now
      {q where q is Point of TOP-REAL n: (|.q.|) < a } c= the carrier of
      TOP-REAL n
      proof
        let z be object;
        assume z in {q where q is Point of TOP-REAL n: (|.q.|) < a };
        then ex q being Point of TOP-REAL n st q=z & (|.q.|) < a;
        hence thesis;
      end;
      then reconsider
      Q={q where q is Point of TOP-REAL n: (|.q.|) < a } as Subset
      of TOP-REAL n;
      set d = the Element of Q;
      assume {q where q is Point of TOP-REAL n: (|.q.|) < a }<>{};
      then d in {q where q is Point of TOP-REAL n: (|.q.|) < a };
      then ex q being Point of TOP-REAL n st q=d & (|.q.|) < a;
      hence contradiction by A17;
    end;
    then P=[#](TOP-REAL n) by A2,EUCLID:22;
    hence thesis by A1,Th22;
  end;
end;
