
theorem Th57:
  for G1, G2 being _Graph, H being Subgraph of G1
  for F being PGraphMapping of G1, G2
  holds (F is empty implies F | H is empty) &
    (F is total implies F | H is total) &
    (F is one-to-one implies F | H is one-to-one) &
    (F is weak_SG-embedding implies F | H is weak_SG-embedding) &
    (F is semi-continuous implies F | H is semi-continuous) &
    (F is non onto implies F | H is non onto) &
    (F is directed implies F | H is directed) &
    (F is semi-Dcontinuous implies F | H is semi-Dcontinuous)
proof
  let G1, G2 be _Graph, H be Subgraph of G1, F be PGraphMapping of G1, G2;
  thus F is empty implies F|H is empty;
  thus A1: F is total implies F|H is total
  proof
    assume A2: F is total;
    A3: dom (F|H)_V = dom F_V /\ the_Vertices_of H by RELAT_1:61
      .= the_Vertices_of H by A2, XBOOLE_1:28;
    dom (F|H)_E = dom F_E /\ the_Edges_of H by RELAT_1:61
      .= the_Edges_of H by A2, XBOOLE_1:28;
    hence F|H is total by A3;
  end;
  thus F is one-to-one implies F|H is one-to-one by FUNCT_1:52;
  hence F is weak_SG-embedding implies F|H is weak_SG-embedding by A1;
  thus F is semi-continuous implies F|H is semi-continuous
  proof
    assume A4: F is semi-continuous;
    reconsider f = F_V | the_Vertices_of H
      as PartFunc of the_Vertices_of H, the_Vertices_of G2 by PARTFUN1:10;
    reconsider g = F_E | the_Edges_of H
      as PartFunc of the_Edges_of H, the_Edges_of G2 by PARTFUN1:10;
    now
      let e,v,w be object;
      assume e in dom g & v in dom f & w in dom f;
      then A5: e in dom F_E & e in the_Edges_of H &
        v in dom F_V & v in the_Vertices_of H &
        w in dom F_V & w in the_Vertices_of H by RELAT_1:57;
      then A6: g.e = F_E.e & f.v = F_V.v & f.w = F_V.w by FUNCT_1:49;
      assume g.e Joins f.v,f.w,G2;
      then e Joins v,w,G1 by A4, A5, A6;
      hence e Joins v,w,H by A5, GLIB_000:73;
    end;
    hence thesis;
  end;
  F|H is onto implies F is onto
  proof
    assume F|H is onto;
    then the_Vertices_of G2 c= rng F_V & the_Edges_of G2 c= rng F_E
      by RELAT_1:70;
    hence F is onto by XBOOLE_0:def 10;
  end;
  hence F is non onto implies F|H is non onto;
  thus F is directed implies F|H is directed
  proof
    assume A7: F is directed;
    let e,v,w be object;
    assume e in dom (F|H)_E & v in dom (F|H)_V & w in dom (F|H)_V;
    then A8: e in dom F_E & e in the_Edges_of H &
      v in dom F_V & v in the_Vertices_of H &
      w in dom F_V & w in the_Vertices_of H by RELAT_1:57;
    then A9: (F|H)_E.e = F_E.e & (F|H)_V.v = F_V.v & (F|H)_V.w = F_V.w
      by FUNCT_1:49;
    assume A10: e DJoins v,w,H;
    v is set & w is set by TARSKI:1;
    then e DJoins v,w,G1 by A10, GLIB_000:72;
    hence (F|H)_E.e DJoins (F|H)_V.v,(F|H)_V.w,G2 by A7, A8, A9;
  end;
  thus F is semi-Dcontinuous implies F|H is semi-Dcontinuous
  proof
    assume A11: F is semi-Dcontinuous;
    let e,v,w be object;
    assume e in dom (F|H)_E & v in dom (F|H)_V & w in dom (F|H)_V;
    then A12: e in dom F_E & e in the_Edges_of H &
      v in dom F_V & v in the_Vertices_of H &
      w in dom F_V & w in the_Vertices_of H by RELAT_1:57;
    then A13: (F|H)_E.e = F_E.e & (F|H)_V.v = F_V.v & (F|H)_V.w = F_V.w
      by FUNCT_1:49;
    assume (F|H)_E.e DJoins (F|H)_V.v,(F|H)_V.w,G2;
    then e DJoins v,w,G1 by A11, A12, A13;
    hence e DJoins v,w,H by A12, GLIB_000:73;
  end;
end;
