
theorem Th54:
  for W being with_non-empty_element set holds
  W-CL_category, W-CL-opp_category are_anti-isomorphic_under W LowerAdj
proof
  let W be with_non-empty_element set;
  set A1 = W-INF_category, A2 = W-SUP_category;
  reconsider B1 = W-CL_category as non empty subcategory of A1 by ALTCAT_4:36;
  reconsider B2 = W-CL-opp_category as non empty subcategory of A2
  by ALTCAT_4:36;
  set F = W LowerAdj;
A1: ex a being non empty set st a in W by SETFAM_1:def 10;
A2: for a being Object of A1 holds a is Object of B1 iff F.a is Object of B2
  proof
    let a be Object of A1;
A3: F.a = latt a by Def6;
A4: the carrier of latt a in W by A1,Def4;
    then a is Object of B1 iff latt a is strict complete continuous by Th48;
    hence thesis by A3,A4,Th50;
  end;
A5: now
    let a,b be Object of A1 such that
A6: <^a,b^> <> {};
    let a1,b1 be Object of B1 such that
A7: a1 = a and
A8: b1 = b;
    let a2,b2 be Object of B2 such that
A9: a2 = F.a and
A10: b2 = F.b;
    let f be Morphism of a,b;
A11: @f = f by A6,YELLOW21:def 7;
A12: F.a = latt a by Def6;
A13: F.b = latt b by Def6;
A14: F.f = LowerAdj @f by A6,Def6;
    reconsider g = f as infs-preserving Function
    of latt a1, latt b1 by A1,A6,A7,A8,A11,Def4;
A15: UpperAdj LowerAdj g = g by Th10;
    then f in <^a1,b1^> iff UpperAdj LowerAdj g is directed-sups-preserving
    by Th49;
    hence f in <^a1,b1^> implies F.f in <^b2,a2^> by A7,A8,A9,A10,A11,A12,A13
,A14,Th51;
    assume F.f in <^b2,a2^>;
    then ex g being sups-preserving Function of latt b2, latt a2 st F.f = g &
    UpperAdj g is directed-sups-preserving by Th51;
    hence f in <^a1,b1^> by A7,A8,A9,A10,A11,A12,A13,A14,A15,Th49;
  end;
  B1,B2 are_anti-isomorphic_under F by A2,A5,YELLOW20:57;
  hence thesis;
end;
