reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th54:
  for V being vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct, M1,M2
  being Subset of V, z being Complex holds z*(M1 + M2) = z*M1 + z*M2
proof
  let V be vector-distributive scalar-distributive scalar-associative
  scalar-unital non empty CLSStruct;
  let M1,M2 be Subset of V;
  let z be Complex;
  for x being VECTOR of V st x in z*M1 + z*M2 holds x in z*(M1+M2)
  proof
    let x be VECTOR of V;
    assume x in z*M1 + z*M2;
    then consider w1,w2 be VECTOR of V such that
A1: x = w1 + w2 and
A2: w1 in z*M1 and
A3: w2 in z*M2;
    consider v2 be VECTOR of V such that
A4: w2 = z * v2 and
A5: v2 in M2 by A3;
    consider v1 be VECTOR of V such that
A6: w1 = z * v1 and
A7: v1 in M1 by A2;
A8: v1 + v2 in M1 + M2 by A7,A5;
    x = z*(v1 + v2) by A1,A6,A4,CLVECT_1:def 2;
    hence thesis by A8;
  end;
  then
A9: z*M1 + z*M2 c= z*(M1+M2);
  for x being VECTOR of V st x in z*(M1+M2) holds x in z*M1 + z*M2
  proof
    let x be VECTOR of V;
    assume x in z*(M1+M2);
    then consider w9 be VECTOR of V such that
A10: x = z*w9 and
A11: w9 in M1 + M2;
    consider w1,w2 be VECTOR of V such that
A12: w9 = w1 + w2 and
A13: w1 in M1 & w2 in M2 by A11;
A14: z*w1 in z*M1 & z*w2 in z*M2 by A13;
    x = z*w1 + z*w2 by A10,A12,CLVECT_1:def 2;
    hence thesis by A14;
  end;
  then z*(M1 + M2) c= z*M1 + z*M2;
  hence thesis by A9,XBOOLE_0:def 10;
end;
