 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
  A c= Z & (for x st x in Z holds f.x=sin.(sin.x)*cos.x) &
  Z = dom f & f|A is continuous
  implies integral(f,A)=(-cos*sin).(upper_bound A)-(-cos*sin).(lower_bound A)
proof
   assume
A1:A c= Z & (for x st x in Z holds f.x=sin.(sin.x)*cos.x)
 & Z = dom f & f|A is continuous; then
A2:f is_integrable_on A & f|A is bounded by INTEGRA5:10,11;
A3: dom sin = REAL by SIN_COS:24;
  rng sin c= dom sin & dom sin = dom cos by SIN_COS:24; then
dom (cos*sin) = REAL by A3,RELAT_1:27;
then A4:dom (-cos*sin) = REAL by VALUED_1:8;
A5:cos*sin is_differentiable_on Z by FDIFF_10:9;
then A6:(-1)(#)(cos*sin) is_differentiable_on Z by A4,FDIFF_1:20;
A7:for x st x in Z holds ((-cos*sin)`|Z).x = sin.(sin.x)*cos.x
  proof
    let x;
    assume
A8:x in Z;
  ((-cos*sin)`|Z).x=((-1)(#)((cos*sin)`|Z)).x by A5,FDIFF_2:19
   .=(-1)*(((cos*sin)`|Z).x) by VALUED_1:6
   .=(-1)*((-sin.(sin.x)*cos.x)) by A8,FDIFF_10:9
   .=sin.(sin.x)*cos.x;
     hence thesis;
   end;
A9:for x being Element of REAL st x in dom ((-cos*sin)`|Z)
holds ((-cos*sin)`|Z).x=f.x
  proof
    let x be Element of REAL;
    assume x in dom ((-cos*sin)`|Z);then
A10: x in Z by A6,FDIFF_1:def 7;then
    ((-cos*sin)`|Z).x =sin.(sin.x)*cos.x by A7
      .= f.x by A1,A10;
    hence thesis;
   end;
  dom ((-cos*sin)`|Z)=dom f by A1,A6,FDIFF_1:def 7;
  then ((-cos*sin)`|Z)= f by A9,PARTFUN1:5;
  hence thesis by A1,A2,A6,INTEGRA5:13;
end;
