reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being ComplexLinearSpace, M being Subset of V, v being VECTOR of
  V holds M is convex iff v + M is convex
proof
  let V be ComplexLinearSpace;
  let M be Subset of V;
  let v be VECTOR of V;
A1: v + M is convex implies M is convex
  proof
    assume
A2: v + M is convex;
    let w1,w2 be VECTOR of V;
    let z be Complex;
    assume that
A3: ex r being Real st z=r & 0 < r & r < 1 and
A4: w1 in M & w2 in M;
    set x1 = v + w1, x2 = v + w2;
    x1 in v + M & x2 in {v + w where w is VECTOR of V : w in M} by A4;
    then
A5: z*x1 + (1r-z)*x2 in v + M by A2,A3;
    z*x1 + (1r-z)*x2 = z*v + z*w1 + (1r-z)*(v + w2) by CLVECT_1:def 2
      .= z*v + z*w1 + ((1r-z)*v + (1r-z)*w2) by CLVECT_1:def 2
      .= z*v + z*w1 + (1r-z)*v + (1r-z)*w2 by RLVECT_1:def 3
      .= z*v + (1r-z)*v + z*w1 + (1r-z)*w2 by RLVECT_1:def 3
      .= (z+(1r-z))*v + z*w1 + (1r-z)*w2 by CLVECT_1:def 3
      .= v + z*w1 + (1r-z)*w2 by CLVECT_1:def 5
      .= v + (z*w1 + (1r-z)*w2) by RLVECT_1:def 3;
    then
    ex w be VECTOR of V st v + (z*w1 + (1r-z)*w2) = v + w & w in M by A5;
    hence thesis by RLVECT_1:8;
  end;
  M is convex implies v + M is convex
  proof
    assume
A6: M is convex;
    let w1,w2 be VECTOR of V;
    let z be Complex;
    assume that
A7: ex r being Real st z=r & 0 < r & r < 1 and
A8: w1 in v + M and
A9: w2 in v + M;
    consider x2 be VECTOR of V such that
A10: w2 = v + x2 and
A11: x2 in M by A9;
    consider x1 be VECTOR of V such that
A12: w1 = v + x1 and
A13: x1 in M by A8;
A14: z*w1 + (1r-z)*w2 = z*v + z*x1 + (1r-z)*(v+x2) by A12,A10,CLVECT_1:def 2
      .= z*v + z*x1 + ((1r-z)*v + (1r-z)*x2) by CLVECT_1:def 2
      .= z*v + z*x1 + (1r-z)*v + (1r-z)*x2 by RLVECT_1:def 3
      .= z*v + (1r-z)*v + z*x1 + (1r-z)*x2 by RLVECT_1:def 3
      .= (z+(1r-z))*v + z*x1 + (1r-z)*x2 by CLVECT_1:def 3
      .= v + z*x1 + (1r-z)*x2 by CLVECT_1:def 5
      .= v + (z*x1 + (1r-z)*x2) by RLVECT_1:def 3;
    z*x1 + (1r-z)*x2 in M by A6,A7,A13,A11;
    hence thesis by A14;
  end;
  hence thesis by A1;
end;
