reserve x for Real;

theorem Th56:
  for z be Complex for n,k be Nat st n <> 0 holds z = ((n
-root |.z.|)*cos((Arg z+2*PI*k)/n)+ (n-root |.z.|)*sin((Arg z+2*PI*k)/n)*<i>)|^
  n
proof
  let z be Complex;
  let n,k be Nat;
  assume
A1: n <> 0;
  then
A2: n >= 0+1 by NAT_1:13;
  per cases;
  suppose
A3: z <> 0;
    thus ((n-root |.z.|)*cos((Arg z+2*PI*k)/n)+ (n-root |.z.|)*sin((Arg z+2*PI
*k)/n)*<i>)|^n = ((n-root |.z.|+0*<i>)* (cos((Arg z+2*PI*k)/n)+sin((Arg z+2*PI*
    k)/n)*<i>))|^n
      .= ((n-root |.z.|+0*<i>))|^n* (cos((Arg z+2*PI*k)/n)+sin((Arg z+2*PI*k
    )/n)*<i>)|^n by NEWTON:7
      .= (n-root |.z.|+0*<i>)|^n*(cos Arg z+(sin Arg z)*<i>) by A1,Th55
      .= (|.z.|+0*<i>)*(cos Arg z+(sin Arg z)*<i>) by A1,Th4,COMPLEX1:46
      .= |.z.|*cos Arg z-0*sin Arg z+(|.z.|*sin Arg z+0*cos Arg z)*<i>
      .= z by A3,Def1;
  end;
  suppose
A4: z = 0;
    hence
    ((n-root |.z.|)*cos((Arg z+2*PI*k)/n)+ (n-root |.z.|)*sin((Arg z+2*PI
*k)/n)*<i>)|^n = (0*cos((Arg z+2*PI*k)/n)+ (n-root 0)*sin((Arg z+2*PI*k)/n)*<i>
    )|^n by A2,COMPLEX1:44,POWER:5
      .= (0+0*sin((Arg z+2*PI*k)/n)*<i>)|^n by A2,POWER:5
      .= z by A2,A4,NEWTON:11;
  end;
end;
