reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th57:
  for f be PartFunc of CNS,RNS st f is_continuous_on X & X1 c= X
  holds f is_continuous_on X1
proof
  let f be PartFunc of CNS,RNS;
  assume that
A1: f is_continuous_on X and
A2: X1 c= X;
  X c= dom f by A1;
  hence
A3: X1 c= dom f by A2;
  let r be Point of CNS;
  assume
A4: r in X1;
  then
A5: f|X is_continuous_in r by A1,A2;
  thus f|X1 is_continuous_in r
  proof
    dom f /\ X1 c= dom f /\ X by A2,XBOOLE_1:26;
    then dom (f|X1) c= dom f /\ X by RELAT_1:61;
    then
A6: dom (f|X1) c= dom (f|X) by RELAT_1:61;
    r in dom f /\ X1 by A3,A4,XBOOLE_0:def 4;
    hence
A7: r in dom (f|X1) by RELAT_1:61;
    then
A8: (f|X)/.r = f/.r by A6,PARTFUN2:15
      .= (f|X1)/.r by A7,PARTFUN2:15;
    let s1 be sequence of CNS such that
A9: rng s1 c= dom (f|X1) and
A10: s1 is convergent & lim s1 = r;
A11: rng s1 c= dom (f|X) by A9,A6;
A12: now
      let n;
      dom s1 = NAT by FUNCT_2:def 1;
      then
A13:  s1.n in rng s1 by FUNCT_1:3;
      thus ((f|X)/*s1).n = (f|X)/.(s1.n) by A9,A6,FUNCT_2:109,XBOOLE_1:1
        .= f/.(s1.n) by A11,A13,PARTFUN2:15
        .= (f|X1)/.(s1.n) by A9,A13,PARTFUN2:15
        .= ((f|X1)/*s1).n by A9,FUNCT_2:109;
    end;
    (f|X)/*s1 is convergent & (f|X)/.r = lim ((f|X)/*s1) by A5,A10,A11;
    hence thesis by A8,A12,FUNCT_2:63;
  end;
end;
