reserve p,q,r,s,A,B for Element of PL-WFF,
  F,G,H for Subset of PL-WFF,
  k,n for Element of NAT,
  f,f1,f2 for FinSequence of PL-WFF;
reserve M for PLModel;

theorem ded:
  F \/ {A} |- B implies F |- A => B
proof
  assume F \/ {A} |- B;then
  consider f such that
A1: f.len f = B and
A2: 1<=len f and
A3: for i be Nat st 1<=i & i<=len f holds prc f,F \/ {A},i;
    defpred P[Nat] means
    1<=$1 & $1<=len f implies F |- A => f/.$1;
A4: for i being Nat st for j being Nat st j<i holds P[j] holds P[i]
    proof
      let i be Nat;
      assume A5: for j be Nat st j<i holds P[j];
      per cases by NAT_1:14;
      suppose i=0;
        hence P[i];
      end;
      suppose not i<1;
        assume that
A6:     1<=i and
A7:     i<=len f;
        per cases by A3,A6,A7,defprc;
        suppose A8: f.i in PL_axioms;
          f/.i => (A=>f/.i) in  PL_axioms by withplax;then
A9:       F |- f/.i => (A=>f/.i) by th42;
          f/.i in PL_axioms by A6,A7,A8,LTLAXIO5:1;then
          F |- f/.i by th42;
          hence thesis by th43,A9;
        end;
        suppose A10: f.i in F \/ {A};
          per cases by A10,XBOOLE_0:def 3;
          suppose A11: f.i in F;
            f/.i => (A=>f/.i) in  PL_axioms by withplax;then
            A12: F |- f/.i=>(A=>f/.i) by th42;
            f/.i in F by A6,A7,A11,LTLAXIO5:1;then
            F |- f/.i by th42;
            hence thesis by th43,A12;
          end;
          suppose f.i in {A};then
            f.i=A by TARSKI:def 1;then
            f/.i=A by A6,A7,LTLAXIO5:1;
            hence thesis by thaa;
          end;
        end;
        suppose ex j,k be Nat st 1<=j & j<i & 1<=k & k<i &
          f/.j,f/.k MP_rule f/.i;
          then consider j,k be Nat such that
A15:      1<=j and
A16:      j<i and
A17:      1<=k and
A18:      k<i and
A19:      f/.j,f/.k MP_rule f/.i;
          j<=len f by A7,A16,XXREAL_0:2;then
A20:      F|- A => f/.j by A5,A15,A16;
          k<=len f by A7,A18,XXREAL_0:2;then
A21:      F|- A => f/.k by A5,A17,A18;
          (A=>(f/.j=>f/.i))=>((A=>f/.j)=>(A=>f/.i)) in PL_axioms
          by withplax;then
A23:      F |- (A=>(f/.j=>f/.i))=>((A=>f/.j)=>(A=>f/.i)) by th42;
            F|- (A=>f/.j)=>(A=>f/.i) by A23,th43,A21,A19;
            hence F |- A => f/.i by A20,th43;
        end;
      end;
    end;
A37: for i be Nat holds P[i] from NAT_1:sch 4(A4);
     B = f/.len f by A1,A2,LTLAXIO5:1;
     hence F |- A => B by A2,A37;
   end;
