
theorem GauF05:
for a,b be Real, f be Function of REAL,REAL st
(b<>0 & for x be Real holds f.x= exp_R(-(x-a)^2/(2*b^2)))
holds
f is continuous
proof
 let a,b be Real;
 let f be Function of REAL,REAL;
 assume b<>0;
 assume A1:for x be Real holds f.x= exp_R(-(x-a)^2/(2*b^2));
 set h = AffineMap(1,-a);
 set g = (-1)/(2*b^2) (#) h (#) h;
 D1: dom(g) = REAL /\ REAL by FUNCT_2:def 1;
 f=exp_R * ((-1)/(2*b^2) (#) h (#) h)
 proof
  dom (exp_R * g) = REAL by FUNCT_2:def 1; then
  A21:dom f = dom (exp_R * ((-1)/(2*b^2) (#) h (#) h)) by FUNCT_2:def 1;
  ( for x being object st x in dom f holds
  f . x = (exp_R * ((-1)/(2*b^2) (#) h (#) h)). x )
  proof
   let x be object;
   assume S2a: x in dom f; then
   x in REAL by FUNCT_2:def 1; then
   reconsider x as Real;
   S1:x in dom (g) by D1,FUNCT_2:def 1,S2a;
   (exp_R * ((-1)/(2*b^2) (#) h (#) h)). x
   = exp_R.(((-1)/(2*b^2) (#) h (#) h). x) by FUNCT_1:13,S1
   .=exp_R.(((-1)/(2*b^2) (#) h).x * h. x  ) by VALUED_1:5
   .=exp_R.(((-1)/(2*b^2)) * h.x * h. x  ) by VALUED_1:6
   .=exp_R.(((-1)/(2*b^2)) * h.x * (1*x+(-a))  ) by FCONT_1:def 4
   .=exp_R.(((-1)/(2*b^2)) * (1*x+(-a)) * (x-a)  ) by FCONT_1:def 4
   .=exp_R(((-1)/(2*b^2)) * ((x-a) * (x-a))  ) by SIN_COS:def 23
   .=exp_R(((x-a) * (x-a)) /(2*b^2)*(-1) ) by XCMPLX_1:75
   .= exp_R(-(x-a)^2/(2*b^2));
   hence thesis by A1;
  end;
  hence thesis by FUNCT_1:2,A21;
 end;
 hence thesis;
end;
