
theorem
for F being Field,
    E being FieldExtension of F
for a being F-algebraic Element of E
holds FAdj(F,{a}) is F-normal iff MinPoly(a,F) splits_in FAdj(F,{a})
proof
let F be Field, E be FieldExtension of F, a be F-algebraic Element of E;
set K = FAdj(F,{a});
    {a} is Subset of K & a in {a} by FIELD_6:35,TARSKI:def 1; then
reconsider a1 = a as Element of K;
    E is K-extending by FIELD_4:7; then
    Ext_eval(MinPoly(a,F),a1)
       = Ext_eval(MinPoly(a,F),a) by FIELD_6:11
      .= 0.E by FIELD_6:52
      .= 0.K by EC_PF_1:def 1; then
H1: a1 is_a_root_of MinPoly(a,F),K by FIELD_4:def 2;
    Roots(K,MinPoly(a,F))
       = {b where b is Element of K : b is_a_root_of MinPoly(a,F),K}
    by FIELD_4:def 4; then
H2: a in Roots(K,MinPoly(a,F)) by H1;
now assume AS: MinPoly(a,F) splits_in K;
   now let U be FieldExtension of F;
     assume B: MinPoly(a,F) splits_in U & U is Subfield of K;
     then K is U-extending by FIELD_4:7;
     then Roots(K,MinPoly(a,F)) c= the carrier of U by AS,B,FIELD_8:27;
     then a in the carrier of U by H2;
     then {a} c= the carrier of U by TARSKI:def 1;
     then {a} is Subset of U & F is Subfield of U & U is Subfield of E
       by FIELD_4:7,B,EC_PF_1:5;
     then K is Subfield of U by FIELD_6:37;
     hence U == K by B,FIELD_7:def 2;
     end;
   then K is SplittingField of MinPoly(a,F) by AS,FIELD_8:def 1;
   hence K is F-normal;
   end;
hence thesis by H1,FIELD_4:def 3;
end;
