reserve n for Nat;

theorem Th58:
  for C be Simple_closed_curve for i,j,k be Nat st 1 <
i & i < len Gauge(C,n) & 1 <= j & j <= k & k <= width Gauge(C,n) & LSeg(Gauge(C
  ,n)*(i,j),Gauge(C,n)*(i,k)) /\ L~Upper_Seq(C,n) = {Gauge(C,n)*(i,k)} & LSeg(
  Gauge(C,n)*(i,j),Gauge(C,n)*(i,k)) /\ L~Lower_Seq(C,n) = {Gauge(C,n)*(i,j)}
  holds LSeg(Gauge(C,n)*(i,j),Gauge(C,n)*(i,k)) meets Lower_Arc C
proof
  let C be Simple_closed_curve;
  let i,j,k be Nat;
  set Ga = Gauge(C,n);
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  set LA = Lower_Arc C;
  set Wmin = W-min L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Ebo = E-bound L~Cage(C,n);
  set Gij = Ga*(i,j);
  set Gik = Ga*(i,k);
  assume that
A1: 1 < i and
A2: i < len Ga and
A3: 1 <= j and
A4: j <= k and
A5: k <= width Ga and
A6: LSeg(Gij,Gik) /\ L~US = {Gik} and
A7: LSeg(Gij,Gik) /\ L~LS = {Gij} and
A8: LSeg(Gij,Gik) misses LA;
  Gij in {Gij} by TARSKI:def 1;
  then
A9: Gij in L~LS by A7,XBOOLE_0:def 4;
  Gik in {Gik} by TARSKI:def 1;
  then
A10: Gik in L~US by A6,XBOOLE_0:def 4;
  then
A11: j <> k by A1,A2,A3,A5,A9,Th57;
A12: j <= width Ga by A4,A5,XXREAL_0:2;
A13: 1 <= k by A3,A4,XXREAL_0:2;
A14: [i,j] in Indices Ga by A1,A2,A3,A12,MATRIX_0:30;
A15: [i,k] in Indices Ga by A1,A2,A5,A13,MATRIX_0:30;
  set go = R_Cut(US,Gik);
  set co = L_Cut(LS,Gij);
A16: len Ga = width Ga by JORDAN8:def 1;
A17: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A18: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
A19: Wmin`1 = Wbo by EUCLID:52
    .= Ga*(1,k)`1 by A5,A13,A16,JORDAN1A:73;
  len Ga >= 4 by JORDAN8:10;
  then
A20: len Ga >= 1 by XXREAL_0:2;
  then
A21: [1,k] in Indices Ga by A5,A13,MATRIX_0:30;
  then
A22: Gik <> US.1 by A1,A15,A18,A19,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2 by A10,JORDAN3:35
;
A23: len LS >= 1+2 by JORDAN1E:15;
  then
A24: len LS >= 1 by XXREAL_0:2;
  then
A25: 1 in dom LS by FINSEQ_3:25;
  len LS in dom LS by A24,FINSEQ_3:25;
  then
A26: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
A27: Wmin`1 = Wbo by EUCLID:52
    .= Ga*(1,k)`1 by A5,A13,A16,JORDAN1A:73;
A28: [i,j] in Indices Ga by A1,A2,A3,A12,MATRIX_0:30;
  then
A29: Gij <> LS.len LS by A1,A21,A26,A27,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2 by A9,JORDAN3:34;
A30: [len Ga,k] in Indices Ga by A5,A13,A20,MATRIX_0:30;
A31: LS.1 = LS/.1 by A25,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  Emax`1 = Ebo by EUCLID:52
    .= Ga*(len Ga,k)`1 by A5,A13,A16,JORDAN1A:71;
  then
A32: Gij <> LS.1 by A2,A28,A30,A31,JORDAN1G:7;
A33: len go >= 1+1 by TOPREAL1:def 8;
A34: Gik in rng US by A1,A2,A5,A10,A13,Th40,JORDAN1G:4;
  then
A35: go is_sequence_on Ga by Th38,JORDAN1G:4;
A36: len co >= 1+1 by TOPREAL1:def 8;
A37: Gij in rng LS by A1,A2,A3,A9,A12,Th40,JORDAN1G:5;
  then
A38: co is_sequence_on Ga by Th39,JORDAN1G:5;
  reconsider go as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A33,A35,JGRAPH_1:12,JORDAN8:5;
  reconsider co as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A36,A38,JGRAPH_1:12,JORDAN8:5;
A39: len go > 1 by A33,NAT_1:13;
  then
A40: len go in dom go by FINSEQ_3:25;
  then
A41: go/.len go = go.len go by PARTFUN1:def 6
    .= Gik by A10,JORDAN3:24;
  len co >= 1 by A36,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A42: co/.1 = co.1 by PARTFUN1:def 6
    .= Gij by A9,JORDAN3:23;
  reconsider m = len go - 1 as Nat by A40,FINSEQ_3:26;
A43: m+1 = len go;
  then
A44: len go-'1 = m by NAT_D:34;
A45: LSeg(go,m) c= L~go by TOPREAL3:19;
A46: L~go c= L~US by A10,JORDAN3:41;
  then LSeg(go,m) c= L~US by A45;
  then
A47: LSeg(go,m) /\ LSeg(Gik,Gij) c= {Gik} by A6,XBOOLE_1:26;
  m >= 1 by A33,XREAL_1:19;
  then
A48: LSeg(go,m) = LSeg(go/.m,Gik) by A41,A43,TOPREAL1:def 3;
  {Gik} c= LSeg(go,m) /\ LSeg(Gik,Gij)
  proof
    let x be object;
A49: Gik in LSeg(Gik,Gij) by RLTOPSP1:68;
    assume x in {Gik};
    then
A50: x = Gik by TARSKI:def 1;
    Gik in LSeg(go,m) by A48,RLTOPSP1:68;
    hence thesis by A50,A49,XBOOLE_0:def 4;
  end;
  then
A51: LSeg(go,m) /\ LSeg(Gik,Gij) = {Gik} by A47;
A52: LSeg(co,1) c= L~co by TOPREAL3:19;
A53: L~co c= L~LS by A9,JORDAN3:42;
  then LSeg(co,1) c= L~LS by A52;
  then
A54: LSeg(co,1) /\ LSeg(Gik,Gij) c= {Gij} by A7,XBOOLE_1:26;
A55: LSeg(co,1) = LSeg(Gij,co/.(1+1)) by A36,A42,TOPREAL1:def 3;
  {Gij} c= LSeg(co,1) /\ LSeg(Gik,Gij)
  proof
    let x be object;
A56: Gij in LSeg(Gik,Gij) by RLTOPSP1:68;
    assume x in {Gij};
    then
A57: x = Gij by TARSKI:def 1;
    Gij in LSeg(co,1) by A55,RLTOPSP1:68;
    hence thesis by A57,A56,XBOOLE_0:def 4;
  end;
  then
A58: LSeg(Gik,Gij) /\ LSeg(co,1) = {Gij} by A54;
A59: go/.1 = US/.1 by A10,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A60: go/.1 = LS/.len LS by JORDAN1F:8
    .= co/.len co by A9,Th35;
A61: rng go c= L~go by A33,SPPOL_2:18;
A62: rng co c= L~co by A36,SPPOL_2:18;
A63: {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A64: x = go/.1 by TARSKI:def 1;
    then
A65: x in rng go by FINSEQ_6:42;
    x in rng co by A60,A64,FINSEQ_6:168;
    hence thesis by A61,A62,A65,XBOOLE_0:def 4;
  end;
A66: LS.1 = LS/.1 by A25,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A67: [len Ga,j] in Indices Ga by A3,A12,A20,MATRIX_0:30;
  L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A68: x in L~go /\ L~co;
    then
A69: x in L~co by XBOOLE_0:def 4;
A70: now
      assume x = Emax;
      then
A71:  Emax = Gij by A9,A66,A69,JORDAN1E:7;
      Ga*(len Ga,j)`1 = Ebo by A3,A12,A16,JORDAN1A:71;
      then Emax`1 <> Ebo by A2,A14,A67,A71,JORDAN1G:7;
      hence contradiction by EUCLID:52;
    end;
    x in L~go by A68,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A46,A53,A69,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then x = Wmin or x = Emax by TARSKI:def 2;
    hence thesis by A59,A70,TARSKI:def 1;
  end;
  then
A72: L~go /\ L~co = {go/.1} by A63;
  set W2 = go/.2;
A73: 2 in dom go by A33,FINSEQ_3:25;
A74: now
    assume Gik`1 = Wbo;
    then Ga*(1,k)`1 = Ga*(i,k)`1 by A5,A13,A16,JORDAN1A:73;
    hence contradiction by A1,A15,A21,JORDAN1G:7;
  end;
  go = mid(US,1,Gik..US) by A34,JORDAN1G:49
    .= US|(Gik..US) by A34,FINSEQ_4:21,FINSEQ_6:116;
  then
A75: W2 = US/.2 by A73,FINSEQ_4:70;
  set pion = <*Gik,Gij*>;
A76: now
    let n be Nat;
    assume n in dom pion;
    then n in Seg 2 by FINSEQ_1:89;
    then n = 1 or n = 2 by FINSEQ_1:2,TARSKI:def 2;
    hence ex i,j be Nat st [i,j] in Indices Ga & pion/.n = Ga*(i,j)
    by A14,A15,FINSEQ_4:17;
  end;
A77: Gik <> Gij by A11,A14,A15,GOBOARD1:5;
A78: Gik`1 = Ga*(i,1)`1 by A1,A2,A5,A13,GOBOARD5:2
    .= Gij`1 by A1,A2,A3,A12,GOBOARD5:2;
  then LSeg(Gik,Gij) is vertical by SPPOL_1:16;
  then pion is being_S-Seq by A77,JORDAN1B:7;
  then consider pion1 be FinSequence of TOP-REAL 2 such that
A79: pion1 is_sequence_on Ga and
A80: pion1 is being_S-Seq and
A81: L~pion = L~pion1 and
A82: pion/.1 = pion1/.1 and
A83: pion/.len pion = pion1/.len pion1 and
A84: len pion <= len pion1 by A76,GOBOARD3:2;
  reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A80;
  set godo = go^'pion1^'co;
A85: 1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
A86: 1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
  len (go^'pion1) >= len go by TOPREAL8:7;
  then
A87: len (go^'pion1) >= 1+1 by A33,XXREAL_0:2;
  then
A88: len (go^'pion1) > 1+0 by NAT_1:13;
A89: len godo >= len (go^'pion1) by TOPREAL8:7;
  then
A90: 1+1 <= len godo by A87,XXREAL_0:2;
A91: US is_sequence_on Ga by JORDAN1G:4;
A92: go/.len go = pion1/.1 by A41,A82,FINSEQ_4:17;
  then
A93: go^'pion1 is_sequence_on Ga by A35,A79,TOPREAL8:12;
A94: (go^'pion1)/.len (go^'pion1) = pion/.len pion by A83,FINSEQ_6:156
    .= pion/.2 by FINSEQ_1:44
    .= co/.1 by A42,FINSEQ_4:17;
  then
A95: godo is_sequence_on Ga by A38,A93,TOPREAL8:12;
  LSeg(pion1,1) c= L~<*Gik,Gij*> by A81,TOPREAL3:19;
  then LSeg(pion1,1) c= LSeg(Gik,Gij) by SPPOL_2:21;
  then
A96: LSeg(go,len go-'1) /\ LSeg(pion1,1) c= {Gik} by A44,A51,XBOOLE_1:27;
A97: len pion1 >= 1+1 by A84,FINSEQ_1:44;
  {Gik} c= LSeg(go,m) /\ LSeg(pion1,1)
  proof
    let x be object;
    assume x in {Gik};
    then
A98: x = Gik by TARSKI:def 1;
A99: Gik in LSeg(go,m) by A48,RLTOPSP1:68;
    Gik in LSeg(pion1,1) by A41,A92,A97,TOPREAL1:21;
    hence thesis by A98,A99,XBOOLE_0:def 4;
  end;
  then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go } by A41,A44,A96;
  then
A100: go^'pion1 is unfolded by A92,TOPREAL8:34;
  len pion1 >= 2+0 by A84,FINSEQ_1:44;
  then
A101: len pion1-2 >= 0 by XREAL_1:19;
  len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
  then len (go^'pion1)-1 = len go + (len pion1-2)
    .= len go + (len pion1-'2) by A101,XREAL_0:def 2;
  then
A102: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A103: len pion1-1 >= 1 by A97,XREAL_1:19;
  then
A104: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A105: len pion1-'2+1 = len pion1-2+1 by A101,XREAL_0:def 2
    .= len pion1-'1 by A103,XREAL_0:def 2;
  len pion1-1+1 <= len pion1;
  then
A106: len pion1-'1 < len pion1 by A104,NAT_1:13;
  LSeg(pion1,len pion1-'1) c= L~<*Gik,Gij*> by A81,TOPREAL3:19;
  then LSeg(pion1,len pion1-'1) c= LSeg(Gik,Gij) by SPPOL_2:21;
  then
A107: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gij} by A58,XBOOLE_1:27;
  {Gij} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
  proof
    let x be object;
    assume x in {Gij};
    then
A108: x = Gij by TARSKI:def 1;
    pion1/.(len pion1-'1+1) = pion/.2 by A83,A104,FINSEQ_1:44
      .= Gij by FINSEQ_4:17;
    then
A109: Gij in LSeg(pion1,len pion1-'1) by A103,A104,TOPREAL1:21;
    Gij in LSeg(co,1) by A55,RLTOPSP1:68;
    hence thesis by A108,A109,XBOOLE_0:def 4;
  end;
  then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gij} by A107;
  then
A110: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) = {(go^'pion1)/.
  len (go^'pion1)} by A42,A92,A94,A105,A106,TOPREAL8:31;
A111: (go^'pion1) is non trivial by A87,NAT_D:60;
A112: rng pion1 c= L~pion1 by A97,SPPOL_2:18;
A113: {pion1/.1} c= L~go /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.1};
    then
A114: x = pion1/.1 by TARSKI:def 1;
    then
A115: x in rng pion1 by FINSEQ_6:42;
    x in rng go by A92,A114,FINSEQ_6:168;
    hence thesis by A61,A112,A115,XBOOLE_0:def 4;
  end;
  L~go /\ L~pion1 c= {pion1/.1}
  proof
    let x be object;
    assume
A116: x in L~go /\ L~pion1;
    then
A117: x in L~pion1 by XBOOLE_0:def 4;
    x in L~go by A116,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~US by A46,A117,XBOOLE_0:def 4;
    hence thesis by A6,A41,A81,A92,SPPOL_2:21;
  end;
  then
A118: L~go /\ L~pion1 = {pion1/.1} by A113;
  then
A119: (go^'pion1) is s.n.c. by A92,Th54;
  rng go /\ rng pion1 c= {pion1/.1} by A61,A112,A118,XBOOLE_1:27;
  then
A120: go^'pion1 is one-to-one by Th55;
A121: pion/.len pion = pion/.2 by FINSEQ_1:44
    .= co/.1 by A42,FINSEQ_4:17;
A122: {pion1/.len pion1} c= L~co /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.len pion1};
    then
A123: x = pion1/.len pion1 by TARSKI:def 1;
    then
A124: x in rng pion1 by FINSEQ_6:168;
    x in rng co by A83,A121,A123,FINSEQ_6:42;
    hence thesis by A62,A112,A124,XBOOLE_0:def 4;
  end;
  L~co /\ L~pion1 c= {pion1/.len pion1}
  proof
    let x be object;
    assume
A125: x in L~co /\ L~pion1;
    then
A126: x in L~pion1 by XBOOLE_0:def 4;
    x in L~co by A125,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~LS by A53,A126,XBOOLE_0:def 4;
    hence thesis by A7,A42,A81,A83,A121,SPPOL_2:21;
  end;
  then
A127: L~co /\ L~pion1 = {pion1/.len pion1} by A122;
A128: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A92,TOPREAL8:35
    .= {go/.1} \/ {co/.1} by A72,A83,A121,A127,XBOOLE_1:23
    .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
    .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
  co/.len co = (go^'pion1)/.1 by A60,FINSEQ_6:155;
  then reconsider
  godo as non constant standard special_circular_sequence by A90,A94,A95,A100
,A102,A110,A111,A119,A120,A128,JORDAN8:4,5,TOPREAL8:11,33,34;
A129: LA is_an_arc_of E-max C,W-min C by JORDAN6:def 9;
  then
A130: LA is connected by JORDAN6:10;
A131: W-min C in LA by A129,TOPREAL1:1;
A132: E-max C in LA by A129,TOPREAL1:1;
  set ff = Rotate(Cage(C,n),Wmin);
  Wmin in rng Cage(C,n) by SPRECT_2:43;
  then
A133: ff/.1 = Wmin by FINSEQ_6:92;
A134: L~ff = L~Cage(C,n) by REVROT_1:33;
  then (W-max L~ff)..ff > 1 by A133,SPRECT_5:22;
  then (N-min L~ff)..ff > 1 by A133,A134,SPRECT_5:23,XXREAL_0:2;
  then (N-max L~ff)..ff > 1 by A133,A134,SPRECT_5:24,XXREAL_0:2;
  then
A135: Emax..ff > 1 by A133,A134,SPRECT_5:25,XXREAL_0:2;
A136: now
    assume
A137: Gik..US <= 1;
    Gik..US >= 1 by A34,FINSEQ_4:21;
    then Gik..US = 1 by A137,XXREAL_0:1;
    then Gik = US/.1 by A34,FINSEQ_5:38;
    hence contradiction by A18,A22,JORDAN1F:5;
  end;
A138: Cage(C,n) is_sequence_on Ga by JORDAN9:def 1;
  then
A139: ff is_sequence_on Ga by REVROT_1:34;
A140: right_cell(godo,1,Ga)\L~godo c= RightComp godo by A90,A95,JORDAN9:27;
A141: L~godo = L~(go^'pion1) \/ L~co by A94,TOPREAL8:35
    .= L~go \/ L~pion1 \/ L~co by A92,TOPREAL8:35;
A142: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
  then
A143: L~US c= L~Cage(C,n) by XBOOLE_1:7;
A144: L~LS c= L~Cage(C,n) by A142,XBOOLE_1:7;
A145: L~go c= L~Cage(C,n) by A46,A143;
A146: L~co c= L~Cage(C,n) by A53,A144;
A147: W-min C in C by SPRECT_1:13;
A148: L~pion = LSeg(Gik,Gij) by SPPOL_2:21;
A149: now
    assume W-min C in L~godo;
    then
A150: W-min C in L~go \/ L~pion1 or W-min C in L~co by A141,XBOOLE_0:def 3;
    per cases by A150,XBOOLE_0:def 3;
    suppose
      W-min C in L~go;
      then C meets L~Cage(C,n) by A145,A147,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
    suppose
      W-min C in L~pion1;
      hence contradiction by A8,A81,A131,A148,XBOOLE_0:3;
    end;
    suppose
      W-min C in L~co;
      then C meets L~Cage(C,n) by A146,A147,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
  end;
  right_cell(Rotate(Cage(C,n),Wmin),1) = right_cell(ff,1,GoB ff) by A86,
JORDAN1H:23
    .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
    .= right_cell(ff,1,Ga) by JORDAN1H:44
    .= right_cell(ff-:Emax,1,Ga) by A135,A139,Th53
    .= right_cell(US,1,Ga) by JORDAN1E:def 1
    .= right_cell(R_Cut(US,Gik),1,Ga) by A34,A91,A136,Th52
    .= right_cell(go^'pion1,1,Ga) by A39,A93,Th51
    .= right_cell(godo,1,Ga) by A88,A95,Th51;
  then W-min C in right_cell(godo,1,Ga) by JORDAN1I:6;
  then
A151: W-min C in right_cell(godo,1,Ga)\L~godo by A149,XBOOLE_0:def 5;
A152: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
    .= Wmin by A59,FINSEQ_6:155;
A153: len US >= 2 by A17,XXREAL_0:2;
A154: godo/.2 = (go^'pion1)/.2 by A87,FINSEQ_6:159
    .= US/.2 by A33,A75,FINSEQ_6:159
    .= (US^'LS)/.2 by A153,FINSEQ_6:159
    .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
A155: L~go \/ L~co is compact by COMPTS_1:10;
  Wmin in rng go by A59,FINSEQ_6:42;
  then Wmin in L~go \/ L~co by A61,XBOOLE_0:def 3;
  then
A156: W-min (L~go \/ L~co) = Wmin by A145,A146,A155,Th21,XBOOLE_1:8;
A157: (W-min (L~go \/ L~co))`1 = W-bound (L~go \/ L~co) by EUCLID:52;
A158: Wmin`1 = Wbo by EUCLID:52;
  W-bound LSeg(Gik,Gij) = Gik`1 by A78,SPRECT_1:54;
  then
A159: W-bound L~pion1 = Gik`1 by A81,SPPOL_2:21;
  Gik`1 >= Wbo by A10,A143,PSCOMP_1:24;
  then Gik`1 > Wbo by A74,XXREAL_0:1;
  then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co) by A155,A156,A157
,A158,A159,Th33;
  then
A160: W-min L~godo = Wmin by A141,A156,XBOOLE_1:4;
A161: rng godo c= L~godo by A87,A89,SPPOL_2:18,XXREAL_0:2;
  2 in dom godo by A90,FINSEQ_3:25;
  then
A162: godo/.2 in rng godo by PARTFUN2:2;
  godo/.2 in W-most L~Cage(C,n) by A154,JORDAN1I:25;
  then (godo/.2)`1 = (W-min L~godo)`1 by A160,PSCOMP_1:31
    .= W-bound L~godo by EUCLID:52;
  then godo/.2 in W-most L~godo by A161,A162,SPRECT_2:12;
  then Rotate(godo,W-min L~godo)/.2 in W-most L~godo by A152,A160,FINSEQ_6:89;
  then reconsider godo as clockwise_oriented non constant standard
  special_circular_sequence by JORDAN1I:25;
  len US in dom US by FINSEQ_5:6;
  then
A163: US.len US = US/.len US by PARTFUN1:def 6
    .= Emax by JORDAN1F:7;
A164: east_halfline E-max C misses L~go
  proof
    assume east_halfline E-max C meets L~go;
    then consider p be object such that
A165: p in east_halfline E-max C and
A166: p in L~go by XBOOLE_0:3;
    reconsider p as Point of TOP-REAL 2 by A165;
    p in L~US by A46,A166;
    then p in east_halfline E-max C /\ L~Cage(C,n) by A143,A165,XBOOLE_0:def 4;
    then
A167: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
    then
A168: p = Emax by A46,A166,Th46;
    then Emax = Gik by A10,A163,A166,Th43;
    then Gik`1 = Ga*(len Ga,k)`1 by A5,A13,A16,A167,A168,JORDAN1A:71;
    hence contradiction by A2,A15,A30,JORDAN1G:7;
  end;
  now
    assume east_halfline E-max C meets L~godo;
    then
A169: east_halfline E-max C meets (L~go \/ L~pion1) or east_halfline E-max
    C meets L~co by A141,XBOOLE_1:70;
    per cases by A169,XBOOLE_1:70;
    suppose
      east_halfline E-max C meets L~go;
      hence contradiction by A164;
    end;
    suppose
      east_halfline E-max C meets L~pion1;
      then consider p be object such that
A170: p in east_halfline E-max C and
A171: p in L~pion1 by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A170;
A172: p`2 = (E-max C)`2 by A170,TOPREAL1:def 11;
      i+1 <= len Ga by A2,NAT_1:13;
      then i+1-1 <= len Ga-1 by XREAL_1:9;
      then
A173: i <= len Ga-'1 by XREAL_0:def 2;
A174: len Ga-'1 <= len Ga by NAT_D:35;
      p`1 = Gik`1 by A78,A81,A148,A171,GOBOARD7:5;
      then p`1 <= Ga*(len Ga-'1,1)`1 by A1,A5,A13,A16,A20,A173,A174,JORDAN1A:18
;
      then p`1 <= E-bound C by A20,JORDAN8:12;
      then
A175: p`1 <= (E-max C)`1 by EUCLID:52;
      p`1 >= (E-max C)`1 by A170,TOPREAL1:def 11;
      then p`1 = (E-max C)`1 by A175,XXREAL_0:1;
      then p = E-max C by A172,TOPREAL3:6;
      hence contradiction by A8,A81,A132,A148,A171,XBOOLE_0:3;
    end;
    suppose
      east_halfline E-max C meets L~co;
      then consider p be object such that
A176: p in east_halfline E-max C and
A177: p in L~co by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A176;
A178: (E-max C)`2 = p`2 by A176,TOPREAL1:def 11;
      set tt = Index(p,co)+(Gij..LS)-'1;
      set RC = Rotate(Cage(C,n),Emax);
A179: L~RC = L~Cage(C,n) by REVROT_1:33;
      consider t be Nat such that
A180: t in dom LS and
A181: LS.t = Gij by A37,FINSEQ_2:10;
      1 <= t by A180,FINSEQ_3:25;
      then
A182: 1 < t by A32,A181,XXREAL_0:1;
      t <= len LS by A180,FINSEQ_3:25;
      then Index(Gij,LS)+1 = t by A181,A182,JORDAN3:12;
      then
A183: len L_Cut(LS,Gij) = len LS-Index(Gij,LS) by A9,A181,JORDAN3:26;
      Index(p,co) < len co by A177,JORDAN3:8;
      then Index(p,co) < len LS-'Index(Gij,LS) by A183,XREAL_0:def 2;
      then Index(p,co)+1 <= len LS-'Index(Gij,LS) by NAT_1:13;
      then
A184: Index(p,co) <= len LS-'Index(Gij,LS)-1 by XREAL_1:19;
A185: co = mid(LS,Gij..LS,len LS) by A37,Th37;
A186: len RC = len Cage(C,n) by FINSEQ_6:179;
      p in L~LS by A53,A177;
      then p in east_halfline E-max C /\ L~Cage(C,n) by A144,A176,
XBOOLE_0:def 4;
      then
A187: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A188: GoB RC = GoB Cage(C,n) by REVROT_1:28
        .= Ga by JORDAN1H:44;
A189: 1+1 <= len LS by A23,XXREAL_0:2;
      then
A190: 2 in dom LS by FINSEQ_3:25;
      consider jj2 be Nat such that
A191: 1 <= jj2 and
A192: jj2 <= width Ga and
A193: Emax = Ga*(len Ga,jj2) by JORDAN1D:25;
A194: len Ga >= 4 by JORDAN8:10;
      then len Ga >= 1 by XXREAL_0:2;
      then
A195: [len Ga,jj2] in Indices Ga by A191,A192,MATRIX_0:30;
A196: 1<=Index(p,co) by A177,JORDAN3:8;
      LS = RC-:Wmin by JORDAN1G:18;
      then
A197: LSeg(LS,1) = LSeg(RC,1) by A189,SPPOL_2:9;
A198: Emax in rng Cage(C,n) by SPRECT_2:46;
      RC is_sequence_on Ga by A138,REVROT_1:34;
      then consider ii,jj be Nat such that
A199: [ii,jj+1] in Indices Ga and
A200: [ii,jj] in Indices Ga and
A201: RC/.1 = Ga*(ii,jj+1) and
A202: RC/.(1+1) = Ga*(ii,jj) by A85,A179,A186,A198,FINSEQ_6:92,JORDAN1I:23;
A203: jj+1+1 <> jj;
A204: 1 <= jj by A200,MATRIX_0:32;
      RC/.1 = E-max L~RC by A179,A198,FINSEQ_6:92;
      then
A205: ii = len Ga by A179,A199,A201,A193,A195,GOBOARD1:5;
      then ii-1 >= 4-1 by A194,XREAL_1:9;
      then
A206: ii-1 >= 1 by XXREAL_0:2;
      then
A207: 1 <= ii-'1 by XREAL_0:def 2;
A208: jj <= width Ga by A200,MATRIX_0:32;
      then
A209: Ga*(len Ga,jj)`1 = Ebo by A16,A204,JORDAN1A:71;
A210: jj+1 <= width Ga by A199,MATRIX_0:32;
      ii+1 <> ii;
      then
A211: right_cell(RC,1) = cell(Ga,ii-'1,jj) by A85,A186,A188,A199,A200,A201,A202
,A203,GOBOARD5:def 6;
A212: ii <= len Ga by A200,MATRIX_0:32;
A213: 1 <= ii by A200,MATRIX_0:32;
A214: ii <= len Ga by A199,MATRIX_0:32;
A215: 1 <= jj+1 by A199,MATRIX_0:32;
      then
A216: Ebo = Ga*(len Ga,jj+1)`1 by A16,A210,JORDAN1A:71;
A217: 1 <= ii by A199,MATRIX_0:32;
      then
A218: ii-'1+1 = ii by XREAL_1:235;
      then
A219: ii-'1 < len Ga by A214,NAT_1:13;
      then
A220: Ga*(ii-'1,jj+1)`2 = Ga*(1,jj+1)`2 by A215,A210,A207,GOBOARD5:1
        .= Ga*(ii,jj+1)`2 by A217,A214,A215,A210,GOBOARD5:1;
A221: E-max C in right_cell(RC,1) by JORDAN1I:7;
      then
A222: Ga*(ii-'1,jj)`2 <= (E-max C)`2 by A214,A210,A204,A211,A218,A206,
JORDAN9:17;
A223: (E-max C)`2 <= Ga*(ii-'1,jj+1)`2 by A221,A214,A210,A204,A211,A218,A206,
JORDAN9:17;
      Ga*(ii-'1,jj)`2 = Ga*(1,jj)`2 by A204,A208,A207,A219,GOBOARD5:1
        .= Ga*(ii,jj)`2 by A213,A212,A204,A208,GOBOARD5:1;
      then p in LSeg(RC/.1,RC/.(1+1)) by A187,A178,A201,A202,A205,A222,A223
,A220,A209,A216,GOBOARD7:7;
      then
A224: p in LSeg(LS,1) by A85,A197,A186,TOPREAL1:def 3;
A225: Gij..LS<=len LS by A37,FINSEQ_4:21;
      Gij..LS <> len LS by A29,A37,FINSEQ_4:19;
      then
A226: Gij..LS < len LS by A225,XXREAL_0:1;
A227: Index(Gij,LS)+1 = Gij..LS by A32,A37,Th56;
      0+Index(Gij,LS) < len LS by A9,JORDAN3:8;
      then len LS-Index(Gij,LS) > 0 by XREAL_1:20;
      then Index(p,co) <= len LS-Index(Gij,LS)-1 by A184,XREAL_0:def 2;
      then Index(p,co) <= len LS-Gij..LS by A227;
      then Index(p,co) <= len LS-'Gij..LS by XREAL_0:def 2;
      then
A228: Index(p,co) < len LS-'(Gij..LS)+1 by NAT_1:13;
A229: p in LSeg(co,Index(p,co)) by A177,JORDAN3:9;
      1<=Gij..LS by A37,FINSEQ_4:21;
      then
A230: LSeg(mid(LS,Gij..LS,len LS),Index(p,co)) = LSeg(LS,Index(p,co)+(
      Gij..LS)-'1) by A226,A196,A228,JORDAN4:19;
      1<=Index(Gij,LS) by A9,JORDAN3:8;
      then
A231: 1+1 <= Gij..LS by A227,XREAL_1:7;
      then Index(p,co)+Gij..LS >= 1+1+1 by A196,XREAL_1:7;
      then Index(p,co)+Gij..LS-1 >= 1+1+1-1 by XREAL_1:9;
      then
A232: tt >= 1+1 by XREAL_0:def 2;
      now
        per cases by A232,XXREAL_0:1;
        suppose
          tt > 1+1;
          then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
          hence contradiction by A224,A229,A185,A230,XBOOLE_0:3;
        end;
        suppose
A233:     tt = 1+1;
          then 1+1 = Index(p,co)+(Gij..LS)-1 by XREAL_0:def 2;
          then 1+1+1 = Index(p,co)+(Gij..LS);
          then
A234:     Gij..LS = 2 by A196,A231,JORDAN1E:6;
          LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A23,A233,TOPREAL1:def 6;
          then p in {LS/.2} by A224,A229,A185,A230,XBOOLE_0:def 4;
          then
A235:     p = LS/.2 by TARSKI:def 1;
          then
A236:     p in rng LS by A190,PARTFUN2:2;
          p..LS = 2 by A190,A235,FINSEQ_5:41;
          then p = Gij by A37,A234,A236,FINSEQ_5:9;
          then Gij`1 = Ebo by A235,JORDAN1G:32;
          then Gij`1 = Ga*(len Ga,j)`1 by A3,A12,A16,JORDAN1A:71;
          hence contradiction by A2,A14,A67,JORDAN1G:7;
        end;
      end;
      hence contradiction;
    end;
  end;
  then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
  then consider W be Subset of TOP-REAL 2 such that
A237: W is_a_component_of (L~godo)` and
A238: east_halfline E-max C c= W by GOBOARD9:3;
  W is not bounded by A238,JORDAN2C:121,RLTOPSP1:42;
  then W is_outside_component_of L~godo by A237,JORDAN2C:def 3;
  then W c= UBD L~godo by JORDAN2C:23;
  then
A239: east_halfline E-max C c= UBD L~godo by A238;
  E-max C in east_halfline E-max C by TOPREAL1:38;
  then E-max C in UBD L~godo by A239;
  then E-max C in LeftComp godo by GOBRD14:36;
  then LA meets L~godo by A130,A131,A132,A140,A151,Th36;
  then
A240: LA meets (L~go \/ L~pion1) or LA meets L~co by A141,XBOOLE_1:70;
A241: LA c= C by JORDAN6:61;
  per cases by A240,XBOOLE_1:70;
  suppose
    LA meets L~go;
    then LA meets L~Cage(C,n) by A46,A143,XBOOLE_1:1,63;
    hence contradiction by A241,JORDAN10:5,XBOOLE_1:63;
  end;
  suppose
    LA meets L~pion1;
    hence contradiction by A8,A81,A148;
  end;
  suppose
    LA meets L~co;
    then LA meets L~Cage(C,n) by A53,A144,XBOOLE_1:1,63;
    hence contradiction by A241,JORDAN10:5,XBOOLE_1:63;
  end;
end;
