reserve p,q,r,s,A,B for Element of PL-WFF,
  F,G,H for Subset of PL-WFF,
  k,n for Element of NAT,
  f,f1,f2 for FinSequence of PL-WFF;
reserve M for PLModel;

theorem sth:
  F |- A implies F |= A
 proof
  assume F|-A;
  then consider f such that
   A1: f.len f=A and
   A2: 1<=len f and
   A3: for i be Nat st 1<=i & i<=len f holds prc f,F,i;
  defpred P[Nat] means
   1<=$1 & $1<=len f implies F|=f/.$1;
  A4: for i being Nat st for j being Nat st j<i holds P[j] holds P[i]
  proof
   let i be Nat;
   assume A5: for j being Nat st j<i holds P[j];
   per cases by NAT_1:14;
   suppose i=0;
    hence P[i];
   end;
   suppose not i<1;
    assume that
     A6: 1<=i and
     A7: i<=len f;
    per cases by A3,A6,A7,defprc;
    suppose f.i in PL_axioms;
     then f/.i in PL_axioms by A6,A7,LTLAXIO5:1;then
     f/.i is axpl1 or f/.i is axpl2 or f/.i is axpl3 by Th36;
     hence F|=f/.i by Th37;
    end;
    suppose f.i in F;
     then A9: f/.i in F by A6,A7,LTLAXIO5:1;
     thus F|=f/.i
     proof
      let M;
      assume M|=F;
      hence M|=f/.i by A9;
     end;
    end;
    suppose ex j,k be Nat st 1<=j & j<i & 1<=k & k<i & f/.j,f/.k MP_rule f/.i;
     then consider j,k be Nat such that
      A10: 1<=j and
      A11: j<i and
      A12: 1<=k and
      A13: k<i and
      A14: f/.j,f/.k MP_rule f/.i;
U1:   k<=len f by A7,A13,XXREAL_0:2;
     A16: j<=len f by A7,A11,XXREAL_0:2;
     F|=f/.j=>f/.i by A5,A12,A13,A14,U1;
      hence F|=f/.i by A5,A10,A11,A16,th24;
    end;
   end;
  end;
  A22: for i be Nat holds P[i] from NAT_1:sch 4(A4);
  f/.len f=A by A1,A2,LTLAXIO5:1;
  hence F|=A by A2,A22;
 end;
