reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th57:
  x * 1_No = x
proof
  defpred P[Ordinal] means for x st born x c= $1 holds x*1_No =x;
  A1: for D be Ordinal st for C be Ordinal st C in D holds P[C] holds P[D]
  proof
    let D be Ordinal such that A2: for C be Ordinal st C in D holds P[C];
    let x such that A3:born x c= D;
    A4: comp(R_x,x,1_No,R_1_No) = {} & comp(L_x,x,1_No,R_1_No) ={} by Th49;
    A5: for X be surreal-membered set st X c= L_x \/R_x
    holds comp(X,x,1_No,L_1_No)=X
    proof
      let X be surreal-membered set such that A6:X c= L_x \/R_x;
      thus comp(X,x,1_No,L_1_No)c=X
      proof
        let o such that A7: o in comp(X,x,1_No,L_1_No);
        consider x1,y1 be Surreal such that
        A8: o = (x1*1_No) +' (x*y1) +' -' (x1*y1) & x1 in X & y1 in L_1_No
        by A7,Def14;
        A9:y1=0_No by A8,TARSKI:def 1;
        A10: born x1 in born x by A8,A6,SURREALO:1;
        o = x1*1_No + x*y1 +- 0_No by A8,A9,Th56
        .= x1*1_No + 0_No + 0_No by A9,Th56
        .= x1*1_No;
        hence thesis by A10,A2,A3,A8;
      end;
      let o such that A11: o in X;
      reconsider x1=o as Surreal by A11,SURREAL0:def 16;
      A12: born x1 in born x by A11,A6,SURREALO:1;
      0_No in L_1_No by TARSKI:def 1;
      then
      A13: x1*1_No + x*0_No + - x1*0_No in comp(X,x,1_No,L_1_No) by A11,Def14;
      x1*1_No + x*0_No + - x1*0_No = x1*1_No + x*0_No +- 0_No by Th56
      .= x1*1_No + 0_No + 0_No by Th56
      .= x1*1_No;
      hence thesis by A12,A2,A3,A13;
    end;
    A14: comp(L_x,x,1_No,L_1_No)=L_x & comp(R_x,x,1_No,L_1_No)=R_x
    by A5,XBOOLE_1:7;
    x * 1_No = [comp(L_x,x,1_No,L_1_No) \/ comp(R_x,x,1_No,R_1_No),
    comp(L_x,x,1_No,R_1_No) \/ comp(R_x,x,1_No,L_1_No)] by Th50
    .=[L_x,R_x] by A4,A14;
    hence thesis;
  end;
  for D be Ordinal holds P[D] from ORDINAL1:sch 2(A1);
  hence thesis;
end;
