
theorem Th58:
  for a,b,c,d being Real, h being Function of TOP-REAL 2,
TOP-REAL 2,f being Function of I[01],TOP-REAL 2, O,I being Point of I[01] st c
<d & h=AffineMap(2/(b-a),-(b+a)/(b-a),2/(d-c),-(d+c)/(d-c)) & c <=(f.O)`2 & (f.
O)`2<(f.I)`2 & (f.I)`2<=d holds -1 <=((h*f).O)`2 & ((h*f).O)`2<((h*f).I)`2 & ((
  h*f).I)`2<=1
proof
  let a,b,c,d be Real, h be Function of TOP-REAL 2,TOP-REAL 2,f be
  Function of I[01],TOP-REAL 2, O,I be Point of I[01];
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  assume that
A1: c <d and
A2: h=AffineMap(A,B,C,D) and
A3: c <=(f.O)`2 and
A4: (f.O)`2<(f.I)`2 and
A5: (f.I)`2<=d;
A6: (h.(f.O))= |[A*((f.O)`1)+B,C*((f.O)`2)+D]| by A2,JGRAPH_2:def 2;
A7: d-c >0 by A1,XREAL_1:50;
  then
A8: C >0 by XREAL_1:139;
  (-1-D)/C =(-1+(d+c)/(d-c))/(2/(d-c))
    .=((-1)*(d-c)+(d+c))/(d-c)/(2/(d-c)) by A7,XCMPLX_1:113
    .= (c+c)/(d-c)/2*(d-c) by XCMPLX_1:82
    .= ((d-c)*((c+c)/(d-c)))/2
    .=(c+c)/2 by A7,XCMPLX_1:87
    .= c;
  then C*((-1-D)/C) <= C*((f.O)`2) by A3,A8,XREAL_1:64;
  then -1-D <= C*((f.O)`2) by A8,XCMPLX_1:87;
  then
A9: -1-D+D <= C*((f.O)`2)+D by XREAL_1:6;
A10: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A11: ((h*f).O)=(h.(f.O)) by FUNCT_1:13;
A12: ((h*f).I)=(h.(f.I)) by A10,FUNCT_1:13;
  (1-D)/C =(1+(d+c)/(d-c))/(2/(d-c))
    .=((1)*(d-c)+(d+c))/(d-c)/(2/(d-c)) by A7,XCMPLX_1:113
    .= (d+d)/(d-c)/2*(d-c) by XCMPLX_1:82
    .= ((d-c)*((d+d)/(d-c)))/2
    .=(d+d)/2 by A7,XCMPLX_1:87
    .= d;
  then C*((1- D)/C) >= C*((f.I)`2) by A5,A8,XREAL_1:64;
  then 1-D >= C*((f.I)`2) by A8,XCMPLX_1:87;
  then
A13: 1-D+D >= C*((f.I)`2)+D by XREAL_1:6;
A14: (h.(f.I))= |[A*((f.I)`1)+B,C*((f.I)`2)+D]| by A2,JGRAPH_2:def 2;
  C*((f.O)`2)< C*((f.I)`2) by A4,A8,XREAL_1:68;
  then C*((f.O)`2)+D < C*((f.I)`2)+D by XREAL_1:8;
  then C*((f.O)`2)+D < ((h*f).I)`2 by A12,A14,EUCLID:52;
  hence thesis by A11,A12,A6,A14,A9,A13,EUCLID:52;
end;
