reserve a,b,c,d,e,f for Real,
        k,m for Nat,
        D for non empty set,
        V for non trivial RealLinearSpace,
        u,v,w for Element of V,
        p,q,r for Element of ProjectiveSpace(V);
reserve o,p,q,r,s,t for Point of TOP-REAL 3,
        M for Matrix of 3,F_Real;

theorem Th48:
  for u,v,w,x being Element of TOP-REAL 3 st
  u is not zero & x is not zero &
  Dir u = Dir x holds |{u,v,w}| = 0 iff |{x,v,w}| = 0
  proof
    let u,v,w,x being Element of TOP-REAL 3;
    assume that
A1: u is not zero and
A2: x is not zero and
A3: Dir u = Dir x;
A4: are_Prop u,x by A1,A2,A3,ANPROJ_1:22;
    then consider a be Real such that
    a <> 0 and
A5: u = a * x by ANPROJ_1:1;
    consider b be Real such that
    b <> 0 and
A6: x = b * u by A4,ANPROJ_1:1;
    hereby
      assume
A7:   |{u,v,w}| = 0;
      thus |{x,v,w}| = b * |{u,v,w}| by A6,Th26
                    .= 0 by A7;
    end;
    assume
A8: |{x,v,w}| = 0;
    thus |{u,v,w}| = a * |{x,v,w}| by A5,Th26
                  .= 0 by A8;
  end;
