reserve A for Tolerance_Space,
  X, Y for Subset of A;
reserve A for Approximation_Space,
  X for Subset of A;
reserve A for finite Tolerance_Space,
  X for Subset of A,
  x for Element of A;
reserve A for finite Approximation_Space,
  X, Y for Subset of A,
  x for Element of A;

theorem
  for X being disjoint_valued FinSequence of bool the carrier of A holds
  MemberFunc (Union X, A).x = Sum FinSeqM (x, X)
proof
  let X be disjoint_valued FinSequence of bool the carrier of A;
  defpred P[FinSequence of bool the carrier of A] means $1 is disjoint_valued
  implies MemberFunc (Union $1, A).x = Sum FinSeqM (x, $1);
A1: for p being FinSequence of bool the carrier of A for y being Subset of A
  st P[p] holds P[p^<*y*>]
  proof
    let p be FinSequence of bool the carrier of A;
    let y be Subset of A;
    assume
A2: P[p];
    P[p^<*y*>]
    proof
      assume
A3:   p^<*y*> is disjoint_valued;
A4:   Union p misses y
      proof
        assume Union p meets y;
        then consider x being object such that
A5:     x in Union p and
A6:     x in y by XBOOLE_0:3;
        consider X being set such that
A7:     x in X and
A8:     X in rng p by A5,TARSKI:def 4;
        consider m being object such that
A9:     m in dom p and
A10:    X = p.m by A8,FUNCT_1:def 3;
        reconsider m as Element of NAT by A9;
A11:    (p^<*y*>).m = p.m & m <= len p by A9,FINSEQ_1:def 7,FINSEQ_3:25;
A12:    (p^<*y*>).(len p + 1) = y & len p < len p + 1 by FINSEQ_1:42,NAT_1:13;
        p.m meets y by A6,A7,A10,XBOOLE_0:3;
        hence thesis by A3,A12,A11;
      end;
      Union (p^<*y*>) = Union p \/ Union <*y*> by Th5
        .= Union p \/ y by FINSEQ_3:135;
      then MemberFunc (Union (p^<*y*>), A).x = MemberFunc (Union p, A).x +
      MemberFunc (y, A).x by A4,Th51
        .= Sum (FinSeqM (x, p) ^ <* MemberFunc (y, A).x *>)
           by A2,A3,Th6,FINSEQ_6:10,RVSUM_1:74
        .= Sum FinSeqM (x, p ^ <*y*>) by Th53;
      hence thesis;
    end;
    hence thesis;
  end;
A13: P[<*> bool the carrier of A]
  proof
    set F = FinSeqM (x, <*> bool the carrier of A);
    assume <*> bool the carrier of A is disjoint_valued;
    dom F = dom <*> bool the carrier of A by Def10;
    then
A14: Sum F = 0 by RELAT_1:41,RVSUM_1:72;
    Union <*> bool the carrier of A = {}A by ZFMISC_1:2;
    hence thesis by A14,Th54;
  end;
  for p being FinSequence of bool the carrier of A holds P[p] from
  FINSEQ_2:sch 2 (A13,A1);
  hence thesis;
end;
