
theorem Th55:
for I,J be non empty closed_interval Subset of REAL,
 f be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real,
 g be PartFunc of [:REAL,REAL:],REAL, G1 be PartFunc of REAL,REAL
 st [:I,J:] = dom f & f is_continuous_on [:I,J:] & f = g
 & G1 = Integral1(L-Meas,|.R_EAL g.|)|J holds G1 is continuous
proof
    let I,J be non empty closed_interval Subset of REAL,
    f be PartFunc of [:RNS_Real,RNS_Real:],RNS_Real,
    g be PartFunc of [:REAL,REAL:],REAL,
    G1 be PartFunc of REAL,REAL;
    assume that
A1:  [:I,J:] = dom f and
A2:  f is_continuous_on [:I,J:] and
A3:  f = g and
A4:  G1 = Integral1(L-Meas,|.R_EAL g.|)|J;

    consider a,b be Real such that
A5:  I = [.a,b.] by MEASURE5:def 3;
A6: a <= b by A5,XXREAL_1:29; then
A7:  a in I & b in I by A5;
A8: [.a,b.] = ['a,b'] by A5,XXREAL_1:29,INTEGRA5:def 3;

A9:for e be Real st 0 < e holds ex r be Real st 0 < r
     & for y1,y2 be Real st |.y2-y1.| < r & y1 in J & y2 in J
        holds for x be Real st x in I holds
         |. (|.g.|).([x,y2])-(|.g.|).([x,y1]) .| < e
    proof
     let e be Real;
     assume 0 < e; then
     consider r be Real such that
A10:  0 < r
    & for x1,x2,y1,y2 be Real st [x1,y1] in [:I,J:] & [x2,y2] in [:I,J:] &
       |.x2-x1.| < r & |.y2-y1.| < r
          holds |. (|.g.|).([x2,y2])-(|.g.|).([x1,y1]) .| < e by A2,A3,Th23;
     take r ;
     thus 0 < r by A10;
     let y1,y2 be Real;
     assume
A11: |.y2-y1.| < r & y1 in J & y2 in J;

     let x be Real;
     assume x in I; then
A12: [x,y1] in [:I,J:] & [x,y2] in [:I,J:] by A11,ZFMISC_1:87;

     |.x-x.| < r by A10;
     hence |. (|.g.|).([x,y2])-(|.g.|).([x,y1]) .| < e by A10,A11,A12;
    end;

    set Rg =R_EAL g;

    dom |.Rg.| = dom Rg by MESFUNC1:def 10; then
A13:dom |.Rg.| = [:I,J:] by A1,A3,MESFUNC5:def 7;

A14:for x,y be Element of REAL st x in I & y in J holds
     (ProjPMap2(|.Rg.|,y)).x =(|.Rg.|).(x,y)
   & (|.Rg.|).(x,y) = |. g.([x,y]) .| & (|.Rg.|).(x,y) = (|.g.|).([x,y])
    proof
     let x,y be Element of REAL;
     assume
A15:  x in I & y in J;
     hence (ProjPMap2(|.Rg.|,y)).x =(|.Rg.|).(x,y)
      by A13,ZFMISC_1:87,MESFUN12:def 4;

     [x,y] in dom g by A15,A1,A3,ZFMISC_1:87; then
A16: [x,y] in dom |.g.| by VALUED_1:def 11;

A17: Rg.([x,y]) = g.([x,y]) by MESFUNC5:def 7;

     (|.Rg.|).(x,y) = |. Rg.([x,y]) .|
       by A15,A13,ZFMISC_1:87,MESFUNC1:def 10;
     hence (|.Rg.|).(x,y) = |.g.([x,y]).| by A17,EXTREAL1:12;
     hence (|.Rg.|).(x,y) = (|.g.|).([x,y]) by VALUED_1:def 11,A16;
    end;

A18:for e be Real st 0 < e holds ex r be Real st 0 < r
    & for y1,y2 be Element of REAL st |.y2-y1.| < r & y1 in J
       & y2 in J holds for x be Element of REAL st x in I
          holds |. (ProjPMap2(|.Rg.|,y2)).x-(ProjPMap2(|.Rg.|,y1)).x .| < e
    proof
     let e be Real;
     assume 0 < e; then
     consider r be Real such that
A19: 0 < r
    & for y1,y2 be Real st |.y2-y1.| < r & y1 in J & y2 in J
       holds for x be Real st x in I holds
        |. (|.g.|).([x,y2])-(|.g.|).([x,y1]) .| < e by A9;

     take r;
     thus 0 < r by A19;

     let y1,y2 be Element of REAL;
     assume
A20: |.y2-y1.| < r & y1 in J & y2 in J;
     let x be Element of REAL;
     assume
A21: x in I; then
A22: |. (|.g.|).([x,y2])-(|.g.|).([x,y1]) .| < e by A19,A20;
a22: (|.g.|).([x,y2])-(|.g.|).([x,y1]) =
     (|.g.|).([x,y2]) qua ExtReal -(|.g.|).([x,y1]);

     (ProjPMap2(|.Rg.|,y1)).x =(|.Rg.|).(x,y1)
   & (|.Rg.|).(x,y1) = (|.g.|).([x,y1])
   & (ProjPMap2(|.Rg.|,y2)).x =(|.Rg.|).(x,y2)
   & (|.Rg.|).(x,y2) = (|.g.|).([x,y2]) by A14,A20,A21;
     hence thesis by A22,a22,EXTREAL1:12;
    end;

    set T = Integral1(L-Meas,|.Rg.|);
A23:dom T = REAL by FUNCT_2:def 1;

    for y0,r be Real st y0 in J & 0 < r
     ex s be Real st 0<s & for y1 be Real
      st y1 in J & |.y1-y0.| < s holds |.G1.y1-G1.y0.| < r
    proof
     let yy0,r be Real;
     assume
A24: yy0 in J & 0 < r;

     reconsider y0=yy0 as Element of REAL by XREAL_0:def 1;
     reconsider Pg0 = ProjPMap2(|.Rg.|,y0) as PartFunc of REAL,REAL by Th30;
A25: dom Pg0 = I by A24,A1,A3,Th28;
A26: Pg0|(dom Pg0) is continuous by A1,A2,A3,Th39;
A27:  Pg0|I is bounded & Pg0 is_integrable_on I by A24,A1,A2,A3,Th47;
A28:  (Integral1(L-Meas,|.Rg.|)).y0 = integral(Pg0,I) by A24,A1,A2,A3,Th49;
     per cases;
     suppose A29: a = b;
      consider s be Real such that
A30:  0 < s
    & for y1,y2 be Element of REAL st |.y2-y1.| < s & y1 in J & y2 in J
        holds for x be Element of REAL st x in I holds
         |. (ProjPMap2(|.Rg.|,y2)).x-(ProjPMap2(|.Rg.|,y1)).x .| < r
           by A18,A24;

      for y1 be Real st y1 in J & |.y1-y0.| < s holds |.G1.y1-G1.yy0 .| < r
      proof
       let yy1 be Real;
       assume
A31:   yy1 in J & |.yy1-y0.| < s;

       reconsider y1=yy1 as Element of REAL by XREAL_0:def 1;
       reconsider Pg1 = ProjPMap2(|.Rg.|,y1) as PartFunc of REAL,REAL
         by Th30;
A32:   dom Pg1 = I by A31,A1,A3,Th28;
A33:   Pg1|(dom Pg1) is continuous by A1,A2,A3,Th39;
A34:    Pg1|I is bounded & Pg1 is_integrable_on I by A31,A1,A2,A3,Th47;
       (Integral1(L-Meas,|.Rg.|)).y1 = integral(Pg1,I)
        by A31,A1,A2,A3,Th49; then
       G1.yy0 = integral(Pg0,I) & G1.yy1 = integral(Pg1,I)
         by A4,A24,A28,A31,FUNCT_1:49; then
A35:   G1.yy0 = integral(Pg0,a,b) & G1.yy1 = integral(Pg1,a,b)
         by A5,A8,XXREAL_1:29,INTEGRA5:def 4;

A36:   dom(Pg1-Pg0) = I /\ I by A25,A32,VALUED_1:12; then
A37:   (Pg1-Pg0)|I is bounded & (Pg1-Pg0) is_integrable_on I
         by A26,A33,INTEGRA5:10,11;

       for x be Real st x in I holds |. (Pg1-Pg0).x .| <= r
       proof
        let x be Real;
        assume
A38:    x in I; then
A39:    |. (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x .| < r
            by A30,A31,A24;

A40:   -(ProjPMap2(|.Rg.|,y0)).x = -Pg0.x by XXREAL_3:def 3;

        (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x
         = (ProjPMap2(|.Rg.|,y1)).x  +-(ProjPMap2(|.Rg.|,y0)).x
           by XXREAL_3:def 4; then
        (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x = Pg1.x + -Pg0.x
           by A40,XXREAL_3:def 2; then
        (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x = Pg1.x - Pg0.x; then
        (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x = (Pg1-Pg0).x
           by A36,A38,VALUED_1:13;
        hence |. (Pg1-Pg0).x .| <= r by A39,EXTREAL1:12;
       end; then
       |. integral(Pg1-Pg0,a,b) .| <= r * (b-a)
         by A6,A5,A8,A36,A37,A7,INTEGRA6:23;
       hence |. G1.yy1-G1.yy0 .| < r
         by A29,A24,A35,A5,A8,A32,A34,A25,A27,INTEGRA6:12;
      end;
      hence
       ex s be Real st 0<s & for y1 be Real
        st y1 in J & |.y1-yy0.| < s holds |.G1.y1-G1.yy0.| < r by A30;
     end;
     suppose a <> b; then
      a < b by A6,XXREAL_0:1; then
A41: 0 < b-a by XREAL_1:50;
      set r1=r/2;
A42: 0 < r1 & r1 < r by A24,XREAL_1:215,XREAL_1:216;
      consider s be Real such that
A43:  0 < s
    & for y1,y2 be Element of REAL st |.y2-y1.| < s & y1 in J
       & y2 in J holds for x be Element of REAL st x in I holds
        |. (ProjPMap2(|.Rg.|,y2)).x-(ProjPMap2(|.Rg.|,y1)).x .| < r1/(b-a)
            by A18,XREAL_1:139,A42,A41;
      take s;
      thus 0 < s by A43;

      let yy1 be Real;
      assume
A44:  yy1 in J & |.yy1-yy0.| < s;

      reconsider y1=yy1 as Element of REAL by XREAL_0:def 1;
      reconsider Pg1 = ProjPMap2(|.Rg.|,y1) as PartFunc of REAL,REAL
         by Th30;
A45:  dom Pg1 = I by A44,A1,A3,Th28;
A46:  Pg1|(dom Pg1) is continuous by A1,A2,A3,Th39;
A47:   Pg1|I is bounded & Pg1 is_integrable_on I
        by A44,A1,A2,A3,Th47;
      (Integral1(L-Meas,|.Rg.|)).y1 = integral(Pg1,I)
         by A44,A1,A2,A3,Th49; then
      G1.yy0 = integral(Pg0,I) & G1.yy1 = integral(Pg1,I)
       by A4,A24,A28,A44,FUNCT_1:49; then
      G1.yy0 = integral(Pg0,a,b) & G1.yy1 = integral(Pg1,a,b)
        by A5,A8,XXREAL_1:29,INTEGRA5:def 4; then
A48:  |.G1.yy1-G1.yy0.| = |. integral(Pg1-Pg0,a,b) .|
       by A6,A5,A8,A45,A47,A25,A27,INTEGRA6:12;

A49:  dom(Pg1-Pg0) = I /\ I by A25,A45,VALUED_1:12; then
A50:  (Pg1-Pg0)|I is bounded & (Pg1-Pg0) is_integrable_on I
        by A26,A46,INTEGRA5:10,11;

      for x be Real st x in I holds |. (Pg1-Pg0).x .| <= r1/(b-a)
      proof
       let x be Real;
       assume
A51:   x in I; then
A52:  |. (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x .| < r1/(b-a)
         by A43,A44,A24;

A53:  -(ProjPMap2(|.Rg.|,y0)).x = -Pg0.x by XXREAL_3:def 3;

       (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x
        = (ProjPMap2(|.Rg.|,y1)).x  +-(ProjPMap2(|.Rg.|,y0)).x
          by XXREAL_3:def 4; then
       (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x = Pg1.x + -Pg0.x
          by A53,XXREAL_3:def 2; then
       (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x = Pg1.x - Pg0.x; then
       (ProjPMap2(|.Rg.|,y1)).x-(ProjPMap2(|.Rg.|,y0)).x = (Pg1-Pg0).x
          by A49,A51,VALUED_1:13;
       hence thesis by A52,EXTREAL1:12;
      end; then
      |. integral(Pg1-Pg0,a,b) .| <= (r1/(b-a)) * (b-a)
        by A6,A5,A7,A8,A49,A50,INTEGRA6:23; then
      |. integral(Pg1-Pg0,a,b) .| <= r1 by A41,XCMPLX_1:87;
      hence |. G1.yy1-G1.yy0 .| < r by A48,XXREAL_0:2,A42;
     end;
    end; then
    G1|J is continuous by A4,A23,FCONT_1:14;
    hence G1 is continuous by A4;
end;
