reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th55:
  for a,b,c,d being Real,p1,p2 being Point of TOP-REAL 2 st a<b & c <d
  & p1 in LSeg(|[a,c]|,|[a,d]|) & p2 in LSeg(|[a,c]|,|[a,d]|)
  holds LE p1,p2,rectangle(a,b,c,d) iff p1`2<=p2`2
proof
  let a,b,c,d be Real,p1,p2 be Point of TOP-REAL 2;
  set K = rectangle(a,b,c,d);
  assume that
A1: a<b and
A2: c <d and
A3: p1 in LSeg(|[a,c]|,|[a,d]|) and
A4: p2 in LSeg(|[a,c]|,|[a,d]|);
A5: K is being_simple_closed_curve by A1,A2,Th50;
A6: p1`1=a by A2,A3,Th1;
A7: c <=p1`2 by A2,A3,Th1;
A8: p2`1=a by A2,A4,Th1;
A9: E-max(K)= |[b,d]| by A1,A2,Th46;
A10: Upper_Arc(K)=LSeg(|[a,c]|,|[a,d]|) \/ LSeg(|[a,d]|,|[b,d]|) by A1,A2,Th51;
  then
A11: LSeg(|[a,c]|,|[a,d]|) c= Upper_Arc(K) by XBOOLE_1:7;
A12: Upper_Arc(K) /\ Lower_Arc(K)={W-min(K),E-max(K)} by A5,JORDAN6:def 9;
A13: now
    assume p2 in Lower_Arc(K);
    then
A14: p2 in Upper_Arc(K) /\ Lower_Arc(K) by A4,A11,XBOOLE_0:def 4;
    now
      assume p2=E-max(K);
      then p2`1=b by A9,EUCLID:52;
      hence contradiction by A1,A4,TOPREAL3:11;
    end;
    hence p2=W-min(K) by A12,A14,TARSKI:def 2;
  end;
  thus LE p1,p2,K implies p1`2<=p2`2
  proof
    assume LE p1,p2,K;
    then
A15: p1 in Upper_Arc(K) & p2 in Lower_Arc(K)& not p2=W-min(K) or
    p1 in Upper_Arc(K) & p2 in Upper_Arc(K) &
    LE p1,p2,Upper_Arc(K),W-min(K),E-max(K) or
    p1 in Lower_Arc(K) & p2 in Lower_Arc(K)& not p2=W-min(K) &
    LE p1,p2,Lower_Arc(K),E-max(K),W-min(K) by JORDAN6:def 10;
    consider f being Function of I[01],(TOP-REAL 2)|(Upper_Arc(K)) such that
A16: f is being_homeomorphism and
A17: f.0=W-min(K) and
A18: f.1=E-max(K) and rng f=Upper_Arc(K)
    and for r being Real st r in [.0,1/2.] holds f.r=(1-2*r)*|[a,c]|+(2*r)
    *|[a,d]|
    and for r being Real st r in [.1/2,1.] holds f.r=(1-(2*r-1))*|[a,d]|+(
    2*r-1)*|[b,d]| and
A19: for p being Point of TOP-REAL 2 st p in LSeg(|[a,c]|,|[a,d]|)
    holds 0<=((p`2)-c)/(d-c)/2 & ((p`2)-c)/(d-c)/2<=1 & f.(((p`2)-c)/(d-c)/2)=p
    and for p being Point of TOP-REAL 2 st p in LSeg(|[a,d]|,|[b,d]|)
holds 0<=((p`1)-a)/(b-a)/2+1/2 & ((p`1)-a)/(b-a)/2+1/2<=1 & f.(((p`1)-a)/(b-a)/
    2+1/2)=p
    by A1,A2,Th53;
    reconsider s1=((p1`2)-c)/(d-c)/2,s2=((p2`2)-c)/(d-c)/2 as Real;
A20: f.s1=p1 by A3,A19;
A21: f.s2=p2 by A4,A19;
A22: d-c >0 by A2,XREAL_1:50;
A23: s1<=1 by A3,A19;
A24: 0<=s2 by A4,A19;
    s2<=1 by A4,A19;
    then s1<=s2 by A13,A15,A16,A17,A18,A20,A21,A23,A24,JORDAN5C:def 3;
    then ((p1`2)-c)/(d-c)/2*2<=((p2`2)-c)/(d-c)/2*2 by XREAL_1:64;
    then ((p1`2)-c)/(d-c)*(d-c)<= ((p2`2)-c)/(d-c)*(d-c) by A22,XREAL_1:64;
    then ((p1`2)-c)<= ((p2`2)-c)/(d-c)*(d-c) by A22,XCMPLX_1:87;
    then ((p1`2)-c)<= ((p2`2)-c) by A22,XCMPLX_1:87;
    then ((p1`2)-c)+c <= ((p2`2)-c)+c by XREAL_1:7;
    hence thesis;
  end;
  thus p1`2<=p2`2 implies LE p1,p2,K
  proof
    assume
A25: p1`2<=p2`2;
    for g being Function of I[01], (TOP-REAL 2)|Upper_Arc(K),
    s1, s2 being Real st g is being_homeomorphism & g.0 = W-min(K) &
    g.1 = E-max(K)
    & g.s1 = p1 & 0 <= s1 & s1 <= 1 & g.s2 = p2 & 0 <= s2 & s2 <= 1
    holds s1 <= s2
    proof
      let g be Function of I[01], (TOP-REAL 2)|Upper_Arc(K),
          s1, s2 be Real;
      assume that
A26:  g is being_homeomorphism and
A27:  g.0 = W-min(K) and g.1 = E-max(K) and
A28:  g.s1 = p1 and
A29:  0 <= s1 and
A30:  s1 <= 1 and
A31:  g.s2 = p2 and
A32:  0 <= s2 and
A33:  s2 <= 1;
A34:  dom g=the carrier of I[01] by FUNCT_2:def 1;
A35:  g is one-to-one by A26,TOPS_2:def 5;
      A36:  the
 carrier of ((TOP-REAL 2)|Upper_Arc(K)) =Upper_Arc(K) by PRE_TOPC:8;
      then reconsider g1=g as Function of I[01],TOP-REAL 2 by FUNCT_2:7;
      g is continuous by A26,TOPS_2:def 5;
      then
A37:  g1 is continuous by PRE_TOPC:26;
      reconsider h1=proj1 as Function of TOP-REAL 2,R^1 by TOPMETR:17;
      reconsider h2=proj2 as Function of TOP-REAL 2,R^1 by TOPMETR:17;
      reconsider hh1=h1 as Function of the TopStruct of TOP-REAL 2,R^1;
      reconsider hh2=h2 as Function of the TopStruct of TOP-REAL 2,R^1;
A38:  the TopStruct of TOP-REAL 2
      = (the TopStruct of TOP-REAL 2)|([#](the TopStruct of TOP-REAL 2))
      by TSEP_1:3
        .= the TopStruct of ((TOP-REAL 2)|([#](TOP-REAL 2))) by PRE_TOPC:36
        .= (TOP-REAL 2)|([#](TOP-REAL 2));
      then (for p being Point of (TOP-REAL 2)|([#](TOP-REAL 2)) holds
      hh1.p=proj1.p) implies hh1 is continuous by JGRAPH_2:29;
      then
A39:  (for p being Point of (TOP-REAL 2)|([#]TOP-REAL 2)holds
      hh1.p=proj1.p) implies h1 is continuous by PRE_TOPC:32;
      (for p being Point of (TOP-REAL 2)|([#](TOP-REAL 2)) holds
      hh2.p=proj2.p) implies hh2 is continuous by A38,JGRAPH_2:30;
      then (for p being Point of (TOP-REAL 2)|([#](TOP-REAL 2)) holds
      hh2.p=proj2.p) implies h2 is continuous by PRE_TOPC:32;
      then consider h being Function of TOP-REAL 2,R^1 such that
A40:  for p being Point of TOP-REAL 2, r1,r2 being Real st hh1.p=r1 &
      hh2.p=r2 holds h.p=r1+r2 and
A41:  h is continuous by A39,JGRAPH_2:19;
      reconsider k=h*g1 as Function of I[01],R^1;
A42:  W-min K=|[a,c]| by A1,A2,Th46;
      now
        assume
A43:    s1>s2;
A44:    dom g=[.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
        0 in [.0,1.] by XXREAL_1:1;
        then
A45:    k.0=h.(W-min(K)) by A27,A44,FUNCT_1:13
          .=h1.(W-min(K))+h2.(W-min(K)) by A40
          .=(W-min(K))`1+proj2.(W-min(K)) by PSCOMP_1:def 5
          .=(W-min(K))`1+(W-min(K))`2 by PSCOMP_1:def 6
          .=a+(W-min(K))`2 by A42,EUCLID:52
          .=a+c by A42,EUCLID:52;
        s1 in [.0,1.] by A29,A30,XXREAL_1:1;
        then
A46:    k.s1=h.p1 by A28,A44,FUNCT_1:13
          .=h1.p1+h2.p1 by A40
          .=p1`1+proj2.p1 by PSCOMP_1:def 5
          .=a+p1`2 by A6,PSCOMP_1:def 6;
A47:    s2 in [.0,1.] by A32,A33,XXREAL_1:1;
        then
A48:    k.s2=h.p2 by A31,A44,FUNCT_1:13
          .=h1.p2+h2.p2 by A40
          .=p2`1+proj2.p2 by PSCOMP_1:def 5
          .=a+p2`2 by A8,PSCOMP_1:def 6;
A49:    k.0<=k.s1 by A7,A45,A46,XREAL_1:7;
A50:    k.s1<=k.s2 by A25,A46,A48,XREAL_1:7;
A51:    0 in [.0,1.] by XXREAL_1:1;
        then
A52:    [.0,s2.] c= [.0,1.] by A47,XXREAL_2:def 12;
        reconsider B=[.0,s2.] as Subset of I[01] by A47,A51,BORSUK_1:40
,XXREAL_2:def 12;
A53:    B is connected by A32,A47,A51,BORSUK_1:40,BORSUK_4:24;
A54:    0 in B by A32,XXREAL_1:1;
A55:    s2 in B by A32,XXREAL_1:1;
        consider xc being Point of I[01] such that
A56:    xc in B and
A57:    k.xc =k.s1 by A37,A41,A49,A50,A53,A54,A55,TOPREAL5:5;
        reconsider rxc=xc as Real;
A58:    for x1,x2 being set st x1 in dom k & x2 in dom k &
        k.x1=k.x2 holds x1=x2
        proof
          let x1,x2 be set;
          assume that
A59:      x1 in dom k and
A60:      x2 in dom k and
A61:      k.x1=k.x2;
          reconsider r1=x1 as Point of I[01] by A59;
          reconsider r2=x2 as Point of I[01] by A60;
A62:      k.x1=h.(g1.x1) by A59,FUNCT_1:12
            .=h1.(g1.r1)+h2.(g1.r1) by A40
            .=(g1.r1)`1+proj2.(g1.r1) by PSCOMP_1:def 5
            .=(g1.r1)`1+(g1.r1)`2 by PSCOMP_1:def 6;
A63:      k.x2=h.(g1.x2) by A60,FUNCT_1:12
            .=h1.(g1.r2)+h2.(g1.r2) by A40
            .=(g1.r2)`1+proj2.(g1.r2) by PSCOMP_1:def 5
            .=(g1.r2)`1+(g1.r2)`2 by PSCOMP_1:def 6;
A64:      g.r1 in Upper_Arc(K) by A36;
A65:      g.r2 in Upper_Arc(K) by A36;
          reconsider gr1=g.r1 as Point of TOP-REAL 2 by A64;
          reconsider gr2=g.r2 as Point of TOP-REAL 2 by A65;
          now per cases by A10,A36,XBOOLE_0:def 3;
            case
              A66:          g
.r1 in LSeg(|[a,c]|,|[a,d]|) & g.r2 in LSeg(|[a,c]|,|[a,d]|);
              then
A67:          (gr1)`1=a by A2,Th1;
              (gr2)`1=a by A2,A66,Th1;
              then |[(gr1)`1,(gr1)`2]|=g.r2 by A61,A62,A63,A67,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A34,A35,FUNCT_1:def 4;
            end;
            case
              A68:          g
.r1 in LSeg(|[a,c]|,|[a,d]|) & g.r2 in LSeg(|[a,d]|,|[b,d]|);
              then
A69:          (gr1)`1=a by A2,Th1;
A70:          (gr1)`2 <=d by A2,A68,Th1;
A71:          (gr2)`2=d by A1,A68,Th3;
A72:          a <=(gr2)`1 by A1,A68,Th3;
A73:          a+(gr1)`2=(gr2)`1 +d by A1,A61,A62,A63,A68,A69,Th3;
A74:          now
                assume a<>gr2`1;
                then a<gr2`1 by A72,XXREAL_0:1;
                hence contradiction by A70,A73,XREAL_1:8;
              end;
              now
                assume gr1`2<>d;
                then d>gr1`2 by A70,XXREAL_0:1;
                hence contradiction by A61,A62,A63,A69,A71,A72,XREAL_1:8;
              end;
              then |[(gr1)`1,(gr1)`2]|=g.r2 by A69,A71,A74,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A34,A35,FUNCT_1:def 4;
            end;
            case
              A75:          g
.r1 in LSeg(|[a,d]|,|[b,d]|) & g.r2 in LSeg(|[a,c]|,|[a,d]|);
              then
A76:          (gr2)`1=a by A2,Th1;
A77:          (gr2)`2 <=d by A2,A75,Th1;
A78:          (gr1)`2=d by A1,A75,Th3;
A79:          a <=(gr1)`1 by A1,A75,Th3;
A80:          a+(gr2)`2=(gr1)`1 +d by A1,A61,A62,A63,A75,A76,Th3;
A81:          now
                assume a<>gr1`1;
                then a<gr1`1 by A79,XXREAL_0:1;
                hence contradiction by A77,A80,XREAL_1:8;
              end;
              now
                assume gr2`2<>d;
                then d>gr2`2 by A77,XXREAL_0:1;
                hence contradiction by A61,A62,A63,A76,A78,A79,XREAL_1:8;
              end;
              then |[(gr2)`1,(gr2)`2]|=g.r1 by A76,A78,A81,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A34,A35,FUNCT_1:def 4;
            end;
            case
              A82:          g
.r1 in LSeg(|[a,d]|,|[b,d]|) & g.r2 in LSeg(|[a,d]|,|[b,d]|);
              then
A83:          (gr1)`2=d by A1,Th3;
              (gr2)`2=d by A1,A82,Th3;
              then |[(gr1)`1,(gr1)`2]|=g.r2 by A61,A62,A63,A83,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A34,A35,FUNCT_1:def 4;
            end;
          end;
          hence thesis;
        end;
A84:    dom k=[.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
        then s1 in dom k by A29,A30,XXREAL_1:1;
        then rxc=s1 by A52,A56,A57,A58,A84;
        hence contradiction by A43,A56,XXREAL_1:1;
      end;
      hence thesis;
    end;
    then LE p1,p2,Upper_Arc(K),W-min(K),E-max(K) by A3,A4,A11,JORDAN5C:def 3;
    hence thesis by A3,A4,A11,JORDAN6:def 10;
  end;
end;
