
theorem Th49:
for X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
 M1 be sigma_Measure of S1,
 A be Element of S1, B be Element of S2, y be Element of X2 holds
  M1.A * chi(B,X2).y = Integral(M1,ProjMap2(chi([:A,B:],[:X1,X2:]),y))
proof
   let X1,X2 be non empty set, S1 be SigmaField of X1,
   S2 be SigmaField of X2,
   M1 be sigma_Measure of S1,
   A be Element of S1, B be Element of S2, y be Element of X2;
A1:for x be Element of X1 holds
    ProjMap2(chi([:A,B:],[:X1,X2:]),y).x = chi(A,X1).x * chi(B,X2).y
   proof
    let x be Element of X1;
    ProjMap2(chi([:A,B:],[:X1,X2:]),y).x = chi([:A,B:],[:X1,X2:]).(x,y)
      by MESFUNC9:def 7;
    hence thesis by MEASUR10:2;
   end;
   set CAB = chi([:A,B:],[:X1,X2:]);
   per cases;
   suppose y in B; then
A2: chi(B,X2).y = 1 by FUNCT_3:def 3; then
A3: M1.A * chi(B,X2).y = M1.A by XXREAL_3:81;
A4: dom (ProjMap2(chi([:A,B:],[:X1,X2:]),y)) = X1 by FUNCT_2:def 1
       .= dom chi(A,X1) by FUNCT_3:def 3;
    for x be Element of X1 st x in dom(ProjMap2(CAB,y)) holds
      ProjMap2(CAB,y).x = chi(A,X1).x
    proof
     let x be Element of X1;
     assume x in dom(ProjMap2(CAB,y));
     ProjMap2(CAB,y).x = chi(A,X1).x * chi(B,X2).y by A1;
     hence ProjMap2(CAB,y).x = chi(A,X1).x by A2,XXREAL_3:81;
    end; then
    ProjMap2(CAB,y) = chi(A,X1) by A4,PARTFUN1:5;
    hence M1.A * chi(B,X2).y = Integral(M1,ProjMap2(CAB,y))
       by A3,MESFUNC9:14;
   end;
   suppose not y in B; then
A5: chi(B,X2).y = 0 by FUNCT_3:def 3; then
A6: M1.A * chi(B,X2).y = 0;
A7: {} is Element of S1 by PROB_1:4;
A8: dom(ProjMap2(CAB,y)) = X1 by FUNCT_2:def 1
       .= dom chi({},X1) by FUNCT_3:def 3;
    for x be Element of X1 st x in dom(ProjMap2(CAB,y)) holds
      ProjMap2(CAB,y).x = chi({},X1).x
    proof
     let x be Element of X1;
     assume x in dom(ProjMap2(CAB,y));
     ProjMap2(CAB,y).x = chi(A,X1).x * chi(B,X2).y by A1; then
     ProjMap2(CAB,y).x = 0 by A5;
     hence ProjMap2(CAB,y).x = chi({},X1).x by FUNCT_3:def 3;
    end; then
    ProjMap2(CAB,y) = chi({},X1) by A8,PARTFUN1:5; then
    Integral(M1,ProjMap2(CAB,y)) = M1.{} by A7,MESFUNC9:14;
    hence M1.A * chi(B,X2).y = Integral(M1,ProjMap2(CAB,y))
      by A6,VALUED_0:def 19;
   end;
end;
