reserve x,y,y1,y2 for object;
reserve GF for add-associative right_zeroed right_complementable Abelian
  associative well-unital distributive non empty doubleLoopStr,
  V,X,Y for Abelian add-associative right_zeroed right_complementable
  vector-distributive scalar-distributive scalar-associative scalar-unital non
  empty ModuleStr over GF;
reserve a for Element of GF;
reserve u,u1,u2,v,v1,v2 for Element of V;
reserve W,W1,W2 for Subspace of V;
reserve V1 for Subset of V;
reserve w,w1,w2 for Element of W;
reserve B,C for Coset of W;

theorem
  for GF being Field, V being VectSp of GF, a being Element of GF, v
being Element of V, W being Subspace of V st a <> 1_GF & a * v in v + W holds v
  in W
proof
  let GF be Field, V be VectSp of GF, a be Element of GF, v be Element of V, W
  be Subspace of V;
  assume that
A1: a <> 1_GF and
A2: a * v in v + W;
A3: a - 1_GF <> 0.GF by A1,RLVECT_1:21;
  consider u being Element of V such that
A4: a * v = v + u and
A5: u in W by A2;
  u = u + 0.V by RLVECT_1:4
    .= u + (v - v) by VECTSP_1:19
    .= a * v - v by A4,RLVECT_1:def 3
    .= a * v - 1_GF * v
    .= (a - 1_GF) * v by Lm1;
  then (a - 1_GF)" * u = ((a - 1_GF)" * (a - 1_GF)) * v by VECTSP_1:def 16;
  then 1_GF * v = (a - 1_GF)" * u by A3,VECTSP_1:def 10;
  then v = (a - 1_GF)" * u;
  hence thesis by A5,Th21;
end;
