reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th56:
  for a,b,c,d being Real,p1,p2 being Point of TOP-REAL 2
  st a < b & c < d & p1 in LSeg(|[a,d]|,|[b,d]|) & p2 in LSeg(|[a,d]|,|[b,d]|)
  holds LE p1,p2,rectangle(a,b,c,d) iff p1`1<=p2`1
proof
  let a,b,c,d be Real,p1,p2 be Point of TOP-REAL 2;
  set K = rectangle(a,b,c,d);
  assume that
A1: a<b and
A2: c <d and
A3: p1 in LSeg(|[a,d]|,|[b,d]|) and
A4: p2 in LSeg(|[a,d]|,|[b,d]|);
A5: K is being_simple_closed_curve by A1,A2,Th50;
A6: p1`2=d by A1,A3,Th3;
A7: a <=p1`1 by A1,A3,Th3;
A8: p1`1 <= b by A1,A3,Th3;
A9: p2`2=d by A1,A4,Th3;
A10: W-min(K)= |[a,c]| by A1,A2,Th46;
A11: E-max(K)= |[b,d]| by A1,A2,Th46;
A12: Upper_Arc(K)=LSeg(|[a,c]|,|[a,d]|) \/ LSeg(|[a,d]|,|[b,d]|) by A1,A2,Th51;
  then
A13: LSeg(|[a,d]|,|[b,d]|) c= Upper_Arc(K) by XBOOLE_1:7;
A14: Upper_Arc(K) /\ Lower_Arc(K)={W-min(K),E-max(K)} by A5,JORDAN6:def 9;
A15: now
    assume p2 in Lower_Arc(K);
    then
A16: p2 in Upper_Arc(K) /\ Lower_Arc(K) by A4,A13,XBOOLE_0:def 4;
    now
      assume p2=W-min(K);
      then p2`2=c by A10,EUCLID:52;
      hence contradiction by A2,A4,TOPREAL3:12;
    end;
    hence p2=E-max(K) by A14,A16,TARSKI:def 2;
  end;
  thus LE p1,p2,K implies p1`1<=p2`1
  proof
    assume LE p1,p2,K;
    then
A17: p1 in Upper_Arc(K) & p2 in Lower_Arc(K)& not p2=W-min(K) or
    p1 in Upper_Arc(K) & p2 in Upper_Arc(K) &
    LE p1,p2,Upper_Arc(K),W-min(K),E-max(K) or
    p1 in Lower_Arc(K) & p2 in Lower_Arc(K)& not p2=W-min(K) &
    LE p1,p2,Lower_Arc(K),E-max(K),W-min(K) by JORDAN6:def 10;
    now per cases;
      case p2=E-max(K);
        hence thesis by A8,A11,EUCLID:52;
      end;
      case
A18:    p2<>E-max(K);
consider f being Function of I[01],(TOP-REAL 2)|(Upper_Arc(K)) such that
A19:    f is being_homeomorphism and
A20:    f.0=W-min(K) and
A21:    f.1=E-max(K) and rng f=Upper_Arc(K)
        and for r being Real st r in [.0,1/2.] holds f.r=(1-2*r)*|[a,c]|+(2*r)
        *|[a,d]|
        and for r being Real st r in [.1/2,1.] holds f.r=(1-(2*r-1))*|[a,d]|+(
        2*r-1)*|[b,d]|
        and for p being Point of TOP-REAL 2 st p in LSeg(|[a,c]|,|[a,d]|)
holds 0<=((p`2)-c)/(d-c)/2 & ((p`2)-c)/(d-c)/2<=1 & f.(((p`2)-c)/(d-c)/2)=p and
A22:    for p being Point of TOP-REAL 2 st p in LSeg(|[a,d]|,|[b,d]|)
holds 0<=((p`1)-a)/(b-a)/2+1/2 & ((p`1)-a)/(b-a)/2+1/2<=1 & f.(((p`1)-a)/(b-a)/
        2+1/2)=p
        by A1,A2,Th53;
        reconsider s1=((p1`1)-a)/(b-a)/2+1/2,s2=((p2`1)-a)/(b-a)/2+1/2 as
        Real;
A23:    f.s1=p1 by A3,A22;
A24:    f.s2=p2 by A4,A22;
A25:    b-a >0 by A1,XREAL_1:50;
A26:    s1<=1 by A3,A22;
A27:    0<=s2 by A4,A22;
        s2<=1 by A4,A22;
        then s1<=s2 by A15,A17,A18,A19,A20,A21,A23,A24,A26,A27,JORDAN5C:def 3;
        then ((p1`1)-a)/(b-a)/2<= ((p2`1)-a)/(b-a)/2 by XREAL_1:6;
        then ((p1`1)-a)/(b-a)/2*2<=((p2`1)-a)/(b-a)/2*2 by XREAL_1:64;
        then ((p1`1)-a)/(b-a)*(b-a)<= ((p2`1)-a)/(b-a)*(b-a) by A25,XREAL_1:64;
        then ((p1`1)-a)<= ((p2`1)-a)/(b-a)*(b-a) by A25,XCMPLX_1:87;
        then ((p1`1)-a)<= ((p2`1)-a) by A25,XCMPLX_1:87;
        then ((p1`1)-a)+a <= ((p2`1)-a)+a by XREAL_1:7;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  thus p1`1<=p2`1 implies LE p1,p2,K
  proof
    assume
A28: p1`1<=p2`1;
    for g being Function of I[01], (TOP-REAL 2)|Upper_Arc(K),
    s1, s2 being Real st g is being_homeomorphism & g.0 = W-min(K) &
    g.1 = E-max(K)
    & g.s1 = p1 & 0 <= s1 & s1 <= 1 & g.s2 = p2 & 0 <= s2 & s2 <= 1
    holds s1 <= s2
    proof
      let g be Function of I[01], (TOP-REAL 2)|Upper_Arc(K),
          s1, s2 be Real;
      assume that
A29:  g is being_homeomorphism and
A30:  g.0 = W-min(K) and g.1 = E-max(K) and
A31:  g.s1 = p1 and
A32:  0 <= s1 and
A33:  s1 <= 1 and
A34:  g.s2 = p2 and
A35:  0 <= s2 and
A36:  s2 <= 1;
A37:  dom g=the carrier of I[01] by FUNCT_2:def 1;
A38:  g is one-to-one by A29,TOPS_2:def 5;
      A39:  the
 carrier of ((TOP-REAL 2)|Upper_Arc(K)) =Upper_Arc(K) by PRE_TOPC:8;
      then reconsider g1=g as Function of I[01],TOP-REAL 2 by FUNCT_2:7;
      g is continuous by A29,TOPS_2:def 5;
      then
A40:  g1 is continuous by PRE_TOPC:26;
      reconsider h1=proj1 as Function of TOP-REAL 2,R^1 by TOPMETR:17;
      reconsider h2=proj2 as Function of TOP-REAL 2,R^1 by TOPMETR:17;
      reconsider hh1=h1 as Function of the TopStruct of TOP-REAL 2,R^1;
      reconsider hh2=h2 as Function of the TopStruct of TOP-REAL 2,R^1;
A41:  the TopStruct of TOP-REAL 2
      = (the TopStruct of TOP-REAL 2)|([#](the TopStruct of TOP-REAL 2))
      by TSEP_1:3
        .= the TopStruct of ((TOP-REAL 2)|([#](TOP-REAL 2))) by PRE_TOPC:36
        .= (TOP-REAL 2)|([#](TOP-REAL 2));
      then (for p being Point of (TOP-REAL 2)|([#](TOP-REAL 2)) holds
      hh1.p=proj1.p) implies hh1 is continuous by JGRAPH_2:29;
      then
A42:  (for p being Point of (TOP-REAL 2)|([#]TOP-REAL 2)holds
      hh1.p=proj1.p) implies h1 is continuous by PRE_TOPC:32;
      (for p being Point of (TOP-REAL 2)|([#](TOP-REAL 2)) holds
      hh2.p=proj2.p) implies hh2 is continuous by A41,JGRAPH_2:30;
      then (for p being Point of (TOP-REAL 2)|([#](TOP-REAL 2)) holds
      hh2.p=proj2.p) implies h2 is continuous by PRE_TOPC:32;
      then consider h being Function of TOP-REAL 2,R^1 such that
A43:  for p being Point of TOP-REAL 2, r1,r2 being Real st h1.p=r1 &
      h2.p=r2 holds h.p=r1+r2 and
A44:  h is continuous by A42,JGRAPH_2:19;
      reconsider k=h*g1 as Function of I[01],R^1;
A45:  W-min K=|[a,c]| by A1,A2,Th46;
      now
        assume
A46:    s1>s2;
A47:    dom g=[.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
        0 in [.0,1.] by XXREAL_1:1;
        then
A48:    k.0=h.(W-min(K)) by A30,A47,FUNCT_1:13
          .=h1.(W-min(K))+h2.(W-min(K)) by A43
          .=(W-min(K))`1+proj2.(W-min(K)) by PSCOMP_1:def 5
          .=(W-min(K))`1+(W-min(K))`2 by PSCOMP_1:def 6
          .=(W-min(K))`1+c by A45,EUCLID:52
          .=a+c by A45,EUCLID:52;
        s1 in [.0,1.] by A32,A33,XXREAL_1:1;
        then
A49:    k.s1=h.p1 by A31,A47,FUNCT_1:13
          .=h1.p1+h2.p1 by A43
          .=p1`1+proj2.p1 by PSCOMP_1:def 5
          .=p1`1 +d by A6,PSCOMP_1:def 6;
A50:    s2 in [.0,1.] by A35,A36,XXREAL_1:1;
        then
A51:    k.s2=h.p2 by A34,A47,FUNCT_1:13
          .=h1.p2+h2.p2 by A43
          .=p2`1+proj2.p2 by PSCOMP_1:def 5
          .=p2`1 +d by A9,PSCOMP_1:def 6;
A52:    k.0<=k.s1 by A2,A7,A48,A49,XREAL_1:7;
A53:    k.s1<=k.s2 by A28,A49,A51,XREAL_1:7;
A54:    0 in [.0,1.] by XXREAL_1:1;
        then
A55:    [.0,s2.] c= [.0,1.] by A50,XXREAL_2:def 12;
        reconsider B=[.0,s2.] as Subset of I[01] by A50,A54,BORSUK_1:40
,XXREAL_2:def 12;
A56:    B is connected by A35,A50,A54,BORSUK_1:40,BORSUK_4:24;
A57:    0 in B by A35,XXREAL_1:1;
A58:    s2 in B by A35,XXREAL_1:1;
        consider xc being Point of I[01] such that
A59:    xc in B and
A60:    k.xc =k.s1 by A40,A44,A52,A53,A56,A57,A58,TOPREAL5:5;
        reconsider rxc=xc as Real;
A61:    for x1,x2 being set st x1 in dom k & x2 in dom k &
        k.x1=k.x2 holds x1=x2
        proof
          let x1,x2 be set;
          assume that
A62:      x1 in dom k and
A63:      x2 in dom k and
A64:      k.x1=k.x2;
          reconsider r1=x1 as Point of I[01] by A62;
          reconsider r2=x2 as Point of I[01] by A63;
A65:      k.x1=h.(g1.x1) by A62,FUNCT_1:12
            .=h1.(g1.r1)+h2.(g1.r1) by A43
            .=(g1.r1)`1+proj2.(g1.r1) by PSCOMP_1:def 5
            .=(g1.r1)`1+(g1.r1)`2 by PSCOMP_1:def 6;
A66:      k.x2=h.(g1.x2) by A63,FUNCT_1:12
            .=h1.(g1.r2)+h2.(g1.r2) by A43
            .=(g1.r2)`1+proj2.(g1.r2) by PSCOMP_1:def 5
            .=(g1.r2)`1+(g1.r2)`2 by PSCOMP_1:def 6;
A67:      g.r1 in Upper_Arc(K) by A39;
A68:      g.r2 in Upper_Arc(K) by A39;
          reconsider gr1=g.r1 as Point of TOP-REAL 2 by A67;
          reconsider gr2=g.r2 as Point of TOP-REAL 2 by A68;
          now per cases by A12,A39,XBOOLE_0:def 3;
            case
              A69:          g
.r1 in LSeg(|[a,c]|,|[a,d]|) & g.r2 in LSeg(|[a,c]|,|[a,d]|);
              then
A70:          (gr1)`1=a by A2,Th1;
              (gr2)`1=a by A2,A69,Th1;
              then |[(gr1)`1,(gr1)`2]|=g.r2 by A64,A65,A66,A70,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A37,A38,FUNCT_1:def 4;
            end;
            case
              A71:          g
.r1 in LSeg(|[a,c]|,|[a,d]|) & g.r2 in LSeg(|[a,d]|,|[b,d]|);
              then
A72:          (gr1)`1=a by A2,Th1;
A73:          (gr1)`2 <=d by A2,A71,Th1;
A74:          (gr2)`2=d by A1,A71,Th3;
A75:          a <=(gr2)`1 by A1,A71,Th3;
A76:          a+(gr1)`2=(gr2)`1 +d by A1,A64,A65,A66,A71,A72,Th3;
A77:          now
                assume a<>gr2`1;
                then a<gr2`1 by A75,XXREAL_0:1;
                hence contradiction by A73,A76,XREAL_1:8;
              end;
              now
                assume gr1`2<>d;
                then d>gr1`2 by A73,XXREAL_0:1;
                hence contradiction by A64,A65,A66,A72,A74,A75,XREAL_1:8;
              end;
              then |[(gr1)`1,(gr1)`2]|=g.r2 by A72,A74,A77,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A37,A38,FUNCT_1:def 4;
            end;
            case
              A78:          g
.r1 in LSeg(|[a,d]|,|[b,d]|) & g.r2 in LSeg(|[a,c]|,|[a,d]|);
              then
A79:          (gr2)`1=a by A2,Th1;
A80:          (gr2)`2 <=d by A2,A78,Th1;
A81:          (gr1)`2=d by A1,A78,Th3;
A82:          a <=(gr1)`1 by A1,A78,Th3;
A83:          a+(gr2)`2=(gr1)`1 +d by A1,A64,A65,A66,A78,A79,Th3;
A84:          now
                assume a<>gr1`1;
                then a<gr1`1 by A82,XXREAL_0:1;
                hence contradiction by A80,A83,XREAL_1:8;
              end;
              now
                assume gr2`2<>d;
                then d>gr2`2 by A80,XXREAL_0:1;
                hence contradiction by A64,A65,A66,A79,A81,A82,XREAL_1:8;
              end;
              then |[(gr2)`1,(gr2)`2]|=g.r1 by A79,A81,A84,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A37,A38,FUNCT_1:def 4;
            end;
            case
              A85:          g
.r1 in LSeg(|[a,d]|,|[b,d]|) & g.r2 in LSeg(|[a,d]|,|[b,d]|);
              then
A86:          (gr1)`2=d by A1,Th3;
              (gr2)`2=d by A1,A85,Th3;
              then |[(gr1)`1,(gr1)`2]|=g.r2 by A64,A65,A66,A86,EUCLID:53;
              then g.r1=g.r2 by EUCLID:53;
              hence thesis by A37,A38,FUNCT_1:def 4;
            end;
          end;
          hence thesis;
        end;
A87:    dom k=[.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
        then s1 in dom k by A32,A33,XXREAL_1:1;
        then rxc=s1 by A55,A59,A60,A61,A87;
        hence contradiction by A46,A59,XXREAL_1:1;
      end;
      hence thesis;
    end;
    then LE p1,p2,Upper_Arc(K),W-min(K),E-max(K) by A3,A4,A13,JORDAN5C:def 3;
    hence thesis by A3,A4,A13,JORDAN6:def 10;
  end;
end;
