reserve A for preIfWhileAlgebra,
  C,I,J for Element of A;
reserve S for non empty set,
  T for Subset of S,
  s for Element of S;

theorem Th57:
  for X being disjoint_with_NAT non empty set
  holds EmptyIns FreeUnivAlgNSG(ECIW-signature,X) = 1-tree {}
proof
  let X be disjoint_with_NAT non empty set;
  set S = ECIW-signature;
  reconsider s = S as non empty FinSequence of omega;
  set A = FreeUnivAlgNSG(S,X);
A1: 1 in dom the charact of A by Def10;
  reconsider f = (the charact of A).1 as 0-ary non empty homogeneous
  quasi_total PartFunc of (the carrier of A)*, the carrier of A by Def10;
A2: f = FreeOpNSG(1,S,X) by A1,FREEALG:def 11;
A3: 1 in dom S by Th54;
  then
A4: s/.1 = S.1 by PARTFUN1:def 6;
A5: dom FreeOpNSG(1,S,X) = (s/.1)-tuples_on TS(DTConUA(S,X))
  by A3,FREEALG:def 10
    .= {{}} by A4,Th54,COMPUT_1:5;
A6: {} in {{}} by TARSKI:def 1;
A7: {} = <*> TS(DTConUA(S,X));
  thus EmptyIns A = f.{} by A1,SUBSET_1:def 8
    .= Sym(1,S,X)-tree({}) by A2,A3,A5,A6,A7,FREEALG:def 10
    .= 1-tree {} by A3,FREEALG:def 9;
end;
