reserve
  X for non empty set,
  FX for Filter of X,
  SFX for Subset-Family of X;

theorem
  for X be non empty set,F1,F2 be Filter of X st
  for M1 be Element of F1,M2 be Element of F2 holds M1/\M2 is non empty
  holds
  ex F be Filter of X st F is_filter-finer_than F1 & F is_filter-finer_than F2
  proof
    let X be non empty set,F1,F2 be Filter of X;
    assume
A1: for M1 be Element of F1,M2 be Element of F2 holds
    M1/\M2 is non empty;
    set F=the set of all M1/\M2 where M1 is Element of F1,M2 is Element of F2;
    take F;
    F is non empty Subset-Family of X
    proof
      set M1=the Element of F1;
      set M2=the Element of F2;
A2:   M1/\M2 in F;
      F c= bool X
      proof
        let x be object;
        assume x in F;
        then
        consider M1 be Element of F1,M2 be Element of F2 such that
A3:     x=M1/\M2;
        thus x in bool X by A3;
      end;
      hence thesis by A2;
    end;
    then reconsider F as non empty Subset-Family of X;
    now
      hereby
        assume {} in F;
        then consider M1 be Element of F1,M2 be Element of F2 such that
A4:     {}=M1/\M2;
        thus not {} in F by A4,A1;
      end;
      hereby
        let Y1,Y2 be Subset of X;
        hereby
          assume that
A5:       Y1 in F and
A6:       Y2 in F;
          consider M1 be Element of F1,M2 be Element of F2 such that
A7:       Y1=M1/\M2 by A5;
          consider M3 be Element of F1,M4 be Element of F2 such that
A8:       Y2=M3/\M4 by A6;
          Y1/\Y2=M1/\(M2/\(M3/\M4)) by A7,A8,XBOOLE_1:16;
          then Y1/\Y2=M1/\(M3/\(M4/\M2)) by XBOOLE_1:16;
          then
A9:       Y1 /\ Y2 = (M1/\M3)/\(M2/\M4) by XBOOLE_1:16;
          M1/\M3 is Element of F1 & M2/\M4 is Element of F2 by CARD_FIL:def 1;
          hence Y1 /\ Y2 in F by A9;
        end;
        assume that
A10:    Y1 in F and
A11:    Y1 c= Y2;
        consider M1 be Element of F1,M2 be Element of F2 such that
A12:    Y1=M1/\M2 by A10;
        Y2\/(M1/\M2)=Y2 by A11,A12,XBOOLE_1:12;
        then
A13:    Y2=(M1\/Y2)/\(M2\/Y2) by XBOOLE_1:24;
        M1 c= M1\/Y2 & M2 c= M2\/Y2 by XBOOLE_1:7;
        then M1\/Y2 is Element of F1 & M2\/Y2 is Element of F2
        by CARD_FIL:def 1;
        hence Y2 in F by A13;
      end;
    end;
    then reconsider F0=F as Filter of X by CARD_FIL:def 1;
A14:
    X in F1 & X in F2 by CARD_FIL:5;
    F1 c= F0
    proof
      let x be object;
      assume
A15:  x in F1;
      then reconsider x as Subset of X;
      x=x/\X by XBOOLE_1:17,XBOOLE_1:19;
      hence thesis by A14,A15;
    end;
    then
A16:F0 is_filter-finer_than F1;
    F2 c= F0
    proof
      let x be object;
      assume
A17:  x in F2;
      then reconsider x as Subset of X;
      x=x/\X by XBOOLE_1:17,XBOOLE_1:19;
      hence thesis by A14,A17;
    end;
    then F0 is_filter-finer_than F2;
    hence thesis by A16;
  end;
