
theorem Th54:
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
  g be PartFunc of [:[:REAL,REAL:],REAL:],REAL st [:[:I,J:],K:] = dom g
holds Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x)|(REAL\J)) = 0
proof
    let x be Element of REAL;
    let I,J,K be non empty closed_interval Subset of REAL,
    g be PartFunc of [:[:REAL,REAL:],REAL:],REAL;
    assume
A1: [:[:I,J:],K:] = dom g;

    set Rf = R_EAL g;
    set F2 = Integral2(L-Meas,Rf);

A2: dom Rf = [:[:I,J:],K:] by A1,MESFUNC5:def 7;
A3: dom F2 = [:REAL,REAL:] by FUNCT_2:def 1;
    [#]REAL = REAL by SUBSET_1:def 3; then
A4: dom ProjPMap1(F2,x) = REAL by A3,MESFUN16:25;

A5: J is Element of L-Field by MEASUR10:5,MEASUR12:75;

    set NJ = REAL \ J;
    REAL in L-Field by PROB_1:5; then
A6: NJ is Element of L-Field by A5,PROB_1:6;

    set RL = ProjPMap1(F2,x);
    reconsider RL0 = RL|J as PartFunc of REAL,ExtREAL;
    reconsider RL1=RL| NJ  as PartFunc of REAL,ExtREAL;

    now let y be Element of REAL;
     assume
A7:  y in dom RL1;
     y in REAL & not y in J by A4,A7,XBOOLE_0:def 5; then
     not [x,y] in [:I,J:] by ZFMISC_1:87; then
A8:  dom ProjPMap1(Rf,[x,y]) = {} by A2,MESFUN16:25;

     [x,y] in [:REAL,REAL:]; then
A9: [x,y] in dom F2 by FUNCT_2:def 1;
     RL1.y = ProjPMap1(F2,x).y by A4,A7,FUNCT_1:49; then
A10: RL1.y = F2.(x,y) by A9,MESFUN12:def 3;
     F2.(x,y) = Integral(L-Meas,ProjPMap1(Rf,[x,y])) by MESFUN12:def 8;
     hence RL1.y = 0 by A8,A10,MESFUN16:1;
    end;
    hence thesis by A4,A6,MESFUN12:57;
end;
