 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
A c= Z & (for x st x in Z holds f.x=cos.(cos.x)*sin.x)
 & Z = dom f & f|A is continuous
implies integral(f,A)=(-sin*cos).(upper_bound A)-(-sin*cos).(lower_bound A)
proof
   assume
A1:A c= Z & (for x st x in Z holds f.x=cos.(cos.x)*sin.x)
   & Z = dom f & f|A is continuous; then
A2:f is_integrable_on A & f|A is bounded by INTEGRA5:10,11;
   dom cos = REAL & rng cos c= dom cos & dom sin = dom cos by SIN_COS:24;
   then
dom (sin*cos) = REAL by RELAT_1:27;
then A3: dom (-sin*cos) = REAL by VALUED_1:8;
A4:sin*cos is_differentiable_on Z by FDIFF_10:8;
then A5:(-1)(#)(sin*cos) is_differentiable_on Z by A3,FDIFF_1:20;
A6:for x st x in Z holds ((-sin*cos)`|Z).x = cos.(cos.x)*sin.x
  proof
    let x;
    assume
A7:x in Z;
  ((-sin*cos)`|Z).x=((-1)(#)((sin*cos)`|Z)).x by A4,FDIFF_2:19
   .=(-1)*(((sin*cos)`|Z).x) by VALUED_1:6
   .=(-1)*((-cos.(cos.x)*sin.x)) by A7,FDIFF_10:8
   .=cos.(cos.x)*sin.x;
     hence thesis;
   end;
A8:for x being Element of REAL st x in dom ((-sin*cos)`|Z)
holds ((-sin*cos)`|Z).x=f.x
  proof
    let x be Element of REAL;
    assume x in dom ((-sin*cos)`|Z);then
A9:x in Z by A5,FDIFF_1:def 7;then
  ((-sin*cos)`|Z).x = cos.(cos.x)*sin.x by A6
  .= f.x by A1,A9;
   hence thesis;
   end;
  dom ((-sin*cos)`|Z)=dom f by A1,A5,FDIFF_1:def 7;
  then ((-sin*cos)`|Z)= f by A8,PARTFUN1:5;
  hence thesis by A1,A2,A5,INTEGRA5:13;
end;
