reserve n,m for Nat,
  r,r1,r2,s,t for Real,
  x,y for set;

theorem
  for F be PartFunc of REAL,REAL, X be set, r holds F
  is_convex_on X iff F-r is_convex_on X
proof
  let F be PartFunc of REAL,REAL, X be set, r;
A1: dom F = dom(F-r) by VALUED_1:3;
  thus F is_convex_on X implies F-r is_convex_on X
  proof
    assume
A2: F is_convex_on X;
    hence
A3: X c= dom(F-r) by A1;
    let p be Real;
    assume
A4: 0<=p & p<=1;
    let x,y be Real;
    assume that
A5: x in X and
A6: y in X and
A7: p*x + (1-p)*y in X;
    F.(p*x+(1-p)*y) <= p*F.x + (1-p)*F.y by A2,A4,A5,A6,A7;
    then
A8: F.(p*x+(1-p)*y) - r <= p*F.x + (1-p)*F.y -r by XREAL_1:9;
    p*F.x + (1-p)*F.y - r = p*(F.x -r) + (1-p)*(F.y - r)
      .= p*(F-r).x + (1-p)*(F.y - r) by A1,A3,A5,VALUED_1:3
      .= p*(F-r).x + (1-p)*(F-r).y by A1,A3,A6,VALUED_1:3;
    hence thesis by A1,A3,A7,A8,VALUED_1:3;
  end;
  assume
A9: F-r is_convex_on X;
  hence
A10: X c= dom F by A1;
  let p be Real;
  assume
A11: 0<=p & p<=1;
  let x,y be Real;
  assume that
A12: x in X and
A13: y in X and
A14: p*x + (1-p)*y in X;
  (F-r).(p*x+(1-p)*y) <= p*(F-r).x + (1-p)*(F-r).y by A9,A11,A12,A13,A14;
  then
A15: F.(p*x+(1-p)*y) -r <= p*(F-r).x + (1-p)*(F-r).y by A10,A14,VALUED_1:3;
  p*(F-r).x + (1-p)*(F-r).y = p*(F-r).x + (1-p)*(F.y - r) by A10,A13,VALUED_1:3
    .= p*(F.x - r) + ((1-p)*F.y - (1-p)*r) by A10,A12,VALUED_1:3
    .= p*F.x + (1-p)*F.y - r;
  hence thesis by A15,XREAL_1:9;
end;
