reserve i, i1, i2, j, k for Nat,
  r, s for Real;
reserve D for non empty set,
  f1 for FinSequence of D;
reserve g, g1, g2 for FinSequence of TOP-REAL 2;

theorem Th55:
  for f being non constant standard special_circular_sequence,
      g1,g2 st i1<>i2 &
      g1 is_a_part_of f,i1,i2 & g2 is_a_part_of f,i1,i2 & g1.2=g2.2
  holds g1=g2
proof
  let f be non constant standard special_circular_sequence, g1,g2;
  assume that
A1: i1<>i2 and
A2: g1 is_a_part_of f,i1,i2 and
A3: g2 is_a_part_of f,i1,i2 and
A4: g1.2=g2.2;
  per cases by A2;
  suppose
A5: g1 is_a_part>_of f,i1,i2;
    now
      per cases by A3;
      case
        g2 is_a_part>_of f,i1,i2;
        hence thesis by A5,Th52;
      end;
      case
        g2 is_a_part<_of f,i1,i2;
        hence contradiction by A1,A4,A5,Th54;
      end;
    end;
    hence thesis;
  end;
  suppose
A6: g1 is_a_part<_of f,i1,i2;
    now
      per cases by A3;
      case
        g2 is_a_part>_of f,i1,i2;
        hence contradiction by A1,A4,A6,Th54;
      end;
      case
        g2 is_a_part<_of f,i1,i2;
        hence thesis by A6,Th53;
      end;
    end;
    hence thesis;
  end;
end;
