reserve i,j for Nat;
reserve i,j for Nat,
  x for variable,
  l for quasi-loci;
reserve C for initialized ConstructorSignature,
  c for constructor OperSymbol of C;
reserve a,a9 for quasi-adjective,
  t,t1,t2 for quasi-term,
  T for quasi-type,

  c for Element of Constructors;

theorem Th57:
  for n being Nat for s being SortSymbol of MaxConstrSign
  ex m being constructor OperSymbol of s
  st len the_arity_of m = n
  proof set C = MaxConstrSign;
    let n be Nat;
    let s be SortSymbol of C;
    deffunc F(Nat) = [{},$1];
    consider l being FinSequence such that
A1: len l = n and
A2: for i st i in dom l holds l.i = F(i) from FINSEQ_1:sch 2;
A3: l is one-to-one
    proof
      let i,j be object such that
A4:   i in dom l & j in dom l & l.i = l.j;
      reconsider i,j as Nat by A4;
      l.i = F(i) & l.i = F(j) by A2,A4; then
      i = F(j)`2;
      hence thesis;
    end;
    rng l c= Vars
    proof
      let z be object; assume z in rng l; then
      consider a being object such that
A5:   a in dom l & z = l.a by FUNCT_1:def 3;
      reconsider a as Nat by A5;
      z = F(a) by A2,A5;
      hence thesis by ABCMIZ_1:25;
    end; then
    reconsider l as one-to-one FinSequence of Vars by A3,FINSEQ_1:def 4;
    for i being Nat, x being variable st i in dom l & x = l.i
    for y being variable st y in vars x
    ex j being Nat st j in dom l & j < i & y = l.j
    proof
      let i,x; assume i in dom l & x = l.i; then
      x = F(i) by A2;
      hence thesis;
    end; then
    reconsider l as quasi-loci by ABCMIZ_1:30;
    set m = [s,[l,0]];
 the carrier of C = {a_Type, an_Adj, a_Term} by ABCMIZ_1:def 9;
then A6: m in Constructors by Th28; then
    m in {*,non_op}\/Constructors by XBOOLE_0:def 3; then
    reconsider m as constructor OperSymbol of C by A6,Th42,ABCMIZ_1:def 24;
    the_result_sort_of m = m`1 by ABCMIZ_1:def 24 .= s; then
    reconsider m as constructor OperSymbol of s by ABCMIZ_1:def 32;
    take m;
    thus len the_arity_of m = card m`2`1 by ABCMIZ_1:def 24
      .= card [l,0]`1
      .= card l
      .= n by A1;
  end;
