reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem
  for p being non empty ProbFinS FinSequence of REAL st ex k st k in dom
  p & p.k = 1 holds Entropy p = 0
proof
  let p be non empty ProbFinS FinSequence of REAL;
  assume ex k st k in dom p & p.k = 1;
  then consider k1 being Nat such that
A1: k1 in dom p and
A2: p.k1 = 1;
  set q = Infor_FinSeq_of p;
  len q = len p by Th47;
  then
A3: dom q = dom p by FINSEQ_3:29;
A4: p has_onlyone_value_in k1 by A1,A2,Th15;
  for k st k in dom q holds q.k = 0
  proof
    let k such that
A5: k in dom q;
    per cases;
    suppose
      k=k1;
      hence q.k = 1*log(2,1) by A2,A5,Th47
        .= 0 by POWER:51;
    end;
    suppose
      k<>k1;
      then
A6:   p.k = 0 by A4,A3,A5;
      thus q.k = p.k * log(2,p.k) by A5,Th47
        .= 0 by A6;
    end;
  end;
  then for x being object st x in dom q holds q.x = 0;
  then q = dom q --> 0 by FUNCOP_1:11;
  then q = len q |-> 0 by FINSEQ_1:def 3;
  then Sum q = 0 by RVSUM_1:81;
  hence thesis;
end;
