reserve r,r1,g for Real,
  n,m,k for Nat,
  seq,seq1, seq2 for Real_Sequence,
  f,f1,f2 for PartFunc of REAL,REAL,
  x for set;
reserve r,r1,r2,g,g1,g2 for Real;

theorem
  f1 is divergent_in+infty_to+infty & (for r ex g st r<g & g in dom(f1
  (#)f2 ) ) & (ex r,r1 st 0<r & for g st g in dom f2 /\ right_open_halfline(r1)
  holds r<=f2.g) implies f1(#)f2 is divergent_in+infty_to+infty
proof
  assume that
A1: f1 is divergent_in+infty_to+infty and
A2: for r ex g st r<g & g in dom(f1(#)f2);
  given r2,r1 such that
A3: 0<r2 and
A4: for g st g in dom f2/\right_open_halfline(r1) holds r2<=f2.g;
  now
    let seq;
    assume that
A5: seq is divergent_to+infty and
A6: rng seq c=dom(f1(#) f2);
    consider k such that
A7: for n st k<=n holds r1<seq.n by A5;
A8: rng(seq^\k)c=rng seq by VALUED_0:21;
A9: rng seq c=dom f2 by A6,Lm3;
    then
A10: rng(seq^\k)c=dom f2 by A8;
A11: now
      thus 0<r2 by A3;
      let n;
A12: n in NAT by ORDINAL1:def 12;
      r1<seq.(n+k) by A7,NAT_1:12;
      then r1<(seq^\k).n by NAT_1:def 3;
      then (seq^\k).n in {g2: r1<g2};
      then (seq^\k).n in rng(seq^\k) & (seq^\k).n in right_open_halfline(r1)
      by VALUED_0:28,XXREAL_1:230;
      then (seq^\k).n in dom f2/\right_open_halfline(r1) by A10,XBOOLE_0:def 4;
      then r2<=f2.((seq^\k).n) by A4;
      hence r2<=(f2/*(seq^\k)).n by A9,A8,FUNCT_2:108,XBOOLE_1:1,A12;
    end;
    dom(f1(#)f2)=dom f1/\dom f2 by A6,Lm3;
    then rng(seq^\k)c=dom f1/\dom f2 by A6,A8;
    then
A13: (f1/*(seq^\k))(#)(f2/*(seq^\k))=(f1(#)f2)/*(seq^\k) by RFUNCT_2:8
      .=((f1(#)f2)/*seq)^\k by A6,VALUED_0:27;
    rng seq c=dom f1 by A6,Lm3;
    then
A14: rng(seq^\k)c=dom f1 by A8;
    seq^\k is divergent_to+infty by A5,Th26;
    then f1/*(seq^\k) is divergent_to+infty by A1,A14;
    then (f1/*(seq^\k))(#)(f2/*(seq^\k)) is divergent_to+infty by A11,Th22;
    hence (f1(#)f2)/*seq is divergent_to+infty by A13,Th7;
  end;
  hence thesis by A2;
end;
