
theorem GauF07:
for a,b,c be Real, f be Function of REAL,REAL st
( b<>0 & for x be Real holds f.x= max(0,min(1, exp_R(-(x-a)^2/(2*b^2))+c)) )
holds
f is FuzzySet of REAL
proof
 let a,b,c be Real;
 let f be Function of REAL,REAL;
 assume  b <> 0;
 assume A2: for x be Real holds f.x= max(0,min(1, exp_R(-(x-a)^2/(2*b^2))+c));
 ex g being Function of REAL,REAL st
 for x be Real holds g.x= exp_R(-(x-a)^2/(2*b^2))+c
 proof
  deffunc H1(Element of REAL) = In(exp_R(-($1-a)^2/(2*b^2))+c,REAL);
  consider f being Function of REAL,REAL such that
  A1: for x being  Element of REAL holds f.x = H1(x) from FUNCT_2:sch 4;
  take f;
  for x be Real holds f.x= exp_R(-(x-a)^2/(2*b^2))+c
  proof
   let x be Real;
   reconsider x as Element of REAL by XREAL_0:def 1;
   f.x = H1(x) by A1;
   hence thesis;
  end;
  hence thesis;
 end; then
 consider g being Function of REAL,REAL such that
 A4:for x be Real holds g.x= exp_R(-(x-a)^2/(2*b^2))+c;
 for x be Real holds f.x= max(0,min(1, g.x))
 proof
  let x be Real;
  f.x = max(0,min(1, exp_R(-(x-a)^2/(2*b^2))+c)) by A2
     .= max(0,min(1, g.x)) by A4;
  hence thesis;
 end;
 hence thesis by MM40;
end;
