 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x in dom tan & x+h in dom tan implies
  fD(tan(#)tan(#)sin,h).x = sin.(x+h)|^3*(cos.(x+h))"|^2 - sin.x|^3*(cos.x)"|^2
proof
  set f=tan(#)tan(#)sin;
  assume
A1: x in dom tan & x+h in dom tan;
  x in dom f & x+h in dom f
  proof
    set f1=tan(#)tan;
    set f2=sin;
A2: x in dom f1 & x+h in dom f1
    proof
      x in dom tan /\ dom tan & x+h in dom tan /\ dom tan by A1;
      hence thesis by VALUED_1:def 4;
    end;
    x in dom f1 /\ dom f2 & x+h in dom f1 /\ dom f2
                                        by A2,SIN_COS:24,XBOOLE_0:def 4;
    hence thesis by VALUED_1:def 4;
  end;
  then
  fD(f,h).x = (tan(#)tan(#)sin).(x+h) - (tan(#)tan(#)sin).x by DIFF_1:1
    .= (tan(#)tan).(x+h)*sin.(x+h) - (tan(#)tan(#)sin).x by VALUED_1:5
    .= (tan(#)tan).(x+h)*sin.(x+h) - (tan(#)tan).x*sin.x by VALUED_1:5
    .= tan.(x+h)*tan.(x+h)*sin.(x+h) - (tan(#)tan).x*sin.x by VALUED_1:5
    .= tan.(x+h)*tan.(x+h)*sin.(x+h) - tan.x*tan.x*sin.x by VALUED_1:5
    .= (sin.(x+h)*(cos.(x+h))")*tan.(x+h)*sin.(x+h)
       - tan.x*tan.x*sin.x by A1,RFUNCT_1:def 1
    .= (sin.(x+h)*(cos.(x+h))")*(sin.(x+h)*(cos.(x+h))")*sin.(x+h)
       - tan.x*tan.x*sin.x by A1,RFUNCT_1:def 1
    .= (sin.(x+h)*(cos.(x+h))")*(sin.(x+h)*(cos.(x+h))")*sin.(x+h)
       - (sin.x*(cos.x)")*tan.x*sin.x by A1,RFUNCT_1:def 1
    .= (sin.(x+h)*(cos.(x+h))")*(sin.(x+h)*(cos.(x+h))")*sin.(x+h)
       - (sin.x*(cos.x)")*(sin.x*(cos.x)")*sin.x by A1,RFUNCT_1:def 1
    .= (sin.(x+h)*sin.(x+h)*sin.(x+h))*((cos.(x+h))"*(cos.(x+h))")
       - (sin.x*sin.x*sin.x)*((cos.x)"*(cos.x)")
    .= (sin.(x+h)|^1*sin.(x+h)*sin.(x+h))*((cos.(x+h))"*(cos.(x+h))")
       - (sin.x*sin.x*sin.x)*((cos.x)"*(cos.x)")
    .= (sin.(x+h)|^(1+1)*sin.(x+h))*((cos.(x+h))"*(cos.(x+h))")
       - (sin.x*sin.x*sin.x)*((cos.x)"*(cos.x)") by NEWTON:6
    .= sin.(x+h)|^(2+1)*((cos.(x+h))"*(cos.(x+h))")
       - (sin.x*sin.x*sin.x)*((cos.x)"*(cos.x)") by NEWTON:6
    .= sin.(x+h)|^3*((cos.(x+h))"|^1*(cos.(x+h))")
       - (sin.x*sin.x*sin.x)*((cos.x)"*(cos.x)")
    .= sin.(x+h)|^3*(cos.(x+h))"|^(1+1)
       - (sin.x*sin.x*sin.x)*((cos.x)"*(cos.x)") by NEWTON:6
    .= sin.(x+h)|^3*(cos.(x+h))"|^2
       - (sin.x|^1*sin.x*sin.x)*((cos.x)"*(cos.x)")
    .= sin.(x+h)|^3*(cos.(x+h))"|^2
       - (sin.x|^(1+1)*sin.x)*((cos.x)"*(cos.x)") by NEWTON:6
    .= sin.(x+h)|^3*(cos.(x+h))"|^2
       - sin.x|^(2+1)*((cos.x)"*(cos.x)") by NEWTON:6
    .= sin.(x+h)|^3*(cos.(x+h))"|^2
       - sin.x|^3*((cos.x)"|^1*(cos.x)")
    .= sin.(x+h)|^3*(cos.(x+h))"|^2
       - sin.x|^3*(cos.x)"|^(1+1) by NEWTON:6
    .= sin.(x+h)|^3*(cos.(x+h))"|^2 - sin.x|^3*(cos.x)"|^2;
  hence thesis;
end;
