reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem
  a <= b & c <= d implies N-bound closed_inside_of_rectangle(a,b,c,d) = d
proof
  assume that
A1: a <= b and
A2: c <= d;
  set X = closed_inside_of_rectangle(a,b,c,d);
  reconsider Z = (proj2|X).:the carrier of (T2|X) as Subset of REAL;
A3: X = the carrier of (T2|X) by PRE_TOPC:8;
A4: for p be Real st p in Z holds p <= d
  proof
    let p be Real;
    assume p in Z;
    then consider p0 being object such that
A5: p0 in the carrier of T2|X and p0 in the carrier of T2|X and
A6: p = (proj2|X).p0 by FUNCT_2:64;
    ex p1 st p0 = p1 & a <= p1`1 & p1`1 <= b & c <= p1`2 & p1`2 <= d by A3,A5;
    hence thesis by A3,A5,A6,PSCOMP_1:23;
  end;
A7: for q being Real st
  for p being Real st p in Z holds p <= q holds d <= q
  proof
    let q be Real such that
A8: for p being Real st p in Z holds p <= q;
A9: |[b,d]|`1 = b by EUCLID:52;
A10: |[b,d]|`2 = d by EUCLID:52;
    then
A11: |[b,d]| in X by A1,A2,A9;
    then (proj2|X). |[b,d]| = |[b,d]|`2 by PSCOMP_1:23;
    hence thesis by A3,A8,A10,A11,FUNCT_2:35;
  end;
  |[a,c]| in X by A1,A2,TOPREALA:31;
  hence thesis by A4,A7,SEQ_4:46;
end;
