reserve x, y for object, X for set,
  i, j, k, l, n, m for Nat,
  D for non empty set,
  K for commutative Ring,
  a,b for Element of K,
  perm, p, q for Element of Permutations(n),
  Perm,P for Permutation of Seg n,
  F for Function of Seg n,Seg n,
  perm2, p2, q2, pq2 for Element of Permutations(n+2),
  Perm2 for Permutation of Seg (n+2);
reserve s for Element of 2Set Seg (n+2);
reserve pD for FinSequence of D,
  M for Matrix of n,m,D,
  pK,qK for FinSequence of K,
  A for Matrix of n,K;

theorem Th54:
  not F in Permutations(n) implies Det(A*F) = 0.K
proof
  assume not F in Permutations(n);
  then
A1: F is not onto or F is not one-to-one by MATRIX_1:def 12;
  card Seg n=card Seg n;
  then F is not one-to-one by A1,FINSEQ_4:63;
  then consider x,y being object such that
A2: x in dom F and
A3: y in dom F and
A4: F.x = F.y and
A5: x<>y by FUNCT_1:def 4;
A6: dom F=Seg n by FUNCT_2:52;
  then reconsider x,y as Nat by A2,A3;
  Line(A*F,x)=A.(F.x) by A2,A6,Th38;
  then
A7: Line(A*F,x)=Line(A*F,y) by A3,A4,A6,Th38;
  x>y or y>x by A5,XXREAL_0:1;
  hence thesis by A2,A3,A6,A7,Th50;
end;
